Index: PythonQt2.0.1/CMakeLists.txt
===================================================================
--- /dev/null	1970-01-01 00:00:00.000000000 +0000
+++ PythonQt2.0.1/CMakeLists.txt	2011-03-06 19:23:17.000000000 +0100
@@ -0,0 +1,266 @@
+cmake_minimum_required(VERSION 2.8)
+
+#-----------------------------------------------------------------------------
+# See http://cmake.org/cmake/help/cmake-2-8-docs.html#section_Policies for details
+#
+
+SET(project_policies
+  CMP0001 # NEW: CMAKE_BACKWARDS_COMPATIBILITY should no longer be used.
+  CMP0002 # NEW: Logical target names must be globally unique.
+  CMP0003 # NEW: Libraries linked via full path no longer produce linker search paths.
+  CMP0004 # NEW: Libraries linked may NOT have leading or trailing whitespace.
+  CMP0005 # NEW: Preprocessor definition values are now escaped automatically.
+  CMP0006 # NEW: Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION.
+  CMP0007 # NEW: List command no longer ignores empty elements.
+  CMP0008 # NEW: Libraries linked by full-path must have a valid library file name.
+  CMP0009 # NEW: FILE GLOB_RECURSE calls should not follow symlinks by default.
+  CMP0010 # NEW: Bad variable reference syntax is an error.
+  CMP0011 # NEW: Included scripts do automatic cmake_policy PUSH and POP.
+  CMP0012 # NEW: if() recognizes numbers and boolean constants.
+  CMP0013 # NEW: Duplicate binary directories are not allowed.
+  CMP0014 # NEW: Input directories must have CMakeLists.txt
+  )
+FOREACH(policy ${project_policies})
+  IF(POLICY ${policy})
+    CMAKE_POLICY(SET ${policy} NEW)
+  ENDIF()
+ENDFOREACH()
+
+#-----------------------------------------------------------------------------
+project(PythonQt)
+
+set(PythonQt_MAJOR_VERSION 2)
+set(PythonQt_MINOR_VERSION 0)
+set(PythonQt_BUILD_VERSION 1)
+set(PythonQt_VERSION
+  "${PythonQt_MAJOR_VERSION}.${PythonQt_MINOR_VERSION}.${PythonQt_BUILD_VERSION}")
+set(PythonQt_API_VERSION
+  "${PythonQt_MAJOR_VERSION}.${PythonQt_MINOR_VERSION}")
+set(PythonQt_LIBRARY_PROPERTIES ${PythonQt_LIBRARY_PROPERTIES}
+  VERSION "${PythonQt_VERSION}"
+  SOVERSION "${PythonQt_API_VERSION}"
+)
+
+#-----------------------------------------------------------------------------
+
+#-----------------------------------------------------------------------------
+# Python libraries
+
+find_package(PythonLibs REQUIRED)
+include_directories("${PYTHON_INCLUDE_DIR}")
+
+#-----------------------------------------------------------------------------
+# VTK
+
+option(PythonQt_USE_VTK "Automatically wrap/unwrap VTK based object" OFF)
+set(VTK_LIBRARIES)
+if(PythonQt_USE_VTK)
+  find_package(VTK REQUIRED)
+  include(${VTK_USE_FILE})
+  add_definitions(-DPYTHONQT_USE_VTK)
+  set(VTK_LIBRARIES vtkPythonCore)
+else()
+  remove_definitions(-DPYTHONQT_USE_VTK)
+endif()
+
+#-----------------------------------------------------------------------------
+# Build options
+
+foreach(qtlib core gui network opengl sql svg uitools webkit xml xmlpatterns)
+  OPTION(PythonQt_Wrap_Qt${qtlib} "Make all of Qt${qtlib} available in python" OFF)
+endforeach()
+
+option(PythonQt_DEBUG "Enable/Disable PythonQt debug output" OFF)
+if(PythonQt_DEBUG)
+  add_definitions(-DPYTHONQT_DEBUG)
+else()
+  remove_definitions(-DPYTHONQT_DEBUG)
+endif()
+
+#-----------------------------------------------------------------------------
+# Setup Qt
+
+set(minimum_required_qt_version "4.6.2")
+
+find_package(Qt4)
+
+if(QT4_FOUND)
+
+  set(found_qt_version ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH})
+
+  if(${found_qt_version} VERSION_LESS ${minimum_required_qt_version})
+      message(FATAL_ERROR "error: PythonQt requires Qt >= ${minimum_required_qt_version} -- you cannot use Qt ${found_qt_version}.")
+  endif()
+  
+  # Enable required qt module
+  foreach(qtlib network opengl sql svg uitools webkit xml xmlpatterns)
+    string(TOUPPER ${qtlib} qtlib_uppercase)
+    if (NOT ${QT_QT${qtlib_uppercase}_FOUND})
+      message(FATAL_ERROR "QT_QT${${qtlib_uppercase} *not* FOUND - Try to disable PythonQt_Wrap_Qt${qtlib}")
+    endif()
+    set(QT_USE_QT${qtlib_uppercase} ${PythonQt_Wrap_Qt${qtlib}})
+  endforeach()
+  
+  include(${QT_USE_FILE})
+else()
+  message(FATAL_ERROR "error: Qt4 was not found on your system. You probably need to set the QT_QMAKE_EXECUTABLE variable")
+endif()
+
+#-----------------------------------------------------------------------------
+# Sources
+
+set(sources
+    src/PythonQtClassInfo.cpp
+    src/PythonQtClassWrapper.cpp
+    src/PythonQtConversion.cpp
+    src/PythonQt.cpp
+    src/PythonQtImporter.cpp
+    src/PythonQtInstanceWrapper.cpp
+    src/PythonQtMethodInfo.cpp
+    src/PythonQtMisc.cpp
+    src/PythonQtObjectPtr.cpp
+    src/PythonQtQFileImporter.cpp
+    src/PythonQtSignalReceiver.cpp
+    src/PythonQtSlot.cpp
+    src/PythonQtStdDecorators.cpp
+    #src/PythonQtStdIn.cpp
+    src/PythonQtStdOut.cpp
+    src/gui/PythonQtScriptingConsole.cpp
+    
+    #generated_cpp/PythonQt_QtBindings.cpp
+
+    generated_cpp/com_trolltech_qt_core_builtin/com_trolltech_qt_core_builtin0.cpp
+    generated_cpp/com_trolltech_qt_core_builtin/com_trolltech_qt_core_builtin_init.cpp
+    generated_cpp/com_trolltech_qt_gui_builtin/com_trolltech_qt_gui_builtin0.cpp
+    generated_cpp/com_trolltech_qt_gui_builtin/com_trolltech_qt_gui_builtin_init.cpp
+)
+
+#-----------------------------------------------------------------------------
+# List headers.  This is list is used for the install command.
+
+set(headers
+    src/PythonQtClassInfo.h
+    src/PythonQtClassWrapper.h
+    src/PythonQtConversion.h
+    src/PythonQtCppWrapperFactory.h
+    src/PythonQtDoc.h
+    src/PythonQt.h
+    src/PythonQtImporter.h
+    src/PythonQtImportFileInterface.h
+    src/PythonQtInstanceWrapper.h
+    src/PythonQtMethodInfo.h
+    src/PythonQtMisc.h
+    src/PythonQtObjectPtr.h
+    src/PythonQtQFileImporter.h
+    src/PythonQtSignalReceiver.h
+    src/PythonQtSlot.h
+    src/PythonQtStdDecorators.h
+    #src/PythonQtStdIn.h
+    src/PythonQtStdOut.h
+    src/PythonQtSystem.h
+    src/PythonQtVariants.h
+    #src/dPython.h
+    #generated_cpp/PythonQt_QtBindings.h
+)
+
+#-----------------------------------------------------------------------------
+# Headers that should run through moc
+
+set(moc_sources
+    src/PythonQt.h
+    src/PythonQtSignalReceiver.h
+    src/PythonQtStdDecorators.h
+    src/gui/PythonQtScriptingConsole.h
+
+    generated_cpp/com_trolltech_qt_core_builtin/com_trolltech_qt_core_builtin0.h
+    generated_cpp/com_trolltech_qt_gui_builtin/com_trolltech_qt_gui_builtin0.h
+)
+
+#-----------------------------------------------------------------------------
+# Add extra sources
+foreach(qtlib core gui network opengl sql svg uitools webkit xml xmlpatterns)
+  
+  if (${PythonQt_Wrap_Qt${qtlib}})
+    
+    ADD_DEFINITIONS(-DPYTHONQT_WRAP_Qt${qtlib})
+    
+    set(file_prefix generated_cpp/com_trolltech_qt_${qtlib}/com_trolltech_qt_${qtlib})
+    
+    foreach(index RANGE 0 10)
+    
+      # Source files
+      if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${file_prefix}${index}.cpp)
+        list(APPEND sources ${file_prefix}${index}.cpp)
+      endif()
+      
+      # Headers that should run through moc
+      if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${file_prefix}${index}.h)
+        list(APPEND moc_sources ${file_prefix}${index}.h)
+      endif()
+      
+    endforeach()
+    
+    list(APPEND sources ${file_prefix}_init.cpp)
+
+  endif()
+endforeach()
+
+#-----------------------------------------------------------------------------
+# UI files
+set(ui_sources )
+
+#-----------------------------------------------------------------------------
+# Resources
+set(qrc_sources )
+
+#-----------------------------------------------------------------------------
+# Do wrapping
+qt4_wrap_cpp(gen_moc_sources ${moc_sources})
+qt4_wrap_ui(gen_ui_sources ${ui_sources})
+qt4_add_resources(gen_qrc_sources ${qrc_sources})
+
+#-----------------------------------------------------------------------------
+# Build the library
+
+include_directories(
+  ${CMAKE_CURRENT_SOURCE_DIR}/src
+  )
+  
+add_library(PythonQt SHARED
+            ${sources}
+            ${gen_moc_sources}
+            ${gen_ui_sources}
+            ${gen_qrc_sources}
+  )
+set_target_properties(PythonQt PROPERTIES DEFINE_SYMBOL PYTHONQT_EXPORTS)
+set_target_properties(PythonQt PROPERTIES ${PythonQt_LIBRARY_PROPERTIES})
+
+foreach(source ${gen_moc_sources})
+  string(REGEX MATCH "PythonQtStdDecorators" match ${source})
+  if(match)
+    set_property(SOURCE ${source} PROPERTY COMPILE_FLAGS -DQT_NO_KEYWORDS)
+  endif(match)
+endforeach(source {gen_moc_sources})
+
+#
+# That should solve linkage error on Mac when the project is used in a superbuild setup
+# See http://blog.onesadcookie.com/2008/01/installname-magic.html
+#
+set_target_properties(PythonQt  PROPERTIES
+  INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/lib"
+  )
+
+target_link_libraries(PythonQt
+              ${PYTHON_LIBRARY}
+              ${QT_LIBRARIES}
+              ${VTK_LIBRARIES}
+  )
+
+#-----------------------------------------------------------------------------
+# Install library (on windows, put the dll in 'bin' and the archive in 'lib')
+
+install(TARGETS PythonQt
+        RUNTIME DESTINATION bin
+        LIBRARY DESTINATION lib
+        ARCHIVE DESTINATION lib)
+install(FILES ${headers} DESTINATION include/PythonQt)
Index: PythonQt2.0.1/generator/CMakeLists.txt
===================================================================
--- /dev/null	1970-01-01 00:00:00.000000000 +0000
+++ PythonQt2.0.1/generator/CMakeLists.txt	2011-03-06 19:23:17.000000000 +0100
@@ -0,0 +1,186 @@
+cmake_minimum_required(VERSION 2.8)
+
+#-----------------------------------------------------------------------------
+# See http://cmake.org/cmake/help/cmake-2-8-docs.html#section_Policies for details
+#
+
+SET(project_policies
+  CMP0001 # NEW: CMAKE_BACKWARDS_COMPATIBILITY should no longer be used.
+  CMP0002 # NEW: Logical target names must be globally unique.
+  CMP0003 # NEW: Libraries linked via full path no longer produce linker search paths.
+  CMP0004 # NEW: Libraries linked may NOT have leading or trailing whitespace.
+  CMP0005 # NEW: Preprocessor definition values are now escaped automatically.
+  CMP0006 # NEW: Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION.
+  CMP0007 # NEW: List command no longer ignores empty elements.
+  CMP0008 # NEW: Libraries linked by full-path must have a valid library file name.
+  CMP0009 # NEW: FILE GLOB_RECURSE calls should not follow symlinks by default.
+  CMP0010 # NEW: Bad variable reference syntax is an error.
+  CMP0011 # NEW: Included scripts do automatic cmake_policy PUSH and POP.
+  CMP0012 # NEW: if() recognizes numbers and boolean constants.
+  CMP0013 # NEW: Duplicate binary directories are not allowed.
+  CMP0014 # NEW: Input directories must have CMakeLists.txt
+  )
+FOREACH(policy ${project_policies})
+  IF(POLICY ${policy})
+    CMAKE_POLICY(SET ${policy} NEW)
+  ENDIF()
+ENDFOREACH()
+
+#-----------------------------------------------------------------------------
+project(PythonQtGenerator)
+#-----------------------------------------------------------------------------
+
+#-----------------------------------------------------------------------------
+# Setup Qt
+
+set(minimum_required_qt_version "4.6.2")
+
+find_package(Qt4)
+
+if(QT4_FOUND)
+
+  set(found_qt_version ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH})
+
+  if(${found_qt_version} VERSION_LESS ${minimum_required_qt_version})
+      message(FATAL_ERROR "error: PythonQt requires Qt >= ${minimum_required_qt_version} -- you cannot use Qt ${found_qt_version}.")
+  endif()
+  
+  set(QT_USE_QTXML ON)
+  
+  include(${QT_USE_FILE})
+else()
+  message(FATAL_ERROR "error: Qt4 was not found on your system. You probably need to set the QT_QMAKE_EXECUTABLE variable")
+endif()
+
+#-----------------------------------------------------------------------------
+# Sources
+
+set(sources
+  parser/ast.cpp
+  parser/binder.cpp
+  parser/class_compiler.cpp
+  parser/codemodel.cpp
+  parser/codemodel_finder.cpp
+  parser/compiler_utils.cpp
+  parser/control.cpp
+  parser/declarator_compiler.cpp
+  parser/default_visitor.cpp
+  parser/dumptree.cpp
+  parser/lexer.cpp
+  parser/list.cpp
+  parser/name_compiler.cpp
+  parser/parser.cpp
+  parser/smallobject.cpp
+  parser/tokens.cpp
+  parser/type_compiler.cpp
+  parser/visitor.cpp
+  
+  abstractmetabuilder.cpp
+  abstractmetalang.cpp
+  asttoxml.cpp
+  customtypes.cpp
+  fileout.cpp
+  generator.cpp
+  generatorset.cpp
+  generatorsetqtscript.cpp
+  main.cpp
+  metajava.cpp
+  metaqtscriptbuilder.cpp
+  metaqtscript.cpp
+  prigenerator.cpp
+  reporthandler.cpp
+  setupgenerator.cpp
+  shellgenerator.cpp
+  shellheadergenerator.cpp
+  shellimplgenerator.cpp
+  typeparser.cpp
+  typesystem.cpp
+  )
+  
+#-----------------------------------------------------------------------------
+# List headers.  This list is used for the install command.
+
+set(headers
+  )
+
+#-----------------------------------------------------------------------------
+# Headers that should run through moc
+
+set(moc_sources
+  fileout.h
+  generator.h
+  generatorset.h
+  generatorsetqtscript.h
+  prigenerator.h
+  setupgenerator.h
+  shellgenerator.h
+  shellheadergenerator.h
+  shellimplgenerator.h
+  )
+  
+#-----------------------------------------------------------------------------
+# UI files
+
+set(ui_sources )
+
+#-----------------------------------------------------------------------------
+# Resources
+
+set(qrc_sources
+  generator.qrc
+  )
+
+#-----------------------------------------------------------------------------
+# Do wrapping
+qt4_wrap_cpp(gen_moc_sources ${moc_sources})
+qt4_wrap_ui(gen_ui_sources ${ui_sources})
+qt4_add_resources(gen_qrc_sources ${qrc_sources})
+
+#-----------------------------------------------------------------------------
+# Copy file expected by the generator and specify install rules
+
+file(GLOB files_to_copy RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "build_*.txt" "typesystem_*.xml")
+list(APPEND files_to_copy qtscript_masterinclude.h parser/rpp/pp-qt-configuration)
+foreach(file ${files_to_copy})
+  configure_file(
+    ${file}
+    ${CMAKE_CURRENT_BINARY_DIR}/${file}
+    COPYONLY
+    )
+  get_filename_component(destination_dir ${file} PATH)
+  install(FILES ${file} DESTINATION bin/${destination_dir})
+endforeach()
+
+#-----------------------------------------------------------------------------
+# Build the library
+
+SOURCE_GROUP("Resources" FILES
+  ${qrc_sources}
+  ${ui_sources}
+  ${files_to_copy}
+  )
+
+include_directories(
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}/parser
+  ${CMAKE_CURRENT_SOURCE_DIR}/parser/rpp
+  )
+  
+add_definitions(-DRXX_ALLOCATOR_INIT_0)
+  
+add_executable(${PROJECT_NAME}
+  ${sources}
+  ${gen_moc_sources}
+  ${gen_ui_sources}
+  ${gen_qrc_sources}
+)
+
+target_link_libraries(${PROJECT_NAME} ${QT_LIBRARIES})
+
+#-----------------------------------------------------------------------------
+# Install library (on windows, put the dll in 'bin' and the archive in 'lib')
+
+install(TARGETS ${PROJECT_NAME}
+        RUNTIME DESTINATION bin
+        LIBRARY DESTINATION lib
+        ARCHIVE DESTINATION lib)