Introduction to string processing
=================================

stringproc.lisp enlarges Maximas capabilities of working with strings and adds some useful functions for file in/output.

For questions and bugs please mail to volkervannek at gmail dot com .

In Maxima a string is easily constructed by typing "text". stringp tests for strings.

     (%i1) m: "text";
     (%o1)                         text
     (%i2) stringp(m);
     (%o2)                         true

Characters are represented as strings of length 1. These are not Lisp characters. Tests can be done with charp (respectively lcharp and conversion from Lisp to Maxima characters with cunlisp).

     (%i1) c: "e";
     (%o1)                           e
     (%i2) [charp(c),lcharp(c)];
     (%o2)                     [true, false]
     (%i3) supcase(c);
     (%o3)                           E
     (%i4) charp(%);
     (%o4)                         true

All functions in stringproc.lisp that return characters, return Maxima-characters. Due to the fact, that the introduced characters are strings of length 1, you can use a lot of string functions also for characters. As seen, supcase is one example.

It is important to know, that the first character in a Maxima-string is at position 1. This is designed due to the fact that the first element in a Maxima-list is at position 1 too. See definitions of charat and charlist for examples.

In applications string-functions are often used when working with files. You will find some useful stream- and print-functions in stringproc.lisp. The following example shows some of the here introduced functions at work.

Example:

openw returns an output stream to a file, printf then allows formatted writing to this file. See printf for details.

     (%i1) s: openw("E:/file.txt");
     (%o1)                    #<output stream E:/file.txt>
     (%i2) for n:0 thru 10 do printf( s, "~d ", fib(n) );
     (%o2)                                done
     (%i3) printf( s, "~%~d ~f ~a ~a ~f ~e ~a~%",
                   42,1.234,sqrt(2),%pi,1.0e-2,1.0e-2,1.0b-2 );
     (%o3)                                false
     (%i4) close(s);
     (%o4)                                true

After closing the stream you can open it again, this time with input direction. readline returns the entire line as one string. The stringproc package now offers a lot of functions for manipulating strings. Tokenizing can be done by split or tokens.

     (%i5) s: openr("E:/file.txt");
     (%o5)                     #<input stream E:/file.txt>
     (%i6) readline(s);
     (%o6)                     0 1 1 2 3 5 8 13 21 34 55
     (%i7) line: readline(s);
     (%o7)               42 1.234 sqrt(2) %pi 0.01 1.0E-2 1.0b-2
     (%i8) list: tokens(line);
     (%o8)           [42, 1.234, sqrt(2), %pi, 0.01, 1.0E-2, 1.0b-2]
     (%i9) map( parse_string, list );
     (%o9)            [42, 1.234, sqrt(2), %pi, 0.01, 0.01, 1.0b-2]
     (%i10) float(%);
     (%o10) [42.0, 1.234, 1.414213562373095, 3.141592653589793, 0.01,
                                                          0.01, 0.01]
     (%i11) readline(s);
     (%o11)                               false
     (%i12) close(s)$

readline returns false when the end of file occurs.

Strings Share packages Package stringproc

Functions and Variables for input and output
============================================

