#!/usr/bin/perl
# $Id: service.in,v 1.77 2003/06/05 08:26:59 cjwatson Exp $
# ^ more or less ^
#
# Usage: service <code>.nn
# Temps:  incoming/P<code>.nn

use Mail::Address;
use File::Copy;
use MIME::Parser;

$config_path = '/etc/debbugs';
$lib_path = '/usr/lib/debbugs';

require "$config_path/config";
require "$lib_path/errorlib";
$ENV{'PATH'} = $lib_path.':'.$ENV{'PATH'};

chdir("$gSpoolDir") || die "chdir spool: $!\n";

# open(DEBUG,">&4");
open DEBUG, ">/dev/null";
$debug = 0;
umask(002);

$_=shift;
m/^[RC]\.\d+$/ || &quit("bad argument");
$control= m/C/;
$nn= $_;
if (!rename("incoming/G$nn","incoming/P$nn")) {
    $_=$!.'';  m/no such file or directory/i && exit 0;
    &quit("renaming to lock: $!");
}    

open(M,"incoming/P$nn");
@log=<M>;
@msg=@log;
close(M);

chomp @msg;

print "###\n",join("##\n",@msg),"\n###\n" if $debug;

my $parser = new MIME::Parser;
mkdir "$gSpoolDir/mime.tmp", 0777;
$parser->output_under("$gSpoolDir/mime.tmp");
my $entity = eval { $parser->parse_data(join('',@log)) };

# header and decoded body respectively
my (@headerlines, @bodylines);

