1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
|
C Copyright (c) 2003-2010 University of Florida
C
C This program is free software; you can redistribute it and/or modify
C it under the terms of the GNU General Public License as published by
C the Free Software Foundation; either version 2 of the License, or
C (at your option) any later version.
C This program is distributed in the hope that it will be useful,
C but WITHOUT ANY WARRANTY; without even the implied warranty of
C MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
C GNU General Public License for more details.
C The GNU General Public License is included in this distribution
C in the file COPYRIGHT.
SUBROUTINE OED__KIN_CSGTO
+
+ ( IMAX,ZMAX,
+ NALPHA,NCOEFF,NCSUM,
+ NCGTO1,NCGTO2,
+ NPGTO1,NPGTO2,
+ SHELL1,SHELL2,
+ X1,Y1,Z1,X2,Y2,Z2,
+ ALPHA,CC,CCBEG,CCEND,
+ L1CACHE,TILE,NCTROW,
+ SPHERIC,SCREEN,
+ ICORE,
+
+ NBATCH,
+ NFIRST,
+ ZCORE )
+
C------------------------------------------------------------------------
C OPERATION : OED__KIN_CSGTO
C MODULE : ONE ELECTRON INTEGRALS DIRECT
C MODULE-ID : OED
C SUBROUTINES : OED__KIN_SET_AB
C OED__KIN_SET_IJ_PAIRS
C OED__KIN_AB_DEF_BLOCKS
C OED__KIN_PREPARE_CTR
C OED__KIN_AB_PCGTO_BLOCK
C OED__CTR_2INDEX_BLOCK
C OED__CTR_RS_EXPAND
C OED__CTR_2INDEX_REORDER
C OED__TRANSPOSE_BATCH
C OED__XYZ_TO_RY_AB
C OED__CARTESIAN_NORMS
C OED__SPHERICAL_TRANSFORM
C OED__NORMALIZE_CARTESIAN
C OED__MOVE_RY
C DESCRIPTION : This operation calculates a batch of contracted
C kinetic integrals on up to two different centers
C between spherical or cartesian gaussian type shells.
C
C
C Input (x = 1 and 2):
C
C IMAX,ZMAX = maximum integer,flp memory
C NALPHA = total # of exponents
C NCOEFF = total # of contraction coeffs
C NCSUM = total # of contractions
C NCGTOx = # of contractions for csh x
C NPGTOx = # of primitives per contraction
C for csh x
C SHELLx = the shell type for csh x
C Xy,Yy,Zy = the x,y,z-coordinates for centers
C y = 1 and 2
C ALPHA = primitive exponents for csh
C 1 and 2 in that order
C CC = full set (including zeros) of
C contraction coefficients for csh
C 1 and 2 in that order, for each
C csh individually such that an
C (I,J) element corresponds to the
C I-th primitive and J-th contraction.
C CC(BEG)END = (lowest)highest nonzero primitive
C index for contractions for csh
C 1 and 2 in that order. They are
C different from (1)NPGTOx only for
C segmented contractions
C L1CACHE = Size of level 1 cache in units of
C 8 Byte
C TILE = Number of rows and columns in
C units of 8 Byte of level 1 cache
C square tile array used for
C performing optimum matrix
C transpositions
C NCTROW = minimum # of rows that are
C accepted for blocked contractions
C SPHERIC = is true, if spherical integrals
C are wanted, false if cartesian
C ones are wanted
C SCREEN = is true, if screening will be
C done at primitive integral level
C ICORE = integer scratch space
C ZCORE (part) = flp scratch space
C
C Output:
C
C NBATCH = # of integrals in batch
C NFIRST = first address location inside the
C ZCORE array containing the first
C integral
C ZCORE = full batch of contracted (1|2)
C kinetic integrals over cartesian
C or spherical gaussians starting
C at ZCORE (NFIRST)
C
C
C
C --- NOTES ABOUT THE OVERALL KINETIC INTEGRAL PREFACTOR ---
C
C The overal kinetic integral prefactor is defined here
C as follows. Consider the normalization factors for a
C primitive cartesian GTO and for a spherical GTO
C belonging to the angular momentum L = l+m+n:
C
C
C lmn l m n 2
C GTO (x,y,z) = N (l,m,n,a) * x y z * exp (-ar )
C a
C
C
C LM L LM 2
C GTO (r,t,p) = N (L,a) * r * Y (t,p) * exp (-ar )
C a
C
C
C where a = alpha exponent, t = theta and p = phi and
C N (l,m,n,a) and N (L,a) denote the respective
C cartesian and spherical normalization factors such
C that:
C
C
C lmn lmn
C integral {GTO (x,y,z) * GTO (x,y,z) dx dy dz} = 1
C a a
C
C
C LM LM
C integral {GTO (r,t,p) * GTO (r,t,p) dr dt dp} = 1
C a a
C
C
C The normalization constants have then the following
C values, assuming the spherical harmonics are
C normalized:
C
C _____________________________________
C / 2^(2L+1+1/2) * a^((2L+3)/2)
C N (l,m,n,a) = / ----------------------------------------
C \/ (2l-1)!!(2m-1)!!(2n-1)!! * pi * sqrt (pi)
C
C
C ____________________________
C / 2^(2L+3+1/2) * a^((2L+3)/2)
C N (L,a) = / -----------------------------
C \/ (2L+1)!! * sqrt (pi)
C
C
C Note, that the extra pi under the square root in
C N (l,m,n,a) belongs to the normalization of the
C spherical harmonic functions and therefore does not
C appear in the expression for N (L,a). The common
C L-,l-,m-,n- and a-independent part of the cartesian
C norm is a scalar quantity needed for all integrals
C no matter what L-,l-,m-,n- and a-values they have:
C
C _____________
C / 2^(1+1/2)
C N (0,0,0,0) = / --------------
C \/ pi * sqrt (pi)
C
C
C Also every kinetic integral has a factor of pi**(3/2)
C associated with it, hence the overall common factor
C for all kinetic integrals will be N(0,0,0,0)**2 times
C pi**(3/2), which is equal to:
C
C ___
C PREFACT = \/ 8
C
C
C and is set as a parameter inside the present routine.
C The alpha exponent dependent part of the norms:
C
C ______________
C \/ a^((2L+3)/2)
C
C will be calculated separately (see below) and their
C inclusion in evaluating the primitive cartesian
C kinetic [A|B] integrals will be essential for numerical
C stability during contraction.
C
C
C AUTHOR : Norbert Flocke
C------------------------------------------------------------------------
C
C
C ...include files and declare variables.
C
C
IMPLICIT NONE
LOGICAL ATOMIC
LOGICAL BLOCKED
LOGICAL EMPTY
LOGICAL EQUALAB
LOGICAL MEMORY
LOGICAL REORDER
LOGICAL SCREEN
LOGICAL SPHERIC
LOGICAL SWAP12,SWAPRS
INTEGER IMAX,ZMAX
INTEGER IN,OUT
INTEGER INDEXA,INDEXB
INTEGER INDEXR,INDEXS
INTEGER IPRIMA,IPRIMB
INTEGER IPUSED,IPSAVE,IPPAIR
INTEGER ISNROWA,ISNROWB
INTEGER ISROWA,ISROWB
INTEGER IUSED,ZUSED
INTEGER L1CACHE,TILE,NCTROW
INTEGER LCC1,LCC2
INTEGER LCCA,LCCB
INTEGER LCCSEGA,LCCSEGB
INTEGER LEXP1,LEXP2
INTEGER LEXPA,LEXPB
INTEGER MXPRIM,MNPRIM
INTEGER MXSHELL
INTEGER MIJ
INTEGER MOVE,NOTMOVE
INTEGER NALPHA,NCOEFF,NCSUM
INTEGER NBATCH,NFIRST
INTEGER NCGTO1,NCGTO2
INTEGER NCGTOA,NCGTOB,NCGTOAB
INTEGER NCGTOR,NCGTOS
INTEGER NCTR
INTEGER NIJ,NIJBLK,NIJBEG,NIJEND
INTEGER NKIN1D,NOVL1D
INTEGER NPGTO1,NPGTO2
INTEGER NPGTOA,NPGTOB,NPGTOAB
INTEGER NPSIZE,NCSIZE,NWSIZE
INTEGER NROTA,NROTB
INTEGER NROWA,NROWB
INTEGER NRYA,NRYB
INTEGER NXYZA,NXYZB,NXYZT
INTEGER SHELL1,SHELL2
INTEGER SHELLA,SHELLB,SHELLP
INTEGER TEMP
INTEGER ZCBATCH,ZPBATCH,ZWORK,
+ ZNORMA,ZNORMB,
+ ZBASE,ZCNORM,
+ ZRHOAB,
+ ZEA,ZEB,ZE2AB,ZPAX,ZPAY,ZPAZ,ZPINVHF,ZSCALE,
+ ZKIN1DX,ZKIN1DY,ZKIN1DZ,
+ ZOVL1DX,ZOVL1DY,ZOVL1DZ,
+ ZSROTA,ZSROTB
INTEGER CCBEG (1:NCSUM)
INTEGER CCEND (1:NCSUM)
INTEGER ICORE (1:IMAX)
INTEGER IXOFF (1:2)
DOUBLE PRECISION ABX,ABY,ABZ
DOUBLE PRECISION PREFACT
DOUBLE PRECISION RNABSQ
DOUBLE PRECISION SPNORM
DOUBLE PRECISION X1,Y1,Z1,X2,Y2,Z2
DOUBLE PRECISION XA,YA,ZA,XB,YB,ZB
DOUBLE PRECISION ALPHA (1:NALPHA)
DOUBLE PRECISION CC (1:NCOEFF)
DOUBLE PRECISION ZCORE (1:ZMAX)
PARAMETER (PREFACT = 2.828427124746190D0)
C
C
C------------------------------------------------------------------------
C
C
C ...fix the A,B labels from the 1,2 ones. Calculate
C the relevant data for the A,B batch of kinetic
C integrals.
C
C
LEXP1 = 1
LEXP2 = LEXP1 + NPGTO1
LCC1 = 1
LCC2 = LCC1 + NPGTO1 * NCGTO1
CALL OED__KIN_SET_AB
+
+ ( NCGTO1,NCGTO2,
+ NPGTO1,NPGTO2,
+ SHELL1,SHELL2,
+ X1,Y1,Z1,X2,Y2,Z2,
+ ALPHA (LEXP1),ALPHA (LEXP2),
+ CC (LCC1),CC (LCC2),
+ SPHERIC,
+
+ NCGTOA,NCGTOB,
+ NPGTOA,NPGTOB,
+ SHELLA,SHELLB,SHELLP,
+ MXSHELL,
+ XA,YA,ZA,XB,YB,ZB,
+ ATOMIC,EQUALAB,
+ ABX,ABY,ABZ,RNABSQ,
+ SPNORM,
+ NXYZA,NXYZB,NXYZT,
+ NRYA,NRYB,
+ INDEXA,INDEXB,
+ SWAP12,SWAPRS,
+ LEXPA,LEXPB,
+ LCCA,LCCB,
+ LCCSEGA,LCCSEGB,
+ EMPTY )
+
+
C WRITE (*,*) ' Finished set ab '
C WRITE (*,*) ' Index A,B = ',INDEXA,INDEXB
IF (EMPTY) THEN
NBATCH = 0
RETURN
END IF
C
C
C ...enter the cartesian contracted (a|b) kinetic batch
C generation. Set the i and j primitive exponent
C sets and the corresponding exponential prefactors.
C
C
IF (EQUALAB) THEN
NPGTOAB = (NPGTOA*(NPGTOA+1))/2
NCGTOAB = (NCGTOA*(NCGTOA+1))/2
ELSE
NPGTOAB = NPGTOA * NPGTOB
NCGTOAB = NCGTOA * NCGTOB
END IF
IPRIMA = 1
IPRIMB = IPRIMA + NPGTOAB
CALL OED__KIN_SET_IJ_PAIRS
+
+ ( NPGTOA,NPGTOB,NPGTOAB,
+ ATOMIC,EQUALAB,
+ SWAPRS,
+ RNABSQ,
+ PREFACT,
+ ALPHA (LEXPA),ALPHA (LEXPB),
+ SCREEN,
+
+ EMPTY,
+ NIJ,
+ ICORE (IPRIMA),ICORE (IPRIMB),
+ ZCORE (1) )
+
+
IF (EMPTY) THEN
NBATCH = 0
RETURN
END IF
C
C
C ...decide on the primitive [a|b] block size and
C return array sizes and pointers for the primitive
C [a|b] generation. Perform also some preparation
C steps for contraction.
C
C
MEMORY = .FALSE.
CALL OED__KIN_AB_DEF_BLOCKS
+
+ ( ZMAX,
+ NPGTOA,NPGTOB,
+ SHELLA,SHELLB,SHELLP,
+ NIJ,NCGTOAB,
+ NXYZT,
+ L1CACHE,NCTROW,
+ MEMORY,
+
+ NIJBLK,
+ NPSIZE,NCSIZE,NWSIZE,
+ NKIN1D,NOVL1D,
+ MXPRIM,MNPRIM,
+ ZCBATCH,ZPBATCH,ZWORK,
+ ZNORMA,ZNORMB,
+ ZRHOAB,
+ ZEA,ZEB,ZE2AB,
+ ZPAX,ZPAY,ZPAZ,ZPINVHF,ZSCALE,
+ ZKIN1DX,ZKIN1DY,ZKIN1DZ,
+ ZOVL1DX,ZOVL1DY,ZOVL1DZ )
+
+
BLOCKED = NIJBLK .LT. NIJ
CALL OED__KIN_PREPARE_CTR
+
+ ( NCSIZE,
+ NIJ,
+ NPGTOA,NPGTOB,
+ SHELLA,SHELLB,
+ ALPHA (LEXPA),ALPHA (LEXPB),
+ PREFACT,SPNORM,
+ EQUALAB,
+ BLOCKED,
+ ZCORE (1),
+
+ ZCORE (ZNORMA),ZCORE (ZNORMB),
+ ZCORE (ZRHOAB),
+ ZCORE (ZCBATCH) )
+
+
IPUSED = IPRIMB + NPGTOAB
IPSAVE = IPUSED + MNPRIM
IPPAIR = IPSAVE + MXPRIM
C
C
C ...evaluate unnormalized rescaled [a|b] kinetic integrals
C in blocks over ij pairs and add to final contracted
C (a|b) overlap integrals. The keyword REORDER indicates,
C if the primitive [a|b] overlap integrals need to be
C transposed before being contracted.
C
C
REORDER = .TRUE.
DO 1000 NIJBEG = 1,NIJ,NIJBLK
NIJEND = MIN0 (NIJBEG+NIJBLK-1,NIJ)
MIJ = NIJEND - NIJBEG + 1
CALL OED__KIN_AB_PCGTO_BLOCK
+
+ ( NPSIZE,NKIN1D,NOVL1D,
+ ATOMIC,
+ MIJ,NIJ,NIJBEG,NIJEND,
+ NPGTOA,NPGTOB,
+ NXYZA,NXYZB,
+ SHELLA,SHELLB,SHELLP,
+ XA,YA,ZA,XB,YB,ZB,
+ ABX,ABY,ABZ,
+ ALPHA (LEXPA),ALPHA (LEXPB),
+ ICORE (IPRIMA+NIJBEG-1),
+ ICORE (IPRIMB+NIJBEG-1),
+ ZCORE (ZNORMA),ZCORE (ZNORMB),
+ ZCORE (ZRHOAB),
+ ZCORE (ZEA),ZCORE (ZEB),ZCORE (ZE2AB),
+ ZCORE (ZPAX),ZCORE (ZPAY),ZCORE (ZPAZ),
+ ZCORE (ZPINVHF),ZCORE (ZSCALE),
+ ZCORE (ZKIN1DX),ZCORE (ZKIN1DY),ZCORE (ZKIN1DZ),
+ ZCORE (ZOVL1DX),ZCORE (ZOVL1DY),ZCORE (ZOVL1DZ),
+
+ ZCORE (ZPBATCH) )
+
+
C WRITE (*,*) ' Finished ab kinetic pcgto block '
CALL OED__CTR_2INDEX_BLOCK
+
+ ( NPSIZE,NCSIZE,NWSIZE,
+ NXYZT,
+ MIJ,NCGTOAB,
+ NPGTOA,NPGTOB,
+ NCGTOA,NCGTOB,
+ MXPRIM,MNPRIM,
+ CC (LCCA),CC (LCCB),
+ CCBEG (LCCSEGA),CCBEG (LCCSEGB),
+ CCEND (LCCSEGA),CCEND (LCCSEGB),
+ ICORE (IPRIMA+NIJBEG-1),
+ ICORE (IPRIMB+NIJBEG-1),
+ L1CACHE,TILE,NCTROW,
+ EQUALAB,
+ SWAPRS,
+ REORDER,
+ BLOCKED,
+ ICORE (IPUSED),
+ ICORE (IPSAVE),
+ ICORE (IPPAIR),
+ ZCORE (ZPBATCH),
+ ZCORE (ZWORK),
+
+ ZCORE (ZCBATCH) )
+
+
C WRITE (*,*) ' Finished 2 index ctr block '
1000 CONTINUE
C
C
C ...the unnormalized cartesian (a|b) contracted kinetic
C batch is ready. Expand the contraction indices
C (if necessary):
C
C batch (nxyzt,r>=s) --> batch (nxyzt,r,s)
C
C and reorder the contraction index part (if necessary):
C
C batch (nxyzt,r,s) --> batch (nxyzt,1,2)
C
C The array IXOFF (x) indicates the total # of indices
C to the left of x without including the nxyzt-part.
C For the left most IXOFF value it is convenient to
C set it equal to 1 instead of 0. Note, that the IXOFF
C array indicates the true # of indices to the left
C after! the batch has been transposed (see below) and
C can be used as initial values when moving the
C ry-components later during the cartesian -> spherical
C transformation procedure.
C
C Efficient application of the cartesian -> spherical
C transformation requires the batch elements to be
C ordered as:
C
C batch (1,2,nxyzt)
C
C hence we transpose the batch after the reordering.
C
C The space partitioning of the flp array for all of
C these steps will be as follows:
C
C
C | Zone 1 | Zone 2 |
C
C in which Zone 1 and 2 are 2 batches of cartesian
C (a|b) size.
C
C
IXOFF (1) = 1
IXOFF (2) = NCGTO1
NCTR = NCGTO1 * NCGTO2
NBATCH = NCTR * NXYZT
IN = ZCBATCH
OUT = IN + NBATCH
IF (EQUALAB .AND. NCGTOAB.GT.1) THEN
CALL OED__CTR_RS_EXPAND
+
+ ( NXYZT,NCGTOAB,
+ NCGTOA,NCGTOB,
+ ZCORE (IN),
+
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished ctr rs expansion '
TEMP = IN
IN = OUT
OUT = TEMP
END IF
REORDER = SWAP12 .NEQV. SWAPRS
IF (REORDER .AND. NCTR.GT.1) THEN
IF (SWAPRS) THEN
INDEXR = INDEXB
INDEXS = INDEXA
NCGTOR = NCGTOB
NCGTOS = NCGTOA
ELSE
INDEXR = INDEXA
INDEXS = INDEXB
NCGTOR = NCGTOA
NCGTOS = NCGTOB
END IF
CALL OED__CTR_2INDEX_REORDER
+
+ ( NXYZT,NCTR,
+ NCGTOR,NCGTOS,
+ IXOFF (INDEXR),IXOFF (INDEXS),
+ ZCORE (IN),
+
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished ctr reorder '
TEMP = IN
IN = OUT
OUT = TEMP
END IF
IF (NXYZT.GT.1 .AND. NCTR.GT.1) THEN
CALL OED__TRANSPOSE_BATCH
+
+ ( NXYZT,NCTR,
+ TILE,
+ ZCORE (IN),
+
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished transpose batch '
TEMP = IN
IN = OUT
OUT = TEMP
END IF
C
C
C ...enter the cartesian -> spherical transformation or
C cartesian normalization section. After one shell
C is transformed it is moved to its final position.
C This leads to the sequence of events (where ' means
C spherical or cartesian normalization and [] means the
C indices are in positional correspondence):
C
C batch (ij,a,b) --> batch (ij,a,b')
C batch (ij,a,b') --> batch (ij[b'],a)
C batch (ij[b'],a) --> batch (ij[b'],a')
C batch (ij[b'],a') --> batch (ij[a'b'])
C
C
C The space partitioning of the flp array will be
C as follows:
C
C
C | Zone 1 | Zone 2 | Zone 3 |
C
C
C Zone 1 and 2: 2 batches of cartesian (a|b) size
C (set previously)
C
C Zone 3: cart -> spher transformation data
C or
C cartesian normalization factors
C
C
C Determine the memory allocation offsets for the
C cartesian -> spherical transformations or cartesian
C normalizations and generate the transformation
C matrices + associated data for those shells > p-shell.
C The offsets are as follows (x=A,B):
C
C IN = offset for input cartesian (a|b) batch
C OUT = offset for output cartesian (a|b) batch
C
C ZSROTx = offset for x-part transformation matrix
C ISNROWx = offset for # of non-zero XYZ contribution row
C labels for x-part transformation matrix
C ISROWx = offset for non-zero XYZ contribution row
C labels for x-part transformation matrix
C
C
C In case of s- or p-shells no transformation matrix is
C generated, hence if we have s- and/or p-shells, then
C no call to the cartesian -> spherical transformation
C or cartesian normalization routines needs to be done.
C Instead all integrals have to be multiplied by a factor
C SPNORM, which has the following value for each s- and
C p-shell:
C
C For s-type shell = 1
C
C For p-type shell = 2 * norm for s-type
C
C This factor was introduced together with the overall
C prefactor during evaluation of the primitive integrals
C in order to save multiplications.
C
C
ZBASE = MAX (IN,OUT) + NBATCH
IF (SPHERIC) THEN
IF (MXSHELL.GT.1) THEN
CALL OED__XYZ_TO_RY_AB
+
+ ( NXYZA,NXYZB,
+ NRYA,NRYB,
+ SHELLA,SHELLB,
+ 1,ZBASE,
+
+ NROWA,NROWB,
+ NROTA,NROTB,
+ ZSROTA,ZSROTB,
+ ISNROWA,ISNROWB,
+ ISROWA,ISROWB,
+ IUSED,ZUSED,
+ ICORE,ZCORE )
+
+
C WRITE (*,*) ' Finished xyz to ry ab '
ELSE
IUSED = 0
ZUSED = 0
END IF
ELSE
IF (MXSHELL.GT.1) THEN
ZCNORM = ZBASE
CALL OED__CARTESIAN_NORMS
+
+ ( MXSHELL,
+
+ ZCORE (ZCNORM))
+
+
C WRITE (*,*) ' Finished cartesian partial norms '
IUSED = 0
ZUSED = MXSHELL + 1
ELSE
IUSED = 0
ZUSED = 0
END IF
END IF
C
C
C ...do cart -> spher transformation / cart normalization
C (if b > 1):
C
C (ij,a,b) --> (ij,a,b')
C
C
IF (SHELLB.GT.1) THEN
IF (SPHERIC) THEN
CALL OED__SPHERICAL_TRANSFORM
+
+ ( NCTR*NXYZA,
+ NROWB,NXYZB,NRYB,
+ ICORE (ISNROWB),
+ ICORE (ISROWB),
+ ZCORE (ZSROTB),
+ ZCORE (IN),
+
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished sph quart b '
TEMP = IN
IN = OUT
OUT = TEMP
ELSE
CALL OED__NORMALIZE_CARTESIAN
+
+ ( NCTR*NXYZA,
+ NXYZB,
+ SHELLB,
+ ZCORE (ZCNORM),
+
+ ZCORE (IN) )
+
+
C WRITE (*,*) ' Finished normalized cart b '
END IF
END IF
C
C
C ...move transformed b shell (if size > 1):
C
C (ij,a,b') --> (ij[b'],a)
C
C
IF (NRYB.GT.1) THEN
NBATCH = NCTR * NXYZA * NRYB
NOTMOVE = IXOFF (INDEXB)
MOVE = NBATCH / (NOTMOVE * NRYB)
IF (MOVE.GT.1) THEN
CALL OED__MOVE_RY
+
+ ( NBATCH,2,
+ NOTMOVE,MOVE,NRYB,
+ INDEXB,
+ TILE,
+ ZCORE (IN),
+
+ IXOFF,
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished move ry b '
TEMP = IN
IN = OUT
OUT = TEMP
END IF
END IF
C
C
C ...do cart -> spher / cart normalization (if a > 1):
C
C (ij[b'],a) --> (ij[b'],a')
C
C
IF (SHELLA.GT.1) THEN
IF (SPHERIC) THEN
CALL OED__SPHERICAL_TRANSFORM
+
+ ( NCTR*NRYB,
+ NROWA,NXYZA,NRYA,
+ ICORE (ISNROWA),
+ ICORE (ISROWA),
+ ZCORE (ZSROTA),
+ ZCORE (IN),
+
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished sph quart a '
TEMP = IN
IN = OUT
OUT = TEMP
ELSE
CALL OED__NORMALIZE_CARTESIAN
+
+ ( NCTR*NRYB,
+ NXYZA,
+ SHELLA,
+ ZCORE (ZCNORM),
+
+ ZCORE (IN) )
+
+
C WRITE (*,*) ' Finished normalized cart a '
END IF
END IF
C
C
C ...move transformed a shell (if size > 1):
C
C (ij[b'],a') --> (ij[a'b'])
C
C
NBATCH = NCTR * NRYB * NRYA
IF (NRYA.GT.1) THEN
NOTMOVE = IXOFF (INDEXA)
MOVE = NBATCH / (NOTMOVE * NRYA)
IF (MOVE.GT.1) THEN
CALL OED__MOVE_RY
+
+ ( NBATCH,2,
+ NOTMOVE,MOVE,NRYA,
+ INDEXA,
+ TILE,
+ ZCORE (IN),
+
+ IXOFF,
+ ZCORE (OUT) )
+
+
C WRITE (*,*) ' Finished move ry a '
TEMP = IN
IN = OUT
OUT = TEMP
END IF
END IF
C
C
C ...set final pointer to integrals in ZCORE array.
C
C
NFIRST = IN
C
C
C ...ready!
C
C
RETURN
END
|