Example:

     (%i1) s: openw("E:/file.txt");
     (%o1)                     #<output stream E:/file.txt>
     (%i2) control:
     "~2tAn atom: ~20t~a~%~2tand a list: ~20t~{~r ~}~%~2t\
     and an integer: ~20t~d~%"$
     (%i3) printf( s,control, 'true,[1,2,3],42 )$
     (%o3)                                false
     (%i4) close(s);
     (%o4)                                true
     (%i5) s: openr("E:/file.txt");
     (%o5)                     #<input stream E:/file.txt>
     (%i6) while stringp( tmp:readline(s) ) do print(tmp)$
       An atom:          true
       and a list:       one two three
       and an integer:   42
     (%i7) close(s)$

 -- Function: close (STREAM)
     Closes STREAM and returns true if STREAM had been open.

     File input File output Package stringproc

 -- Function: flength (STREAM)
     Returns the number of elements in STREAM where STREAM has to be a stream from or to a file.

     File input File output Package stringproc

 -- Function: fposition (STREAM)
 -- Function: fposition (STREAM, POS)

     Returns the current position in STREAM, if POS is not used. If POS is used, fposition sets the position in STREAM. STREAM has to be a stream from or to a file and POS has to be a positive number where the first element in STREAM is in position 1.

     File input File output Package stringproc

 -- Function: freshline ()
 -- Function: freshline (STREAM)
     Writes a new line (to STREAM), if the position is not at the beginning of a line. See also newline.

     File output Package stringproc

 -- Function: get_output_stream_string (STREAM)

     Returns a string containing all the characters currently present in STREAM which must be an open string-output stream. The returned characters are removed from STREAM.

     Example: See make_string_output_stream .

     Package stringproc

 -- Function: make_string_input_stream (STRING)
 -- Function: make_string_input_stream (STRING, START)
 -- Function: make_string_input_stream (STRING, START, END)

     Returns an input stream which contains parts of STRING and an end of file. Without optional arguments the stream contains the entire string and is positioned in front of the first character. START and END define the substring contained in the stream. The first character is available at position 1.

          (%i1) istream : make_string_input_stream("text", 1, 4);
          (%o1)              #<string-input stream from "text">
          (%i2) (while (c : readchar(istream)) # false do sprint(c), newline())$
          t e x
          (%i3) close(istream)$

     Package stringproc

 -- Function: make_string_output_stream ()

     Returns an output stream that accepts characters. Characters currently present in this stream can be retrieved by get_output_stream_string.

          (%i1) ostream : make_string_output_stream();
          (%o1)               #<string-output stream 09622ea0>
          (%i2) printf(ostream, "foo")$

          (%i3) printf(ostream, "bar")$

          (%i4) string : get_output_stream_string(ostream);
          (%o4)                            foobar
          (%i5) printf(ostream, "baz")$

          (%i6) string : get_output_stream_string(ostream);
          (%o6)                              baz
          (%i7) close(ostream)$

     Package stringproc

 -- Function: newline ()
 -- Function: newline (STREAM)
     Writes a new line (to STREAM). See sprint for an example of using newline(). Note that there are some cases, where newline() does not work as expected.

     File output Package stringproc

 -- Function: opena (FILE)
     Returns an output stream to FILE. If an existing file is opened, opena appends elements at the end of file.

     File output Package stringproc

 -- Function: openr (FILE)
     Returns an input stream to FILE. If FILE does not exist, it will be created.

     File input Package stringproc

 -- Function: openw (FILE)
     Returns an output stream to FILE. If FILE does not exist, it will be created. If an existing file is opened, openw destructively modifies FILE.

     File output Package stringproc

 -- Function: printf (DEST, STRING)
 -- Function: printf (DEST, STRING, EXPR_1, ..., EXPR_N)

     Produces formatted output by outputting the characters of control-string STRING and observing that a tilde introduces a directive. The character after the tilde, possibly preceded by prefix parameters and modifiers, specifies what kind of formatting is desired. Most directives use one or more elements of the arguments EXPR_1, ..., EXPR_N to create their output.

     If DEST is a stream or true, then printf returns false. Otherwise, printf returns a string containing the output.

     printf provides the Common Lisp function format in Maxima. The following example illustrates the general relation between these two functions.

          (%i1) printf(true, "R~dD~d~%", 2, 2);
          R2D2
          (%o1)                                false
          (%i2) :lisp (format t "R~dD~d~%" 2 2)
          R2D2
          NIL

     The following description is limited to a rough sketch of the possibilities of printf. The Lisp function format is described in detail in many reference books. Of good help is e.g. the free available online-manual "Common Lisp the Language" by Guy L. Steele. See chapter 22.3.3 there.

             ~%       new line
             ~&       fresh line
             ~t       tab
             ~$       monetary
             ~d       decimal integer
             ~b       binary integer
             ~o       octal integer
             ~x       hexadecimal integer
             ~br      base-b integer
             ~r       spell an integer
             ~p       plural
             ~f       floating point
             ~e       scientific notation
             ~g       ~f or ~e, depending upon magnitude
             ~h       bigfloat
             ~a       uses Maxima function string
             ~s       like ~a, but output enclosed in "double quotes"
             ~~       ~
             ~<       justification, ~> terminates
             ~(       case conversion, ~) terminates
             ~[       selection, ~] terminates
             ~{       iteration, ~} terminates

     The directive ~h for bigfloat is no Lisp-standard and is therefore illustrated below.

     Note that the directive ~* is not supported.

     If DEST is a stream or true, then printf returns false. Otherwise, printf returns a string containing the output.

          (%i1) printf( false, "~a ~a ~4f ~a ~@r",
                        "String",sym,bound,sqrt(12),144), bound = 1.234;
          (%o1)                 String sym 1.23 2*sqrt(3) CXLIV
          (%i2) printf( false,"~{~a ~}",["one",2,"THREE"] );
          (%o2)                          one 2 THREE
          (%i3) printf(true,"~{~{~9,1f ~}~%~}",mat ),
                    mat = args(matrix([1.1,2,3.33],[4,5,6],[7,8.88,9]))$
                1.1       2.0       3.3
                4.0       5.0       6.0
                7.0       8.9       9.0
          (%i4) control: "~:(~r~) bird~p ~[is~;are~] singing."$
          (%i5) printf( false,control, n,n,if n=1 then 1 else 2 ), n=2;
          (%o5)                    Two birds are singing.

     The directive ~h has been introduced to handle bigfloats.

          ~w,d,e,x,o,p@H
           w : width
           d : decimal digits behind floating point
           e : minimal exponent digits
           x : preferred exponent
           o : overflow character
           p : padding character
           @ : display sign for positive numbers

          (%i1) fpprec : 1000$
          (%i2) printf(true, "|~h|~%", 2.b0^-64)$
          |0.0000000000000000000542101086242752217003726400434970855712890625|
          (%i3) fpprec : 26$
          (%i4) printf(true, "|~h|~%", sqrt(2))$
          |1.4142135623730950488016887|
          (%i5) fpprec : 24$
          (%i6) printf(true, "|~h|~%", sqrt(2))$
          |1.41421356237309504880169|
          (%i7) printf(true, "|~28h|~%", sqrt(2))$
          |   1.41421356237309504880169|
          (%i8) printf(true, "|~28,,,,,'*h|~%", sqrt(2))$
          |***1.41421356237309504880169|
          (%i9) printf(true, "|~,18h|~%", sqrt(2))$
          |1.414213562373095049|
          (%i10) printf(true, "|~,,,-3h|~%", sqrt(2))$
          |1414.21356237309504880169b-3|
          (%i11) printf(true, "|~,,2,-3h|~%", sqrt(2))$
          |1414.21356237309504880169b-03|
          (%i12) printf(true, "|~20h|~%", sqrt(2))$
          |1.41421356237309504880169|
          (%i13) printf(true, "|~20,,,,'+h|~%", sqrt(2))$
          |++++++++++++++++++++|

     File output Package stringproc

 -- Function: readchar (STREAM)

     Removes and returns the first character in STREAM. If the end of file is encountered readchar returns false.

     Example: See make_string_input_stream.

     File input Package stringproc

 -- Function: readline (STREAM)
     Returns a string containing the characters from the current position in STREAM up to the end of the line or false if the end of the file is encountered.

     File input Package stringproc

 -- Function: sprint (EXPR_1, ..., EXPR_N)

     Evaluates and displays its arguments one after the other `on a line' starting at the leftmost position.  The numbers are printed with the '-' right next to the number, and it disregards line length.  newline(), which will be autoloaded from stringproc.lisp might be useful, if you whish to place intermediate line breaking.

     Example:

          (%i1) for n:0 thru 19 do sprint( fib(n) )$
          0 1 1 2 3 5 8 13 21 34 55 89 144 233 377 610 987 1597 2584 4181
          (%i2) for n:0 thru 22 do (
                   sprint(fib(n)), if mod(n,10)=9 then newline() )$
          0 1 1 2 3 5 8 13 21 34
          55 89 144 233 377 610 987 1597 2584 4181
          6765 10946 17711

     Package stringproc

Functions and Variables for characters
======================================

 -- Function: alphacharp (CHAR)
     Returns true if CHAR is an alphabetic character.

     Predicate functions Package stringproc

 -- Function: alphanumericp (CHAR)
     Returns true if CHAR is an alphabetic character or a digit.

     Predicate functions Package stringproc

 -- Function: ascii (INT)
     Returns the character corresponding to the ASCII number INT. ( -1 < int < 256 )

          (%i1) for n from 0 thru 255 do (
             tmp: ascii(n), if alphacharp(tmp) then sprint(tmp),
                if n=96 then newline() )$
          A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
          a b c d e f g h i j k l m n o p q r s t u v w x y z

     Package stringproc

 -- Function: cequal (CHAR_1, CHAR_2)
     Returns true if CHAR_1 and CHAR_2 are the same.

     Predicate functions Package stringproc

 -- Function: cequalignore (CHAR_1, CHAR_2)
     Like cequal but ignores case.

     Predicate functions Package stringproc

 -- Function: cgreaterp (CHAR_1, CHAR_2)
     Returns true if the ASCII number of CHAR_1 is greater than the number of CHAR_2.

     Predicate functions Package stringproc

 -- Function: cgreaterpignore (CHAR_1, CHAR_2)
     Like cgreaterp but ignores case.

     Predicate functions Package stringproc

 -- Function: charp (OBJ)
     Returns true if OBJ is a Maxima-character. See introduction for example.

     Predicate functions Package stringproc

 -- Function: cint (CHAR)
     Returns the ASCII number of CHAR.

     Package stringproc

 -- Function: clessp (CHAR_1, CHAR_2)
     Returns true if the ASCII number of CHAR_1 is less than the number of CHAR_2.

     Predicate functions Package stringproc

 -- Function: clesspignore (CHAR_1, CHAR_2)
     Like clessp but ignores case.

     Predicate functions Package stringproc

 -- Function: constituent (CHAR)
     Returns true if CHAR is a graphic character and not the space character. A graphic character is a character one can see, plus the space character. (constituent is defined by Paul Graham, ANSI Common Lisp, 1996, page 67.)

          (%i1) for n from 0 thru 255 do (
          tmp: ascii(n), if constituent(tmp) then sprint(tmp) )$
          ! " #  %  ' ( ) * + , - . / 0 1 2 3 4 5 6 7 8 9 : ; < = > ? @ A B
          C D E F G H I J K L M N O P Q R S T U V W X Y Z [ \ ] ^ _ ` a b c
          d e f g h i j k l m n o p q r s t u v w x y z { | } ~

     Predicate functions Package stringproc

 -- Function: cunlisp (LISP_CHAR)
     Converts a Lisp-character into a Maxima-character. (You won't need it.)

     Package stringproc

 -- Function: digitcharp (CHAR)
     Returns true if CHAR is a digit.

     Predicate functions Package stringproc

 -- Function: lcharp (OBJ)
     Returns true if OBJ is a Lisp-character. (You won't need it.)

     Predicate functions Package stringproc

 -- Function: lowercasep (CHAR)
     Returns true if CHAR is a lowercase character.

     Predicate functions Package stringproc

 -- Variable: newline
     The newline character.

     Global variables Package stringproc

 -- Variable: space
     The space character.

     Global variables Package stringproc

 -- Variable: tab
     The tab character.

     Global variables Package stringproc

 -- Function: uppercasep (CHAR)
     Returns true if CHAR is an uppercase character.

     Predicate functions Package stringproc

Functions and Variables for strings
===================================

 -- Function: base64 (STRING)

     Returns the base64-representation of STRING as a string.

     Example:

          (%i1) base64 : base64("foo bar baz");
          (%o1)                       Zm9vIGJhciBiYXo=
          (%i2) string : base64_decode(base64);
          (%o2)                          foo bar baz

     Package stringproc

 -- Function: base64_decode (BASE64-STRING)

     Decodes the string BASE64-STRING coded in base64 back to the original string.

     Example: See base64.

     Package stringproc

 -- Function: charat (STRING, N)
     Returns the N-th character of STRING. The first character in STRING is returned with N = 1.

          (%i1) charat("Lisp",1);
          (%o1)                           L

     Package stringproc

 -- Function: charlist (STRING)
     Returns the list of all characters in STRING.

          (%i1) charlist("Lisp");
          (%o1)                     [L, i, s, p]
          (%i2) %[1];
          (%o2)                           L

     Package stringproc

 -- Function: eval_string (STR)
     Parse the string STR as a Maxima expression and evaluate it. The string STR may or may not have a terminator (dollar sign $ or semicolon ;). Only the first expression is parsed and evaluated, if there is more than one.

     Complain if STR is not a string.

     Examples:

          (%i1) eval_string ("foo: 42; bar: foo^2 + baz");
          (%o1)                       42
          (%i2) eval_string ("(foo: 42, bar: foo^2 + baz)");
          (%o2)                   baz + 1764

     See also parse_string.

     Package stringproc

 -- Function: md5sum (STRING)

     Returns the md5 checksum of a STRING. The return value is a string to guarantee 32 hex characters. To parse the returned value into an integer please set the input base to 16 and prefix the string by zero.

     Example:

          (%i1) string : md5sum("foo bar baz");
          (%o1)                  ab07acbb1e496801937adfa772424bf7
          (%i2) ibase : obase : 16.$

          (%i3) integer : parse_string(sconcat(0, string));
          (%o3)                 0ab07acbb1e496801937adfa772424bf7

     Package stringproc

 -- Function: parse_string (STR)
     Parse the string STR as a Maxima expression (do not evaluate it). The string STR may or may not have a terminator (dollar sign $ or semicolon ;). Only the first expression is parsed, if there is more than one.

     Complain if STR is not a string.

     Examples:

          (%i1) parse_string ("foo: 42; bar: foo^2 + baz");
          (%o1)                    foo : 42
          (%i2) parse_string ("(foo: 42, bar: foo^2 + baz)");
                                             2
          (%o2)          (foo : 42, bar : foo  + baz)

     See also eval_string.

     Package stringproc

 -- Function: scopy (STRING)
     Returns a copy of STRING as a new string.

     Package stringproc

 -- Function: sdowncase (STRING)
 -- Function: sdowncase (STRING, START)
 -- Function: sdowncase (STRING, START, END)
     Like supcase, but uppercase characters are converted to lowercase.

     Package stringproc

 -- Function: sequal (STRING_1, STRING_2)
     Returns true if STRING_1 and STRING_2 are the same length and contain the same characters.

     Predicate functions Package stringproc

 -- Function: sequalignore (STRING_1, STRING_2)
     Like sequal but ignores case.

     Predicate functions Package stringproc

 -- Function: sexplode (STRING)
     sexplode is an alias for function charlist.

     Package stringproc

 -- Function: sha1sum (STRING)

     Returns the sha1 fingerprint of a STRING. The return value is a string to guarantee 48 hex characters. To parse the returned value into an integer please set the input base to 16 and prefix the string by zero.

     Example:

          (%i1) string : sha1sum("foo bar baz");
          (%o1)              c7567e8b39e2428e38bf9c9226ac68de4c67dc39
          (%i2) ibase : obase : 16.$

          (%i3) integer : parse_string(sconcat(0, string));
          (%o3)              0c7567e8b39e2428e38bf9c9226ac68de4c67dc39

     Package stringproc

 -- Function: simplode (LIST)
 -- Function: simplode (LIST, DELIM)
     simplode takes a list of expressions and concatenates them into a string. If no delimiter DELIM is specified, simplode uses no delimiter. DELIM can be any string.

          (%i1) simplode(["xx[",3,"]:",expand((x+y)^3)]);
          (%o1)             xx[3]:y^3+3*x*y^2+3*x^2*y+x^3
          (%i2) simplode( sexplode("stars")," * " );
          (%o2)                   s * t * a * r * s
          (%i3) simplode( ["One","more","coffee."]," " );
          (%o3)                   One more coffee.

     Package stringproc

 -- Function: sinsert (SEQ, STRING, POS)
     Returns a string that is a concatenation of substring (STRING, 1, POS - 1), the string SEQ and substring (STRING, POS). Note that the first character in STRING is in position 1.

          (%i1) s: "A submarine."$
          (%i2) concat( substring(s,1,3),"yellow ",substring(s,3) );
          (%o2)                  A yellow submarine.
          (%i3) sinsert("hollow ",s,3);
          (%o3)                  A hollow submarine.

     Package stringproc

 -- Function: sinvertcase (STRING)
 -- Function: sinvertcase (STRING, START)
 -- Function: sinvertcase (STRING, START, END)
     Returns STRING except that each character from position START to END is inverted. If END is not given, all characters from START to the end of STRING are replaced.

          (%i1) sinvertcase("sInvertCase");
          (%o1)                      SiNVERTcASE

     Package stringproc

 -- Function: slength (STRING)
     Returns the number of characters in STRING.

     Package stringproc

 -- Function: smake (NUM, CHAR)
     Returns a new string with a number of NUM characters CHAR.

          (%i1) smake(3,"w");
          (%o1)                          www

     Package stringproc

 -- Function: smismatch (STRING_1, STRING_2)
 -- Function: smismatch (STRING_1, STRING_2, TEST)
     Returns the position of the first character of STRING_1 at which STRING_1 and STRING_2 differ or false. Default test function for matching is sequal. If smismatch should ignore case, use sequalignore as test.

          (%i1) smismatch("seven","seventh");
          (%o1)                           6

     Package stringproc

 -- Function: split (STRING)
 -- Function: split (STRING, DELIM)
 -- Function: split (STRING, DELIM, MULTIPLE)
     Returns the list of all tokens in STRING. Each token is an unparsed string. split uses DELIM as delimiter. If DELIM is not given, the space character is the default delimiter. MULTIPLE is a boolean variable with true by default. Multiple delimiters are read as one. This is useful if tabs are saved as multiple space characters. If MULTIPLE is set to false, each delimiter is noted.

          (%i1) split("1.2   2.3   3.4   4.5");
          (%o1)                 [1.2, 2.3, 3.4, 4.5]
          (%i2) split("first;;third;fourth",";",false);
          (%o2)               [first, , third, fourth]

     Package stringproc

 -- Function: sposition (CHAR, STRING)
     Returns the position of the first character in STRING which matches CHAR. The first character in STRING is in position 1. For matching characters ignoring case see ssearch.

     Package stringproc

 -- Function: sremove (SEQ, STRING)
 -- Function: sremove (SEQ, STRING, TEST)
 -- Function: sremove (SEQ, STRING, TEST, START)
 -- Function: sremove (SEQ, STRING, TEST, START, END)
     Returns a string like STRING but without all substrings matching SEQ. Default test function for matching is sequal. If sremove should ignore case while searching for SEQ, use sequalignore as test. Use START and END to limit searching. Note that the first character in STRING is in position 1.

          (%i1) sremove("n't","I don't like coffee.");
          (%o1)                   I do like coffee.
          (%i2) sremove ("DO ",%,'sequalignore);
          (%o2)                    I like coffee.

     Package stringproc

 -- Function: sremovefirst (SEQ, STRING)
 -- Function: sremovefirst (SEQ, STRING, TEST)
 -- Function: sremovefirst (SEQ, STRING, TEST, START)
 -- Function: sremovefirst (SEQ, STRING, TEST, START, END)
     Like sremove except that only the first substring that matches seq is removed.

     Package stringproc

 -- Function: sreverse (STRING)
     Returns a string with all the characters of STRING in reverse order.

     Package stringproc

 -- Function: ssearch (SEQ, STRING)
 -- Function: ssearch (SEQ, STRING, TEST)
 -- Function: ssearch (SEQ, STRING, TEST, START)
 -- Function: ssearch (SEQ, STRING, TEST, START, END)
     Returns the position of the first substring of STRING that matches the string SEQ. Default test function for matching is sequal. If ssearch should ignore case, use sequalignore as test. Use START and END to limit searching. Note that the first character in STRING is in position 1.

          (%i1) ssearch("~s","~{~S ~}~%",'sequalignore);
          (%o1)                                  4

     Package stringproc

 -- Function: ssort (STRING)
 -- Function: ssort (STRING, TEST)
     Returns a string that contains all characters from STRING in an order such there are no two successive characters C and D such that test (C, D) is false and test (D, C) is true. Default test function for sorting is CLESSP. The set of test functions is {clessp, clesspignore, cgreaterp, cgreaterpignore, cequal, cequalignore}.

          (%i1) ssort("I don't like Mondays.");
          (%o1)                    '.IMaddeiklnnoosty
          (%i2) ssort("I don't like Mondays.",'cgreaterpignore);
          (%o2)                 ytsoonnMlkIiedda.'

     Package stringproc

 -- Function: ssubst (NEW, OLD, STRING)
 -- Function: ssubst (NEW, OLD, STRING, TEST)
 -- Function: ssubst (NEW, OLD, STRING, TEST, START)
 -- Function: ssubst (NEW, OLD, STRING, TEST, START, END)
     Returns a string like STRING except that all substrings matching OLD are replaced by NEW. OLD and NEW need not to be of the same length. Default test function for matching is sequal. If ssubst should ignore case while searching for old, use sequalignore as test. Use START and END to limit searching. Note that the first character in STRING is in position 1.

          (%i1) ssubst("like","hate","I hate Thai food. I hate green tea.");
          (%o1)          I like Thai food. I like green tea.
          (%i2) ssubst("Indian","thai",%,'sequalignore,8,12);
          (%o2)         I like Indian food. I like green tea.

     Package stringproc

 -- Function: ssubstfirst (NEW, OLD, STRING)
 -- Function: ssubstfirst (NEW, OLD, STRING, TEST)
 -- Function: ssubstfirst (NEW, OLD, STRING, TEST, START)
 -- Function: ssubstfirst (NEW, OLD, STRING, TEST, START, END)
     Like subst except that only the first substring that matches OLD is replaced.

     Package stringproc

 -- Function: strim (SEQ,STRING)
     Returns a string like STRING, but with all characters that appear in SEQ removed from both ends.

          (%i1) "/* comment */"$
          (%i2) strim(" /*",%);
          (%o2)                        comment
          (%i3) slength(%);
          (%o3)                           7

     Package stringproc

 -- Function: striml (SEQ, STRING)
     Like strim except that only the left end of STRING is trimmed.

     Package stringproc

 -- Function: strimr (SEQ, STRING)
     Like strim except that only the right end of string is trimmed.

     Package stringproc

 -- Function: stringp (OBJ)
     Returns true if OBJ is a string. See introduction for example.

     Predicate functions Package stringproc

 -- Function: substring (STRING, START)
 -- Function: substring (STRING, START, END)
     Returns the substring of STRING beginning at position START and ending at position END. The character at position END is not included. If END is not given, the substring contains the rest of the string. Note that the first character in STRING is in position 1.

          (%i1) substring("substring",4);
          (%o1)                        string
          (%i2) substring(%,4,6);
          (%o2)                          in

     Package stringproc

 -- Function: supcase (STRING)
 -- Function: supcase (STRING, START)
 -- Function: supcase (STRING, START, END)
     Returns STRING except that lowercase characters from position START to END are replaced by the corresponding uppercase ones. If END is not given, all lowercase characters from START to the end of STRING are replaced.

          (%i1) supcase("english",1,2);
          (%o1)                        English

     Package stringproc

 -- Function: tokens (STRING)
 -- Function: tokens (STRING, TEST)
     Returns a list of tokens, which have been extracted from STRING. The tokens are substrings whose characters satisfy a certain test function. If test is not given, CONSTITUENT is used as the default test. {constituent, alphacharp, digitcharp, lowercasep, uppercasep, charp, characterp, alphanumericp} is the set of test functions. (The Lisp-version of tokens is written by Paul Graham. ANSI Common Lisp, 1996, page 67.)

          (%i1) tokens("24 October 2005");
          (%o1)                  [24, October, 2005]
          (%i2) tokens("05-10-24",'digitcharp);
          (%o2)                     [05, 10, 24]
          (%i3) map(parse_string,%);
          (%o3)                      [5, 10, 24]

     Package stringproc