if ($entity and $entity->head->tags) {
    @headerlines = @{$entity->head->header};
    chomp @headerlines;

    my $entity_body = getmailbody($entity);
    @bodylines = $entity_body ? $entity_body->as_lines() : ();
    chomp @bodylines;
} else {
    # Legacy pre-MIME code, kept around in case MIME::Parser fails.
    my $i;
    for ($i = 0; $i <= $#msg; $i++) {
	$_ = $msg[$i];
	last unless length($_);
	while ($msg[$i+1] =~ m/^\s/) {
	    $i++;
	    $_ .= "\n".$msg[$i];
	}
	push @headerlines, $_;
    }

    @bodylines = @msg[$i..$#msg];
}

for (@headerlines) {
    s/\n\s/ /g;
    print ">$_<\n" if $debug;
    if (s/^(\S+):\s*//) {
	my $v = lc $1;
	print ">$v=$_<\n" if $debug;
	$header{$v} = $_;
    } else {
	print "!>$_<\n" if $debug;
    }
}

# Strip off RFC2440-style PGP clearsigning.
if (@bodylines and $bodylines[0] =~ /^-----BEGIN PGP SIGNED/) {
    shift @bodylines while @bodylines and length $bodylines[0];
    shift @bodylines while @bodylines and $bodylines[0] !~ /\S/;
    for my $findsig (0 .. $#bodylines) {
	if ($bodylines[$findsig] =~ /^-----BEGIN PGP SIGNATURE/) {
	    $#bodylines = $findsig - 1;
	    last;
	}
    }
    map { s/^- // } @bodylines;
}

grep(s/\s+$//,@bodylines);

print "***\n",join("\n",@bodylines),"\n***\n" if $debug;

if (defined $header{'resent-from'} && !defined $header{'from'}) {
    $header{'from'} = $header{'resent-from'};
}

defined($header{'from'}) || &quit("no From header");

delete $header{'reply-to'} 
	if ( defined($header{'reply-to'}) && $header{'reply-to'} =~ m/^\s*$/ );

if ( defined($header{'reply-to'}) && $header{'reply-to'} ne "" ) {
    $replyto = $header{'reply-to'};
} else {
    $replyto = $header{'from'};
}

$controlrequestaddr= $control ? "control\@$gEmailDomain" : "request\@$gEmailDomain";
$transcript='';
&transcript("Processing commands for $controlrequestaddr:\n\n");

$dl= 0;
$state= 'idle';
$lowstate= 'idle';
$mergelowstate= 'idle';
$midix=0;    
$extras="";

my $quickabort = 0;

my $fuckheads = "(" . join("|", @gFuckheads) . ")";
if (@gFuckheads and $replyto =~ m/$fuckheads/) {
	&transcript("This service is unavailable.\n\n");
	$quickabort = 1;
}

my %clonebugs = ();
my @bcc = ();

for ($procline=0; $procline<=$#bodylines; $procline++) {
    $state eq 'idle' || print "$state ?\n";
    $lowstate eq 'idle' || print "$lowstate ?\n";
    $mergelowstate eq 'idle' || print "$mergelowstate ?\n";
    if ($quickabort) {
         &transcript("Stopping processing here.\n\n");
	 last;
    }
    $_= $bodylines[$procline]; s/\s+$//;
    next unless m/\S/;
    &transcript("> $_\n");
    next if m/^\s*\#/;
    $action= '';
    if (m/^stop/i || m/^quit/i || m/^--/ || m/^thank/i) {
	&transcript("Stopping processing here.\n\n");
        last;
    } elsif (m/^debug\s+(\d+)$/i && $1 >= 0 && $1 <= 1000) {
        $dl= $1+0;
        &transcript("Debug level $dl.\n\n");
    } elsif (m/^(send|get)\s+\#?(\d{2,})$/i) {
        $ref= $2+0;
        &sendlynxdoc("bugreport.cgi?bug=$ref","logs for $gBug#$ref");
    } elsif (m/^send-detail\s+\#?(\d{2,})$/i) {
	$ref= $1+0;
	&sendlynxdoc("bugreport.cgi?bug=$ref&boring=yes",
		     "detailed logs for $gBug#$ref");
    } elsif (m/^index(\s+full)?$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^index-summary\s+by-package$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^index-summary(\s+by-number)?$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^index(\s+|-)pack(age)?s?$/i) {
	&sendlynxdoc("pkgindex.cgi?indexon=pkg",'index of packages');
    } elsif (m/^index(\s+|-)maints?$/i) {
	&sendlynxdoc("pkgindex.cgi?indexon=maint",'index of maintainers');
    } elsif (m/^index(\s+|-)maint\s+(\S+)$/i) {
	$maint = $2;
	&sendlynxdoc("pkgreport.cgi?maint=" . urlsanit($maint),
		     "$gBug list for maintainer \`$maint'");
        $ok++;
    } elsif (m/^index(\s+|-)pack(age)?s?\s+(\S.*\S)$/i) {
	$package = $+;
	&sendlynxdoc("pkgreport.cgi?pkg=" . urlsanit($package),
		     "$gBug list for package $package");
        $ok++;
    } elsif (m/^send-unmatched(\s+this|\s+-?0)?$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^send-unmatched\s+(last|-1)$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^send-unmatched\s+(old|-2)$/i) {
	&transcript("This BTS function is currently disabled, sorry.\n\n");
	$ok++; # well, it's not really ok, but it fixes #81224 :)
    } elsif (m/^getinfo\s+([\w-.]+)$/i) {
        # the following is basically a Debian-specific kludge, but who cares
        $req = $1;
	if ($req =~ /^maintainers$/i && -f "$gConfigDir/Maintainers") {
	    &sendinfo("local", "$gConfigDir/Maintainers", "Maintainers file");
	} elsif ($req =~ /^override\.(\w+)\.([\w-.]+)$/i) {
	    $req =~ s/.gz$//;
	    &sendinfo("ftp.d.o", "$req", "override file for $2 part of $1 distribution");
	} elsif ($req =~ /^pseudo-packages\.(description|maintainers)$/i && -f "$gConfigDir/$req") {
	    &sendinfo("local", "$gConfigDir/$req", "$req file");
	} else {
	    &transcript("Info file $req does not exist.\n\n");
	}
    } elsif (m/^help/i) {
        &sendhelp;
        &transcript("\n");
        $ok++;
    } elsif (m/^refcard/i) {
        &sendtxthelp("bug-mailserver-refcard.txt","mail servers' reference card");
    } elsif (m/^subscribe/i) {
        &transcript(<<END);
There is no $gProject $gBug mailing list.  If you wish to review bug reports
please do so via http://$gWebDomain/ or ask this mail server
to send them to you.
soon: MAILINGLISTS_TEXT
END
    } elsif (m/^unsubscribe/i) {
        &transcript(<<END);
soon: UNSUBSCRIBE_TEXT
soon: MAILINGLISTS_TEXT
END
    } elsif (!$control) {
        &transcript(<<END);
Unknown command or malformed arguments to command.
(Use control\@$gEmailDomain to manipulate reports.)

END
        if (++$unknowns >= 3) {
            &transcript("Too many unknown commands, stopping here.\n\n");
            last;
        }
#### interesting ones start here
    } elsif (m/^close\s+\#?(-?\d+)$/i) {
	$ok++;
	$ref= $1;
	if (&setbug) {
	    &transcript("'close' is deprecated; see http://$gWebDomain/Developer$gHTMLSuffix#closing.\n");
	    if (length($data->{done})) {
		&transcript("$gBug is already closed, cannot re-close.\n\n");
                &nochangebug;
            } else {
                $action= "$gBug closed, send any further explanations to $data->{originator}";
                do {
                    &addmaintainers($data->{package});
					if ( length( $gDoneList ) > 0 && length( $gListDomain ) >
					0 ) { &addccaddress("$gDoneList\@$gListDomain"); }
                    $data->{done}= $replyto;
		    $message= <<END;
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $data->{originator}
Subject: $gBug#$ref acknowledged by developer
         ($header{'subject'})
References: $header{'message-id'} $data->{msgid}
In-Reply-To: $data->{msgid}
Message-ID: <handler.$ref.$nn.notifdonectrl.$midix\@$gEmailDomain>
Reply-To: $ref\@$gEmailDomain

This is an automatic notification regarding your $gBug report
#$ref: $data->{subject},
which was filed against the $data->{package} package.

It has been marked as closed by one of the developers, namely
$replyto.

You should be hearing from them with a substantive response shortly,
in case you haven't already. If not, please contact them directly.

$gMaintainer
(administrator, $gProject $gBugs database)

END
                    &sendmailmessage($message,$data->{originator});
                } while (&getnextbug);
            }
        }
    } elsif (m/^reassign\s+\#?(-?\d+)\s+(\S.*\S)$/i) {
        $ok++;
        $ref= $1; $newpackage= $2;
    	$newpackage =~ y/A-Z/a-z/;
        if (&setbug) {
            if (length($data->{package})) {
                $action= "$gBug reassigned from package \`$data->{package}'".
                         " to \`$newpackage'.";
            } else {
                $action= "$gBug assigned to package \`$newpackage'.";
            }
            do {
                &addmaintainers($data->{package});
                &addmaintainers($newpackage);
                $data->{package}= $newpackage;
            } while (&getnextbug);
        }
    } elsif (m/^reopen\s+\#?(-?\d+)$/i ? ($noriginator='', 1) :
             m/^reopen\s+\#?(-?\d+)\s+\=$/i ? ($noriginator='', 1) :
             m/^reopen\s+\#?(-?\d+)\s+\!$/i ? ($noriginator=$replyto, 1) :
             m/^reopen\s+\#?(-?\d+)\s+(\S.*\S)$/i ? ($noriginator=$2, 1) : 0) {
        $ok++;
        $ref= $1;
        if (&setbug) {
            if (!length($data->{done})) {
                &transcript("$gBug is already open, cannot reopen.\n\n");
                &nochangebug;
            } else {
                $action=
                    $noriginator eq '' ? "$gBug reopened, originator not changed." :
                        "$gBug reopened, originator set to $noriginator.";
                do {
                    &addmaintainers($data->{package});
                    $data->{originator}= $noriginator eq '' ?  $data->{originator} : $noriginator;
                    $data->{done}= '';
                } while (&getnextbug);
            }
        }
    } elsif (m/^submitter\s+\#?(-?\d+)\s+\!$/i ? ($newsubmitter=$replyto, 1) :
             m/^submitter\s+\#?(-?\d+)\s+(\S.*\S)$/i ? ($newsubmitter=$2, 1) : 0) {
        $ok++;
        $ref= $1;
        if ($ref =~ m/^-\d+$/ && defined $clonebugs{$ref}) {
            $ref = $clonebugs{$ref};
        }
        if (&getbug) {
            &foundbug;
            &addmaintainers($data->{package});
            $oldsubmitter= $data->{originator};
            $data->{originator}= $newsubmitter;
            $action= "Changed $gBug submitter from $oldsubmitter to $newsubmitter.";
            &savebug;
            &transcript("$action\n");
            if (length($data->{done})) {
                &transcript("(By the way, that $gBug is currently marked as done.)\n");
            }
            &transcript("\n");
            $message= <<END;
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $oldsubmitter
Subject: $gBug#$ref submitter address changed
         ($header{'subject'})
References: $header{'message-id'} $data->{msgid}
In-Reply-To: $data->{msgid}
Message-ID: <handler.$ref.$nn.newsubmitter.$midix\@$gEmailDomain>
Reply-To: $ref\@$gEmailDomain

The submitter address recorded for your $gBug report
#$ref: $data->{subject}
has been changed.

The new submitter address for this report is
$newsubmitter.

This change was made by
$replyto.
If it was incorrect, please contact them directly.

$gMaintainer
(administrator, $gProject $gBugs database)

END
            &sendmailmessage($message,$oldsubmitter);
        } else {
            &notfoundbug;
        }
    } elsif (m/^forwarded\s+\#?(-?\d+)\s+(\S.*\S)$/i) {
        $ok++;
        $ref= $1; $whereto= $2;
        if (&setbug) {
            if (length($data->{forwarded})) {
    $action= "Forwarded-to-address changed from $data->{forwarded} to $whereto.";
            } else {
    $action= "Noted your statement that $gBug has been forwarded to $whereto.";
            }
            if (length($data->{done})) {
                $extramessage= "(By the way, this $gBug is currently marked as done.)\n";
            }
            do {
                &addmaintainers($data->{package});
		if (length($gFowardList)>0 && length($gListDomain)>0 ) {
		     &addccaddress("$gFowardList\@$gListDomain"); 
		}
                $data->{forwarded}= $whereto;
            } while (&getnextbug);
        }
    } elsif (m/^notforwarded\s+\#?(-?\d+)$/i) {
        $ok++;
        $ref= $1;
        if (&setbug) {
            if (!length($data->{forwarded})) {
                &transcript("$gBug is not marked as having been forwarded.\n\n");
                &nochangebug;
            } else {
    $action= "Removed annotation that $gBug had been forwarded to $data->{forwarded}.";
                do {
                    &addmaintainers($data->{package});
                    $data->{forwarded}= '';
                } while (&getnextbug);
            }
        }
    } elsif (m/^severity\s+\#?(-?\d+)\s+([-0-9a-z]+)$/i ||
	m/^priority\s+\#?(-?\d+)\s+([-0-9a-z]+)$/i) {
        $ok++;
        $ref= $1;
        $newseverity= $2;
        if (!grep($_ eq $newseverity, @gSeverityList, "$gDefaultSeverity")) {
            &transcript("Severity level \`$newseverity' is not known.\n".
 			"Recognized are: $gShowSeverities.\n\n");
        } elsif (exists $gObsoleteSeverities{$newseverity}) {
            &transcript("Severity level \`$newseverity' is obsolete. " .
                        "$gObsoleteSeverities{$newseverity}\n\n");
        } elsif (&setbug) {
            $printseverity= $data->{severity};
            $printseverity= "$gDefaultSeverity" if $printseverity eq '';
	    $action= "Severity set to \`$newseverity'.";
	    do {
                &addmaintainers($data->{package});
                $data->{severity}= $newseverity;
            } while (&getnextbug);
        }
    } elsif (m/^tags?\s+\#?(-?\d+)\s+(([=+-])\s*)?(\S.*)?$/i) {
	$ok++;
	$ref = $1; $addsubcode = $3; $tags = $4;
	$addsub = "add";
	if (defined $addsubcode) {
	    $addsub = "sub" if ($addsubcode eq "-");
	    $addsub = "add" if ($addsubcode eq "+");
	    $addsub = "set" if ($addsubcode eq "=");
	}
	my @okaytags = ();
	my @badtags = ();
	foreach my $t (split /[\s,]+/, $tags) {
	    if (!grep($_ eq $t, @gTags)) {
		push @badtags, $t;
	    } else {
		push @okaytags, $t;
	    }
	}
	if (@badtags) {
            &transcript("Unknown tag/s: ".join(', ', @badtags).".\n".
 			"Recognized are: ".join(' ', @gTags).".\n\n");
	}
	if (&setbug) {
	    if ($data->{keywords} eq '') {
		&transcript("There were no tags set.\n");
	    } else {
		&transcript("Tags were: $data->{keywords}\n");
	    }
	    if ($addsub eq "set") {
		$action= "Tags set to: " . join(", ", @okaytags);
	    } elsif ($addsub eq "add") {
		$action= "Tags added: " . join(", ", @okaytags);
	    } elsif ($addsub eq "sub") {
		$action= "Tags removed: " . join(", ", @okaytags);
	    }
	    do {
                &addmaintainers($data->{package});
	        $data->{keywords} = '' if ($addsub eq "set");
		if ($addsub eq "sub") {
		    foreach my $t (@badtags) {
	                $data->{keywords} = join ' ', grep $_ ne $t, 
		            split ' ', $data->{keywords};
		    }
		}
	        foreach my $t (@okaytags) {
	            $data->{keywords} = join ' ', grep $_ ne $t, 
			split ' ', $data->{keywords};
	            $data->{keywords} = "$t $data->{keywords}" unless($addsub eq "sub");
	        }
		$data->{keywords} =~ s/\s*$//;
            } while (&getnextbug);
	}
    } elsif (m/^retitle\s+\#?(-?\d+)\s+(\S.*\S)\s*$/i) {
        $ok++;
        $ref= $1; $newtitle= $2;
	if ($ref =~ m/^-\d+$/ && defined $clonebugs{$ref}) {
	    $ref = $clonebugs{$ref};
	}
        if (&getbug) {
            &foundbug;
            &addmaintainers($data->{package});
            $data->{subject}= $newtitle;
            $action= "Changed $gBug title.";
            &savebug;
            &transcript("$action\n");
            if (length($data->{done})) {
                &transcript("(By the way, that $gBug is currently marked as done.)\n");
            }
            &transcript("\n");
        } else {
            &notfoundbug;
        }
    } elsif (m/^unmerge\s+\#?(-?\d+)$/i) {
	$ok++;
	$ref= $1;
	if (&setbug) {
	    if (!length($data->{mergedwith})) {
		&transcript("$gBug is not marked as being merged with any others.\n\n");
		&nochangebug;
	    } else {
                $mergelowstate eq 'locked' || die "$mergelowstate ?";
		$action= "Disconnected #$ref from all other report(s).";
		@newmergelist= split(/ /,$data->{mergedwith});
                $discref= $ref;
                do {
                    &addmaintainers($data->{package});
		    $data->{mergedwith}= ($ref == $discref) ? ''
                        : join(' ',grep($_ ne $ref,@newmergelist));
                } while (&getnextbug);
	    }
	}
    } elsif (m/^merge\s+(-?\d+(\s+-?\d+)+)\s*$/i) {
	$ok++;
        @tomerge= sort { $a <=> $b } split(/\s+/,$1);
        @newmergelist= ();
	my %tags = ();
        &getmerge;
        while (defined($ref= shift(@tomerge))) {
            &transcript("D| checking merge $ref\n") if $dl;
	    $ref+= 0;
	    if ($ref =~ m/^-\d+$/ && defined $clonebugs{$ref}) {
		$ref = $clonebugs{$ref};
	    }
	    next if grep($_ eq $ref,@newmergelist);
	    if (!&getbug) { &notfoundbug; @newmergelist=(); last }
            &foundbug;
            &transcript("D| adding $ref ($data->{mergedwith})\n") if $dl;
	    $mismatch= '';
	    &checkmatch('package','m_package',$data->{package});
	    &checkmatch('forwarded addr','m_forwarded',$data->{forwarded});
	    $data->{severity} = '$gDefaultSeverity' if $data->{severity} eq '';
	    &checkmatch('severity','m_severity',$data->{severity});
	    &checkmatch('done mark','m_done',length($data->{done}) ? 'done' : 'open');
	    foreach my $t (split /\s+/, $data->{keywords}) { $tags{$t} = 1; }
	    if (length($mismatch)) {
	        &transcript("Mismatch - only $gBugs in same state can be merged:\n".
                            $mismatch."\n");
		&cancelbug; @newmergelist=(); last;
	    }
            push(@newmergelist,$ref);
            push(@tomerge,split(/ /,$data->{mergedwith}));
	    &cancelbug;
	}
	if (@newmergelist) {
            @newmergelist= sort { $a <=> $b } @newmergelist;
            $action= "Merged @newmergelist.";
	    for $ref (@newmergelist) {
		&getbug || die "huh ?  $gBug $ref disappeared during merge";
                &addmaintainers($data->{package});
		$data->{mergedwith}= join(' ',grep($_ ne $ref,@newmergelist));
		$data->{keywords}= join(' ', keys %tags);
		&savebug;
	    }
    	    &transcript("$action\n\n");
	}
        &endmerge;
    } elsif (m/^clone\s+#?(\d+)\s+((-\d+\s+)*-\d+)\s*$/i) {
	$ok++;

	$origref = $1;
	@newclonedids = split /\s+/, $2;
	$newbugsneeded = scalar(@newclonedids);

	$ref = $origref;
	if (&setbug) {
	    if (length($data->{mergedwith})) {
		&transcript("$gBug is marked as being merged with others.\n\n");
		&nochangebug;
	    } else {
        	&filelock("nextnumber.lock");
        	open(N,"nextnumber") || &quit("nextnumber: read: $!");
        	$v=<N>; $v =~ s/\n$// || &quit("nextnumber bad format");
        	$firstref= $v+0;  $v += $newbugsneeded;
		open(NN,">nextnumber"); print NN "$v\n"; close(NN);
        	&unfilelock;

		$lastref = $firstref + $newbugsneeded - 1;

		if ($newbugsneeded == 1) {
		    $action= "$gBug $origref cloned as bug $firstref.";
		} else {
		    $action= "$gBug $origref cloned as bugs $firstref-$lastref.";
		}
		&getnextbug;
		my $ohash = get_hashname($origref);
		$ref = $firstref;
		for $newclonedid (@newclonedids) {
		    $clonebugs{$newclonedid} = $ref;
	    
		    my $hash = get_hashname($ref);
	            copy("db-h/$ohash/$origref.log", "db-h/$hash/$ref.log");
	            copy("db-h/$ohash/$origref.status", "db-h/$hash/$ref.status");
	            copy("db-h/$ohash/$origref.report", "db-h/$hash/$ref.report");
	            &bughook('new', $ref, "$data->{originator}\n$data->{date}\n$data->{subject}\n$data->{msgid}\n$data->{package}\n$data->{keywords}\n$data->{done}\n$data->{forwarded}\n$data->{mergedwith}\n$data->{severity}\n");

		    $ref++;
		}
	    }
	}
    } else {
        &transcript("Unknown command or malformed arguments to command.\n\n");
        if (++$unknowns >= 5) {
            &transcript("Too many unknown commands, stopping here.\n\n");
            last;
        }
    }
}
if ($procline>$#bodylines) {
    &transcript(">\nEnd of message, stopping processing here.\n\n");
}
if (!$ok && !quickabort) {
    &transcript("No commands successfully parsed; sending the help text(s).\n");
    &sendhelp;
    &transcript("\n");
}

&transcript("MC\n") if $dl>1;
@maintccs= ();
for $maint (keys %maintccreasons) {
&transcript("MM|$maint|\n") if $dl>1;
    next if $maint eq $replyto;
    $reasonstring= '';
    $reasonsref= $maintccreasons{$maint};
&transcript("MY|$maint|\n") if $dl>2;
    for $p (sort keys %$reasonsref) {
&transcript("MP|$p|\n") if $dl>2;
        $reasonstring.= ', ' if length($reasonstring);
        $reasonstring.= $p.' ' if length($p);
        $reasonstring.= join(' ',map("#$_",sort keys %{$$reasonsref{$p}}));
    }
    if (length($reasonstring) > 40) {
	(substr $reasonstring, 37) = "...";
    }
    $reasonstring = "" if (!defined($reasonstring));
    push(@maintccs,"$maint ($reasonstring)");
    push(@maintccaddrs,"$maint");
}

$maintccs = ""; 
if (@maintccs) {
    &transcript("MC|@maintccs|\n") if $dl>2;
    $maintccs .= "Cc: " . join(",\n    ",@maintccs) . "\n";
}

if (!defined $header{'subject'} || $header{'subject'} eq "") {
  $header{'subject'} = "your mail";
}

$reply= <<END;
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $replyto
${maintccs}Subject: Processed: $header{'subject'}
In-Reply-To: $header{'message-id'}
References: $header{'message-id'}
Message-ID: <handler.s.$nn.transcript\@$gEmailDomain>
Precedence: bulk

${transcript}Please contact me if you need assistance.

$gMaintainer
(administrator, $gProject $gBugs database)
$extras
END

$repliedshow= join(', ',$replyto,@maintccaddrs);
&filelock("lock/-1");
open(AP,">>db-h/-1.log") || &quit("open db-h/-1.log: $!");
print(AP
      "\2\n$repliedshow\n\5\n$reply\n\3\n".
      "\6\n".
      "<strong>Request received</strong> from <code>".
      &sani($header{'from'})."</code>\n".
      "to <code>".&sani($controlrequestaddr)."</code>\n".
      "\3\n".
      "\7\n",@{escapelog(@log)},"\n\3\n") || &quit("writing db-h/-1.log: $!");
close(AP) || &quit("open db-h/-1.log: $!");
&unfilelock;
utime(time,time,"db-h");

&sendmailmessage($reply,$replyto,@maintccaddrs,@bcc);

unlink("incoming/P$nn") || &quit("unlinking incoming/P$nn: $!");

sub get_addresses {
    return
       map { $_->address() }
       map { Mail::Address->parse($_) } @_;
}

sub sendmailmessage {
    local ($message,@recips) = @_;
    $message = "X-Loop: $gMaintainerEmail\n" . $message;
    print "mailing to >@recips<\n" if $debug;
    $c= open(D,"|-");
    defined($c) || &quit("mailing forking for sendmail: $!");
    if (!$c) { # ie, we are the child process
        exec '/usr/lib/sendmail','-f'."$gMaintainerEmail",'-odb','-oem','-oi',get_addresses(@recips);
        die $!;
    }
    print(D $message) || &quit("writing to sendmail process: $!");
    $!=0; close(D); $? && &quit("sendmail gave exit status $? ($!)");
    $midix++;
}

sub sendhelp {
        &sendtxthelpraw("bug-log-mailserver.txt","instructions for request\@$gEmailDomain");
        &sendtxthelpraw("bug-maint-mailcontrol.txt","instructions for control\@$gEmailDomain")
            if $control;
}

#sub unimplemented {
#    &transcript("Sorry, command $_[0] not yet implemented.\n\n");
#}

sub checkmatch {
    local ($string,$mvarname,$svarvalue) = @_;
    local ($mvarvalue);
    if (@newmergelist) {
        eval "\$mvarvalue= \$$mvarname";
        &transcript("D| checkmatch \`$string' /$mvarname/$mvarvalue/$svarvalue/\n")
            if $dl;
        $mismatch .=
            "Values for \`$string' don't match:\n".
            " #$newmergelist[0] has \`$mvarvalue';\n".
            " #$ref has \`$svarvalue'\n"
            if $mvarvalue ne $svarvalue;
    } else {
        &transcript("D| setupmatch \`$string' /$mvarname/$svarvalue/\n")
            if $dl;
        eval "\$$mvarname= \$svarvalue";
    }
}

# High-level bug manipulation calls
# Do announcements themselves
#
# Possible calling sequences:
#    setbug (returns 0)
#    
#    setbug (returns 1)
#    &transcript(something)
#    nochangebug
#
#    setbug (returns 1)
#    $action= (something)
#    do {
#      (modify s_* variables)
#    } while (getnextbug);

sub nochangebug {
    &dlen("nochangebug");
    $state eq 'single' || $state eq 'multiple' || die "$state ?";
    &cancelbug;
    &endmerge if $manybugs;
    $state= 'idle';
    &dlex("nochangebug");
}

sub setbug {
    &dlen("setbug $ref");
    if ($ref =~ m/^-\d+/) {
        if (!defined $clonebugs{$ref}) {
            &notfoundbug;
            &dlex("setbug => noclone");
            return 0;
        }
        $ref = $clonebugs{$ref};
    }
    $state eq 'idle' || die "$state ?";
    if (!&getbug) {
        &notfoundbug;
        &dlex("setbug => 0s");
        return 0;
    }
    @thisbugmergelist= split(/ /,$data->{mergedwith});
    if (!@thisbugmergelist) {
        &foundbug;
        $manybugs= 0;
        $state= 'single';
        $sref=$ref;
        &dlex("setbug => 1s");
        return 1;
    }
    &cancelbug;
    &getmerge;
    $manybugs= 1;
    if (!&getbug) {
        &notfoundbug;
        &endmerge;
        &dlex("setbug => 0mc");
        return 0;
    }
    &foundbug;
    $state= 'multiple'; $sref=$ref;
    &dlex("setbug => 1m");
    return 1;
}

sub getnextbug {
    &dlen("getnextbug");
    $state eq 'single' || $state eq 'multiple' || die "$state ?";
    &savebug;
    if (!$manybugs || !@thisbugmergelist) {
        length($action) || die;
        &transcript("$action\n$extramessage\n");
        &endmerge if $manybugs;
        $state= 'idle';
        &dlex("getnextbug => 0");
        return 0;
    }
    $ref= shift(@thisbugmergelist);
    &getbug || die "bug $ref disappeared";
    &foundbug;
    &dlex("getnextbug => 1");
    return 1;
}

# Low-level bug-manipulation calls
# Do no announcements
#
#    getbug (returns 0)
#
#    getbug (returns 1)
#    cancelbug
#
#    getmerge
#    $action= (something)
#    getbug (returns 1)
#    savebug/cancelbug
#    getbug (returns 1)
#    savebug/cancelbug
#    [getbug (returns 0)]
#    &transcript("$action\n\n")
#    endmerge

sub notfoundbug { &transcript("$gBug number $ref not found.\n\n"); }
sub foundbug { &transcript("$gBug#$ref: $data->{subject}\n"); }

sub getmerge {
    &dlen("getmerge");
    $mergelowstate eq 'idle' || die "$mergelowstate ?";
    &filelock('lock/merge');
    $mergelowstate='locked';
    &dlex("getmerge");
}

sub endmerge {
    &dlen("endmerge");
    $mergelowstate eq 'locked' || die "$mergelowstate ?";
    &unfilelock;
    $mergelowstate='idle';
    &dlex("endmerge");
}

sub getbug {
    &dlen("getbug $ref");
    $lowstate eq 'idle' || die "$state ?";
    if (($data = &lockreadbug($ref))) {
        $sref= $ref;
        $lowstate= "open";
        &dlex("getbug => 1");
        $extramessage='';
        return 1;
    }
    $lowstate= 'idle';
    &dlex("getbug => 0");
    return 0;
}

sub cancelbug {
    &dlen("cancelbug");
    $lowstate eq 'open' || die "$state ?";
    &unfilelock;
    $lowstate= 'idle';
    &dlex("cancelbug");
}

sub savebug {
    &dlen("savebug $ref");
    $lowstate eq 'open' || die "$lowstate ?";
    length($action) || die;
    $ref == $sref || die "read $sref but saving $ref ?";
    my $hash = get_hashname($ref);
    open(L,">>db-h/$hash/$ref.log") || &quit("opening db-h/$hash/$ref.log: $!");
    print(L
          "\6\n".
          "<strong>".&sani($action)."</strong>\n".
          "Request was from <code>".&sani($header{'from'})."</code>\n".
          "to <code>".&sani($controlrequestaddr)."</code>. \n".
          "\3\n".
          "\7\n",@{escapelog(@log)},"\n\3\n") || &quit("writing db-h/$hash/$ref.log: $!");
    close(L) || &quit("closing db-h/$hash/$ref.log: $!");
    unlockwritebug($ref, $data);
    $lowstate= "idle";
    &dlex("savebug");
}

sub dlen {
    return if !$dl;
    &transcript("C> @_ ($state $lowstate $mergelowstate)\n");
}

sub dlex {
    return if !$dl;
    &transcript("R> @_ ($state $lowstate $mergelowstate)\n");
}

sub transcript {
    print $_[0] if $debug;
    $transcript.= $_[0];
}

sub urlsanit {
    my $url = shift;
    $url =~ s/%/%25/g;
    $url =~ s/\+/%2b/g;
    my %saniarray = ('<','lt', '>','gt', '&','amp', '"','quot');
    $url =~ s/([<>&"])/\&$saniarray{$1};/g;
    return $url;
}

sub sendlynxdoc {
    &sendlynxdocraw;
    &transcript("\n");
    $ok++;
}

sub sendtxthelp {
    &sendtxthelpraw;
    &transcript("\n");
    $ok++;
}

sub sendtxthelpraw {
    local ($relpath,$description) = @_;
    $doc='';
    open(D,"$gDocDir/$relpath") || &quit("open doc file $relpath: $!");
    while(<D>) { $doc.=$_; }
    close(D);
    &transcript("Sending $description in separate message.\n");
    &sendmailmessage(<<END.$doc,$replyto);
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $replyto
Subject: $gProject $gBug help: $description
References: $header{'message-id'}
In-Reply-To: $header{'message-id'}
Message-ID: <handler.s.$nn.help.$midix\@$gEmailDomain>
Precedence: bulk

END
    $ok++;
}

sub sendlynxdocraw {
    local ($relpath,$description) = @_;
    $doc='';
    open(L,"lynx -nolist -dump http://$gCGIDomain/\Q$relpath\E 2>&1 |") || &quit("fork for lynx: $!");
    while(<L>) { $doc.=$_; }
    $!=0; close(L);
    if ($? == 255 && $doc =~ m/^\n*lynx: Can\'t access start file/) {
        &transcript("Information ($description) is not available -\n".
                    "perhaps the $gBug does not exist or is not on the WWW yet.\n");
         $ok++;
    } elsif ($?) {
        &transcript("Error getting $description (code $? $!):\n$doc\n");
    } else {
        &transcript("Sending $description.\n");
        &sendmailmessage(<<END.$doc,$replyto);
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $replyto
Subject: $gProject $gBugs information: $description
References: $header{'message-id'}
In-Reply-To: $header{'message-id'}
Message-ID: <handler.s.$nn.info.$midix\@$gEmailDomain>
Precedence: bulk

END
         $ok++;
    }
}

sub addccaddress {
    my ($cca) = @_;
    $maintccreasons{$cca}{''}{$ref}= 1;
}

sub addmaintainers {
    # Data structure is:
    #   maintainer email address &c -> assoc of packages -> assoc of bug#'s
    my ($p, $addmaint, $pshow);
    &ensuremaintainersloaded;
    $anymaintfound=0; $anymaintnotfound=0;
    for $p (split(m/[ \t?,()]+/,$_[0])) {
 	$p =~ y/A-Z/a-z/;
        $pshow= ($p =~ m/[-+.a-z0-9]+/ ? $& : '');
	if (defined $gSubscriptionDomain) {
	    if (defined($pkgsrc{$p})) {
		push @bcc, "$pkgsrc{$p}\@$gSubscriptionDomain";
	    } else {
		push @bcc, "$p\@$gSubscriptionDomain";
	    }
	}
        if (defined($maintainerof{$p})) {
 	    $addmaint= $maintainerof{$p};
	    &transcript("MR|$addmaint|$p|$ref|\n") if $dl>2;
            $maintccreasons{$addmaint}{$p}{$ref}= 1;
	    print "maintainer add >$p|$addmaint<\n" if $debug;
        } else { 
	    print "maintainer none >$p<\n" if $debug; 
	    &transcript("Warning: Unknown package '$p'\n");
	    &transcript("MR|unknown-package|$p|$ref|\n") if $dl>2;
            $maintccreasons{$gUnknownMaintainerEmail}{$p}{$ref}= 1;
	}
    }
}

sub ensuremaintainersloaded {
    my ($a,$b);
    return if $maintainersloaded++;
    open(MAINT,"$gMaintainerFile") || die &quit("maintainers open: $!");
    while (<MAINT>) {
	m/^\n$/ && next;
	m/^\s*$/ && next;
        m/^(\S+)\s+(\S.*\S)\s*\n$/ || &quit("maintainers bogus \`$_'");
        $a= $1; $b= $2; $a =~ y/A-Z/a-z/;
        $maintainerof{$1}= $2;
    }
    close(MAINT);
    open(MAINT,"$gMaintainerFileOverride") || die &quit("maintainers.override open: $!");
    while (<MAINT>) {
        m/^\n$/ && next;
        m/^\s*$/ && next;
        m/^(\S+)\s+(\S.*\S)\s*\n$/ || &quit("maintainers.override bogus \`$_'");
        $a= $1; $b= $2; $a =~ y/A-Z/a-z/;
        $maintainerof{$1}= $2;
    }

    open(SOURCES, "$gPackageSource") || &quit("pkgsrc open: $!");
    while (<SOURCES>) {
	next unless m/^(\S+)\s+\S+\s+(\S.*\S)\s*$/;
	my ($a, $b) = ($1, $2);
	$pkgsrc{lc($a)} = $b;
    }
    close(SOURCES);
}

sub sendinfo {
    local ($wherefrom,$path,$description) = @_;
    if ($wherefrom eq "ftp.d.o") {
      $doc = `lynx -nolist -dump http://ftp.debian.org/debian/indices/$path.gz 2>&1 | gunzip -cf` or &quit("fork for lynx/gunzip: $!");
      $! = 0;
      if ($? == 255 && $doc =~ m/^\n*lynx: Can\'t access start file/) {
          &transcript("$description is not available.\n");
          $ok++; return;
      } elsif ($?) {
          &transcript("Error getting $description (code $? $!):\n$doc\n");
          return;
      }
    } elsif ($wherefrom eq "local") {
      open P, "$path";
      $doc = do { local $/; <P> };
      close P;
    } else {
      &transcript("internal errror: info files location unknown.\n");
      $ok++; return;
    }
    &transcript("Sending $description.\n");
    &sendmailmessage(<<END.$doc,$replyto);
From: $gMaintainerEmail ($gProject $gBug Tracking System)
To: $replyto
Subject: $gProject $gBugs information: $description
References: $header{'message-id'}
In-Reply-To: $header{'message-id'}
Message-ID: <handler.s.$nn.info.$midix\@$gEmailDomain>
Precedence: bulk

$description follows:

END
    $ok++;
    &transcript("\n");
}
