#!@PERL@ -w
#
# Converts cvs diffs containing added or removed to files
# so that they patch correctly with patch(1)
#
# usage: fixcvsdiff [-p] [-b] [files to fix]
#
# -p prints the cvs commands that will be needed when applying
# the patch.
#
# -b keeps a .bak backup file
#
# Based on code by Amir Karger <karger@post.harvard.edu>
#
# Modified by John Levon <moz@compsoc.man.ac.uk>
# Contributed under the terms of the GNU GPL v2 or later:
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or (at
# your option) any later version.

use Getopt::Std;
our ($opt_b,$opt_p);
$add = 0;

getopts('pb');

if (defined($opt_b)) {
	$^I = '.bak';
} else {
	$^I = '';
}

while (<>) {
	# get the diff fragment filename
	if (/^Index: (.*)/) {
		$Filename = $1;
	}

	if (!defined($Filename)) {
		print;
		next;
	}

  	if (/^--- \/dev\/null/) {
		if (defined($opt_p)) {
			print STDOUT "cvs add $Filename\n";
		}
		$add = 1;
	}

	if (/^\+\+\+ \/dev\/null/) {
		if (defined($opt_p)) {
			print STDOUT "cvs remove $Filename\n";
		}
	}

	# replace :
	# --- /tmp/cvsbOZJaV
	# with :
	# --- $Filename
	if (/^--- \/tmp\/cvs/) {
		s!^--- /tmp/cvs\S*!--- $Filename!;
	}
	# replace :
	# +++ indexdlg.C
	# with :
	# +++ $Filename
	elsif (/^\+\+\+ [^\/]*/) {
		if ($add == 1) {
			s!\+\+\+ [^/]\S*!+++ $Filename!;
			$add = 0;
		}
	}
	print;
}
