Description: rationalization -- autotools machinery
 Attempt to autotoolize the upstream package in view to ease
 future maintenance on both side.
 This patch is meant to be submitted to the upstream maintainer.
Origin: vendor, Debian
Author: Jerome Benoit <calculus@rezozer.net>
Last-Update: 2016-12-16

--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,87 @@
+dnl                                               -*- Autoconf -*-
+dnl Process this file with autoconf to produce a configure script.
+
+AC_PREREQ([2.69])
+AC_INIT([tachyon], [0.99b9], [johns@ks.uiuc.edu])
+AC_CONFIG_SRCDIR([src/tachyon.h])
+AC_CONFIG_AUX_DIR([build-aux])
+AC_CONFIG_MACRO_DIR([m4])
+AC_CONFIG_HEADERS([config_tachyon.h])
+AM_INIT_AUTOMAKE([foreign])
+AM_SILENT_RULES([no])
+AM_MAINTAINER_MODE
+
+dnl Select library variant scheme.
+AC_ARG_WITH([libflavour],
+[AS_HELP_STRING([--with-libflavour=LIBFLAVOUR],[select as library flavour scheme LIBFLAVOUR [mt]])],
+[],[with_libflavour="mt"])
+case $with_libflavour in
+	serial|mt|openmpi|mpich) ;;
+	*) AC_MSG_ERROR([unknown library flavour scheme $with_libflavour])
+esac
+AM_CONDITIONAL([LIBFLAVOUR_IS_SERIAL],  [test "X$with_libflavour" = "Xserial"])
+AM_CONDITIONAL([LIBFLAVOUR_IS_MT],      [test "X$with_libflavour" = "Xmt"])
+AM_CONDITIONAL([LIBFLAVOUR_IS_OPENMPI], [test "X$with_libflavour" = "Xopenmpi"])
+AM_CONDITIONAL([LIBFLAVOUR_IS_MPICH],   [test "X$with_libflavour" = "Xmpich"])
+
+dnl Checks for system features.
+AC_CANONICAL_HOST
+case "$host_os" in
+	linux*) CPPFLAGS="$CPPFLAGS -DLinux" ;;
+	k*bsd-gnu*) CPPFLAGS="$CPPFLAGS -DBsd" ;;
+	gnu*) CPPFLAGS="$CPPFLAGS -DGnu" ;;
+esac
+
+dnl libtool:
+LT_INIT
+
+dnl Check linker script support.
+gl_LD_VERSION_SCRIPT
+
+dnl Checks for programs.
+AC_PATH_PROG([HELP2MAN],[help2man])
+AC_PROG_CC
+AC_PROG_CC_C99
+PKG_PROG_PKG_CONFIG
+
+dnl Checks for generic compiler characteristics.
+AM_COND_IF([LIBFLAVOUR_IS_SERIAL],[],[AC_OPENMP])
+
+dnl Checks for POSIX threads
+AM_COND_IF([LIBFLAVOUR_IS_SERIAL],[],[ACX_PTHREAD([],[AC_MSG_ERROR([unable to figure out how to build C programs using POSIX threads])])])
+
+dnl Checks for libraries.
+## math library
+LT_LIB_M
+## JPEG library
+AM_PATH_LIBJPEG([62],[CPPFLAGS="$CPPFLAGS -DUSEJPEG"],[AC_MSG_ERROR([unable to find libjpeg])])
+## PNG library
+PKG_CHECK_MODULES([LIBPNG],[libpng],[CPPFLAGS="$CPPFLAGS -DUSEPNG"],[AC_MSG_ERROR([unable to find libpng])])
+## OpenGL
+AC_PATH_X
+AC_PATH_XTRA
+AX_CHECK_GL([:],[AC_MSG_ERROR([unable to find an OpenGL implementation])])
+
+dnl Checks for header files.
+AC_CHECK_HEADERS([fcntl.h stdlib.h string.h sys/time.h unistd.h])
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_TYPE_SIZE_T
+
+dnl Append compliler options
+AX_APPEND_COMPILE_FLAGS(-D_REENTRANT)
+AX_APPEND_COMPILE_FLAGS(-ffast-math)
+AX_APPEND_COMPILE_FLAGS(-fomit-frame-pointer)
+
+dnl Checks for library functions.
+AC_FUNC_MALLOC
+AC_FUNC_REALLOC
+AC_CHECK_FUNCS([clock_gettime gethostname gettimeofday isascii memset pow sqrt strcspn strstr])
+
+AC_CONFIG_FILES([
+	Makefile
+	src/Makefile
+	demosrc/Makefile
+	])
+AC_OUTPUT
+dnl
--- /dev/null
+++ b/Makefile.am
@@ -0,0 +1,12 @@
+ACLOCAL_AMFLAGS = -I m4
+
+AUTOMAKE_OPTIONS = \
+	dist-xz \
+	dist-bzip2 \
+	dist-zip
+
+AM_CFLAGS = -g -Wall
+
+SUBDIRS = src demosrc docs
+
+EXTRA_DIST =
--- /dev/null
+++ b/src/Makefile.am
@@ -0,0 +1,160 @@
+AM_CFLAGS = -g -Wall
+
+## Library versioning (C:R:A == current:revision:age)
+LIBTACHYON_LT_VERSION = 0:0:0
+
+include_HEADERS = tachyon.h
+
+lib_LTLIBRARIES =
+if LIBFLAVOUR_IS_SERIAL
+lib_LTLIBRARIES += \
+	libtachyon.la \
+	libtachyon-serial.la
+endif
+if LIBFLAVOUR_IS_MT
+lib_LTLIBRARIES += \
+	libtachyon-mt-thr.la \
+	libtachyon-mt-openmp.la
+endif
+if LIBFLAVOUR_IS_OPENMPI
+lib_LTLIBRARIES += \
+	libtachyon-openmpi.la \
+	libtachyon-openmpi-thr.la \
+	libtachyon-openmpi-openmp.la
+endif
+if LIBFLAVOUR_IS_MPICH
+lib_LTLIBRARIES += \
+	libtachyon-mpich.la \
+	libtachyon-mpich-thr.la \
+	libtachyon-mpich-openmp.la
+endif
+
+libtachyon_la_LD_VERSION_SCRIPT=
+if HAVE_LD_VERSION_SCRIPT
+libtachyon_la_LD_VERSION_SCRIPT+= -Wl,--version-script=$(top_srcdir)/src/tachyon.map
+endif
+
+noinst_HEADERS = \
+	macros.h \
+	render.h \
+	quadric.h \
+	texture.h \
+	light.h
+
+libtachyon_la_SOURCES = \
+	api.c \
+	apigeom.c \
+	box.c \
+	global.c \
+	hash.c \
+	parallel.c \
+	threads.c \
+	camera.c \
+	render.c \
+	trace.c \
+	grid.c \
+	intersect.c \
+	sphere.c \
+	plane.c \
+	ring.c \
+	triangle.c \
+	cylinder.c \
+	quadric.c \
+	extvol.c \
+	vol.c \
+	ui.c \
+	util.c \
+	vector.c \
+	shade.c \
+	texture.c \
+	coordsys.c \
+	imap.c \
+	light.c \
+	imageio.c \
+	jpeg.c \
+	pngfile.c \
+	ppm.c \
+	psd.c \
+	sgirgb.c \
+	tgafile.c \
+	winbmp.c
+
+AM_PTHREAD_CPPFLAGS = \
+	-DTHR \
+	-DUSEGCCATOMICS \
+	-DUSEPOSIXTHREADS
+
+libtachyon_la_CPPFLAGS =
+
+libtachyon_la_CFLAGS = \
+	$(LIBPNG_CFLAGS) \
+	$(LIBJPEG_CFLAGS)
+
+libtachyon_la_LDFLAGS = \
+	-version-info $(LIBTACHYON_LT_VERSION) \
+	$(libtachyon_la_LD_VERSION_SCRIPT)
+
+libtachyon_la_LIBADD = \
+	$(LIBPNG_LIBS) \
+	$(LIBJPEG_LIBS) \
+	$(LIBM)
+
+
+libtachyon_serial_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_serial_la_CPPFLAGS = $(libtachyon_la_CPPFLAGS)
+libtachyon_serial_la_CFLAGS = $(libtachyon_la_CFLAGS)
+libtachyon_serial_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_serial_la_LIBADD = $(libtachyon_la_LIBADD)
+
+
+libtachyon_mt_openmp_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_mt_openmp_la_CPPFLAGS = $(libtachyon_la_CPPFLAGS)
+libtachyon_mt_openmp_la_CFLAGS = $(libtachyon_la_CFLAGS) $(OPENMP_CFLAGS)
+libtachyon_mt_openmp_la_LDFLAGS = $(libtachyon_la_LDFLAGS) $(OPENMP_CFLAGS)
+libtachyon_mt_openmp_la_LIBADD = $(libtachyon_la_LIBADD)
+
+libtachyon_mt_thr_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_mt_thr_la_CPPFLAGS = $(libtachyon_la_CPPFLAGS) $(AM_PTHREAD_CPPFLAGS)
+libtachyon_mt_thr_la_CFLAGS = $(libtachyon_la_CFLAGS) $(PTHREAD_CFLAGS)
+libtachyon_mt_thr_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_mt_thr_la_LIBADD = $(libtachyon_la_LIBADD) $(PTHREAD_LIBS)
+
+
+libtachyon_openmpi_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_openmpi_la_CPPFLAGS = $(libtachyon_la_CPPFLAGS) -DMPI -DMPI_TUNE=0
+libtachyon_openmpi_la_CFLAGS = $(libtachyon_la_CFLAGS)
+libtachyon_openmpi_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_openmpi_la_LIBADD = $(libtachyon_la_LIBADD)
+
+libtachyon_openmpi_thr_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_openmpi_thr_la_CPPFLAGS = $(libtachyon_openmpi_la_CPPFLAGS) $(AM_PTHREAD_CPPFLAGS)
+libtachyon_openmpi_thr_la_CFLAGS = $(libtachyon_la_CFLAGS) $(PTHREAD_CFLAGS)
+libtachyon_openmpi_thr_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_openmpi_thr_la_LIBADD = $(libtachyon_la_LIBADD) $(PTHREAD_LIBS)
+
+libtachyon_openmpi_openmp_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_openmpi_openmp_la_CPPFLAGS = $(libtachyon_openmpi_la_CPPFLAGS)
+libtachyon_openmpi_openmp_la_CFLAGS = $(libtachyon_la_CFLAGS) $(OPENMP_CFLAGS)
+libtachyon_openmpi_openmp_la_LDFLAGS = $(libtachyon_la_LDFLAGS) $(OPENMP_CFLAGS)
+libtachyon_openmpi_openmp_la_LIBADD = $(libtachyon_la_LIBADD)
+
+
+libtachyon_mpich_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_mpich_la_CPPFLAGS = $(libtachyon_la_CPPFLAGS) -DMPI -DMPI_TUNE=0 -DUSE_MPI_IN_PLACE
+libtachyon_mpich_la_CFLAGS = $(libtachyon_la_CFLAGS)
+libtachyon_mpich_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_mpich_la_LIBADD = $(libtachyon_la_LIBADD)
+
+libtachyon_mpich_thr_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_mpich_thr_la_CPPFLAGS = $(libtachyon_mpich_la_CPPFLAGS) $(AM_PTHREAD_CPPFLAGS)
+libtachyon_mpich_thr_la_CFLAGS = $(libtachyon_la_CFLAGS) $(PTHREAD_CFLAGS)
+libtachyon_mpich_thr_la_LDFLAGS = $(libtachyon_la_LDFLAGS)
+libtachyon_mpich_thr_la_LIBADD = $(libtachyon_la_LIBADD) $(PTHREAD_LIBS)
+
+libtachyon_mpich_openmp_la_SOURCES = $(libtachyon_la_SOURCES)
+libtachyon_mpich_openmp_la_CPPFLAGS = $(libtachyon_mpich_la_CPPFLAGS)
+libtachyon_mpich_openmp_la_CFLAGS = $(libtachyon_la_CFLAGS) $(OPENMP_CFLAGS)
+libtachyon_mpich_openmp_la_LDFLAGS = $(libtachyon_la_LDFLAGS) $(OPENMP_CFLAGS)
+libtachyon_mpich_openmp_la_LIBADD = $(libtachyon_la_LIBADD)
+
+EXTRA_DIST =
--- /dev/null
+++ b/demosrc/Makefile.am
@@ -0,0 +1,85 @@
+bin_PROGRAMS =
+man_MANS =
+if LIBFLAVOUR_IS_SERIAL
+bin_PROGRAMS += tachyon-nox tachyon-ogl
+man_MANS += tachyon-nox.1 tachyon-ogl.1
+endif
+
+
+AM_CFLAGS =
+
+tachyon_SOURCES = \
+	main.c \
+	getargs.c \
+	parse.c \
+	nffparse.c \
+	mgfparse.c \
+	ac3dparse.c
+
+tachyon_nox_SOURCES = \
+	$(tachyon_SOURCES)
+
+tachyon_ogl_SOURCES = \
+	$(tachyon_SOURCES) \
+	glwin.c \
+	spaceball.c \
+	trackball.c
+
+AM_H2MFLAGS = \
+	--manual='Tachyon Manual' \
+	--help-option='-help' \
+	--version-option='-version' \
+	--no-info \
+	--libtool
+
+%.1: %
+	$(HELP2MAN) \
+			-s 1 \
+			$(AM_H2MFLAGS) \
+			-I $(top_srcdir)/demosrc/man/$*.h2m \
+			-n $(if $($(subst -,_,$*)_DESCRIPTION), $($(subst -,_,$*)_DESCRIPTION), "manual page for $*") \
+			-o $@ \
+		$(top_builddir)/demosrc/$<
+
+## short descriptions inspired from the Tachyon User's Guide or/and program banners
+tachyon_DESCRIPTION = "parallel/multiprocessor ray tracer"
+tachyon_nox_DESCRIPTION = "$(shell printf "%s %s" $(tachyon_DESCRIPTION) "with no X support")"
+tachyon_ogl_DESCRIPTION = "$(shell printf "%s %s" $(tachyon_DESCRIPTION) "with OpenGL display")"
+
+tachyon_CPPFLAGS = \
+	-I $(top_srcdir)/src
+
+tachyon_nox_CPPFLAGS = \
+	$(tachyon_CPPFLAGS)
+
+tachyon_ogl_CPPFLAGS = \
+	-DUSEOPENGL \
+	$(tachyon_CPPFLAGS)
+
+tachyon_CFLAGS = \
+	$(AM_CFLAGS)
+
+tachyon_nox_CFLAGS = \
+	$(tachyon_CFLAGS)
+
+tachyon_ogl_CFLAGS = \
+	$(tachyon_CFLAGS) \
+	$(GL_CFLAGS)
+
+tachyon_LDADD = \
+	$(top_builddir)/src/libtachyon.la \
+	$(LIBM)
+
+tachyon_nox_LDADD = \
+	$(tachyon_LDADD)
+
+tachyon_ogl_LDADD = \
+	$(tachyon_LDADD) \
+	$(GL_LIBS) \
+	$(X_LIBS)
+
+CLEANFILES = \
+	$(man_MANS)
+
+EXTRA_DIST =
+
--- /dev/null
+++ b/m4/adhoc_libjpeg.m4
@@ -0,0 +1,236 @@
+# adhoc_libjpeg.m4 serial 1
+dnl m4/adhoc_libjpeg.m4 -- M4 macro processor include script
+dnl
+dnl Copyright (C) 2015 Jerome Benoit <jgmbenoit@rezozer.net>
+dnl
+dnl Based on macros for the GNU GMP library by Owen Taylor, modified by:
+dnl Hans Petter Jansson, 2001-04-09;
+dnl Allin Cottrell, April 2003;
+dnl and certainly others.
+dnl
+dnl Copying and distribution of this file, with or without modification, are
+dnl permitted in any medium without royalty provided the copyright notice and
+dnl this notice are preserved. This file is offered as-is, without any warranty.
+dnl
+dnl
+dnl NOTE:
+dnl  The trick used to extract the library version number of the JPEG library
+dnl  itself was adapted from a comment by user2834915 user at stackoverflow.com,
+dnl  https://stackoverflow.com/questions/10332908/find-out-libjpeg-version-at-runtime-or-other-ways-to-prevent-aborts
+dnl
+
+dnl _adhoc_AC_PROG_PATH_LIBJPEG_CC_ARG_WITH
+AC_DEFUN_ONCE([_adhoc_AC_PROG_PATH_LIBJPEG_CC_ARG_WITH],[dnl
+AC_ARG_WITH([libjpeg-prefix],
+	[AS_HELP_STRING([--with-libjpeg-prefix=PREFIX],
+		[specify prefix for the installed JPEG library [standard search prefixes]])],
+	[libjpeg_config_prefix="$withval"],[libjpeg_config_prefix=""])
+AC_ARG_WITH([libjpeg-include],
+	[AS_HELP_STRING([--with-libjpeg-include=PATH],
+		[specify directory for the installed JPEG library header file [standard search paths]])],
+	[libjpeg_config_include_prefix="$withval"],[libjpeg_config_include_prefix=""])
+AC_ARG_WITH([libjpeg-lib],
+	[AS_HELP_STRING([--with-libjpeg-lib=PATH],
+		[specify directory for the installed JPEG library [standard search paths]])],
+	[libjpeg_config_lib_prefix="$withval"],[libjpeg_config_lib_prefix=""])
+
+	if test "x$libjpeg_config_include_prefix" = "x" ; then
+		if test "x$libjpeg_config_prefix" != "x" ; then
+			libjpeg_config_include_prefix="$libjpeg_config_prefix/include"
+		fi
+	fi
+	if test "x$libjpeg_config_lib_prefix" = "x" ; then
+		if test "x$libjpeg_config_prefix" != "x" ; then
+			libjpeg_config_lib_prefix="$libjpeg_config_prefix/lib"
+		fi
+	fi
+
+	LIBJPEG_CPPFLAGS=
+	if test "x$libjpeg_config_include_prefix" != "x" ; then
+		LIBJPEG_CPPFLAGS="-I$libjpeg_config_include_prefix"
+	fi
+
+	LIBJPEG_LDFLAGS=
+	if test "x$libjpeg_config_lib_prefix" != "x" ; then
+		LIBJPEG_LDFLAGS="-L$libjpeg_config_lib_prefix"
+	fi
+
+AC_SUBST(LIBJPEG_CPPFLAGS)
+AC_SUBST(LIBJPEG_LDFLAGS)
+])
+
+dnl adhoc_AM_PATH_LIBJPEG([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
+AC_DEFUN([adhoc_AM_PATH_LIBJPEG],[dnl
+AC_REQUIRE([AC_PROG_SED])dnl
+AC_REQUIRE([_adhoc_AC_PROG_PATH_LIBJPEG_CC_ARG_WITH])dnl
+
+	min_libjpeg_version=m4_default([$1],[60])
+	min_libjpeg_version_0="$min_libjpeg_version.0"
+
+	min_libjpeg_version_number=`echo $min_libjpeg_version_0 | $SED 's/\([[0-9]]*\).\(.*\)/\1/'`
+
+	min_libjpeg_dotted_version="$min_libjpeg_version_number"
+
+	LIBJPEG_LIBS="-ljpeg"
+
+	AC_MSG_CHECKING([for JPEG library - version >= $min_libjpeg_version ])
+
+	ac_save_CPPFLAGS="$CPPFLAGS"
+	ac_save_CFLAGS="$CFLAGS"
+	ac_save_LDFLAGS="$LDFLAGS"
+	ac_save_LIBS="$LIBS"
+
+	CPPFLAGS="$CPPFLAGS $LIBJPEG_CPPFLAGS"
+	CFLAGS="$CFLAGS $LIBJPEG_CFLAGS"
+	LDFLAGS="$LDFLAGS $LIBJPEG_LDFLAGS"
+	LIBS="$LIBS $LIBJPEG_LIBS"
+
+	rm -f conf.libjpegtest
+	AC_RUN_IFELSE([AC_LANG_SOURCE(
+[[
+#include <stdio.h>
+#include <jpeglib.h>
+
+#define PRINTF_MSG_ERROR_MISMATCH_HEADER_LIBRARY \
+	printf("*** This likely indicates either a bad configuration or some\n"); \
+	printf("*** other inconsistency in the development environment. If the\n"); \
+	printf("*** expected JPEG library cannot be found, it may be sufficient\n"); \
+	printf("*** either to set properly the LD_LIBRARY_PATH environment variable\n"); \
+	printf("*** or to configure ldconfig(8) to consider the installed location.\n"); \
+	printf("*** Otherwise a bad configuration or an inconsistency in the\n"); \
+	printf("*** include/library search paths may be investigated; adjustments\n"); \
+	printf("*** through the use of --with-libjpeg-(include|lib) configure option\n"); \
+	printf("*** may help.\n"); \
+	printf("***\n"); \
+	printf("*** If an old version is installed, it may be best to remove it and to\n"); \
+	printf("*** reinstall a more recent one; although modifying LD_LIBRARY_PATH\n"); \
+	printf("*** may also get things to work. Latest information on JPEG may be\n"); \
+	printf("*** available from <http://jpegclub.org/>.\n"); \
+	printf("***\n");
+
+int adhoc_libjpeg_version(void);
+
+int main ()
+{
+	int libjpeg_hdr_version_number = 0;
+	int libjpeg_lib_version_number = 0;
+
+	fclose (fopen ("conf.libjpegtest", "w"));
+
+#ifdef JPEG_LIB_VERSION
+	libjpeg_hdr_version_number = JPEG_LIB_VERSION;
+#else
+	error JPEG_LIB_VERSION not defined
+#endif
+
+	libjpeg_lib_version_number = adhoc_libjpeg_version();
+
+	if (libjpeg_lib_version_number != libjpeg_hdr_version_number) {
+		printf("\n***\n");
+		printf("*** JPEG header version number (%d) and\n",libjpeg_hdr_version_number);
+		printf("*** JPEG library version number (%d)\n",libjpeg_lib_version_number);
+		printf("*** do not match.\n");
+		printf("***\n");
+		PRINTF_MSG_ERROR_MISMATCH_HEADER_LIBRARY
+		}
+	else if ($min_libjpeg_version_number <= libjpeg_hdr_version_number) {
+		return (0);
+		}
+	else {
+		printf("\n***\n");
+		printf("*** JPEG version $min_libjpeg_dotted_version or higher is required:\n");
+		printf("*** an older version of JPEG (%d) was found.\n",libjpeg_hdr_version_number);
+		printf("*** Latest information on JPEG may be available from <http://jpegclub.org/>.\n");
+		printf("***\n");
+		}
+
+	return (1);
+}
+
+static
+int ADHOC_LIBRARY_JPEG_LIB_VERSION=-1;
+
+static
+void adhoc_libjpeg_version_error_exit(j_common_ptr cinfo) {
+	ADHOC_LIBRARY_JPEG_LIB_VERSION=cinfo->err->msg_parm.i[0];
+	return ; }
+
+int adhoc_libjpeg_version(void) {
+	if (ADHOC_LIBRARY_JPEG_LIB_VERSION < 0) {
+		struct jpeg_decompress_struct cinfo;
+		struct jpeg_error_mgr error_mgr;
+		error_mgr.error_exit=&adhoc_libjpeg_version_error_exit;
+		cinfo.err=&error_mgr;
+#undef JPEG_LIB_VERSION
+#define JPEG_LIB_VERSION -1
+		jpeg_create_decompress(&cinfo);
+#undef JPEG_LIB_VERSION
+		}
+	return (ADHOC_LIBRARY_JPEG_LIB_VERSION); }
+
+]]
+)],[],[no_libjpeg=yes],[AC_MSG_WARN([$ac_n "cross compiling; assumed OK... $ac_c])])
+
+	CPPFLAGS="$ac_save_CPPFLAGS"
+	CFLAGS="$ac_save_CFLAGS"
+	LDFLAGS="$ac_save_LDFLAGS"
+	LIBS="$ac_save_LIBS"
+
+	if test "x$no_libjpeg" = "x" ; then
+		AC_MSG_RESULT([yes])
+		$2
+	else
+		AC_MSG_RESULT([no])
+		if test -f conf.libjpegtest ; then
+			:
+		else
+			echo "***"
+			echo "*** Could not run JPEG test program, checking why..."
+			CPPFLAGS="$CPPFLAGS $LIBJPEG_CPPFLAGS"
+			CFLAGS="$CFLAGS $LIBJPEG_CFLAGS"
+			LDFLAGS="$CFLAGS $LIBJPEG_LDFLAGS"
+			LIBS="$LIBS $LIBJPEG_LIBS"
+			AC_LINK_IFELSE([AC_LANG_PROGRAM(
+[[
+#include <stdio.h>
+#include <jpeg.h>
+]],
+[[ return (1); ]]
+)],
+[
+echo "***"
+echo "*** The test program compiled, but did not run. This usually means"
+echo "*** that the run-time linker is not finding JPEG library or finding the wrong"
+echo "*** version of JPEG. If it is not finding JPEG, you'll need to set your"
+echo "*** LD_LIBRARY_PATH environment variable, or configure ldconfig(8) to consider"
+echo "*** the installed location."
+echo "***"
+echo "*** If you have an old version installed, it is best to remove it; although"
+echo "*** modifying LD_LIBRARY_PATH may also get things to work. Latest information"
+echo "*** on JPEG may be available from <http://jpegclub.org/>."
+echo "***"
+],
+[
+echo "***"
+echo "*** The test program failed to compile or link. See the file config.log for the"
+echo "*** exact error that occured. This usually means JPEG was incorrectly installed"
+echo "*** or that you have moved JPEG since it was installed."
+echo "***"
+])
+			CPPFLAGS="$ac_save_CPPFLAGS"
+			CFLAGS="$ac_save_CFLAGS"
+			LDFLAGS="$ac_save_LDFLAGS"
+			LIBS="$ac_save_LIBS"
+		fi
+		rm -f conf.libjpegtest
+		m4_default([$3],[AC_MSG_ERROR([no suitable JPEG library found])])
+	fi
+	rm -f conf.libjpegtest
+
+AC_SUBST(LIBJPEG_LIBS)
+])
+
+dnl alias
+AU_ALIAS([AM_PATH_LIBJPEG],[adhoc_AM_PATH_LIBJPEG])
+
+dnl eof
--- a/src/util.c
+++ b/src/util.c
@@ -51,7 +51,7 @@
 void rt_finalize(void); /* UGLY! tachyon.h needs more cleanup before it can */
                         /* be properly included without risk of bogosity    */
 
-#if defined(__linux) || defined(Bsd) || defined(AIX) || defined(__APPLE__) || defined(__sun) || defined(__hpux) || defined(_CRAYT3E) || defined(_CRAY) || defined(_CRAYC) || defined(__osf__) || defined(__BEOS__)
+#if defined(__linux) || defined(Bsd) || defined(Gnu) || defined(AIX) || defined(__APPLE__) || defined(__sun) || defined(__hpux) || defined(_CRAYT3E) || defined(_CRAY) || defined(_CRAYC) || defined(__osf__) || defined(__BEOS__)
 #include <sys/time.h>
 #endif