File: read-char.lisp

package info (click to toggle)
acl2 3.1-1
  • links: PTS
  • area: main
  • in suites: etch, etch-m68k
  • size: 36,712 kB
  • ctags: 38,396
  • sloc: lisp: 464,023; makefile: 5,470; sh: 86; csh: 47; cpp: 25; ansic: 22
file content (86 lines) | stat: -rw-r--r-- 3,519 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
;; Processing Unicode Files with ACL2
;; Copyright (C) 2005-2006 by Jared Davis <jared@cs.utexas.edu>
;;
;; This program is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by the Free
;; Software Foundation; either version 2 of the License, or (at your option)
;; any later version.
;;
;; This program is distributed in the hope that it will be useful but WITHOUT
;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
;; more details.
;;
;; You should have received a copy of the GNU General Public License along with
;; this program; if not, write to the Free Software Foundation, Inc., 59 Temple
;; Place - Suite 330, Boston, MA 02111-1307, USA.

(in-package "ACL2")

(local (include-book "update-state"))
(local (include-book "open-input-channels"))

(local (defthm assoc-eq-is-assoc-equal
         (equal (assoc-eq a x)
                (assoc-equal a x))))

(defthm read-char$-state
  (implies (and (force (state-p1 state))
                (force (open-input-channel-p1 channel :character state))
                (force (symbolp channel)))
           (state-p1 (mv-nth 1 (read-char$ channel state))))
  :hints(("Goal" :in-theory (disable statep-functions)
          :use ((:instance state-p1 
                           (x state))
                (:instance state-p1 
                           (x (mv-nth 1 (read-char$ channel state))))))))

(defthm read-char$-open-input-channel-p1
  (implies (and (force (state-p1 state))
                (force (open-input-channel-p1 channel :character state))
                (force (symbolp channel)))
           (open-input-channel-p1 channel 
                                  :character
                                  (mv-nth 1 (read-char$ channel state))))
  :hints(("Goal" :in-theory (disable statep-functions)
          :use ((:instance state-p1 
                           (x state))
                (:instance state-p1 
                           (x (mv-nth 1 (read-char$ channel state))))))))

(local (defthmd car-typed-io-list-char
  (implies (and (typed-io-listp x :character)
                (consp x))
           (characterp (car x)))))

(defthm read-char$-character
  (implies (and (force (state-p1 state))
                (force (open-input-channel-p1 channel :character state))
                (car (read-char$ channel state)))
           (characterp (car (read-char$ channel state))))
  :hints(("Goal" :in-theory (disable open-input-channel-p1
                                     open-input-channels)
          :use (:instance car-typed-io-list-char
                          (x (cddr (assoc-equal 
                                    channel 
                                    (open-input-channels state))))))))

(encapsulate
 ()

 (local (defthm lemma
          (implies (and (typed-io-listp x :character)
                        (not (car x)))
                   (not (cadr x)))))

 (defthm read-char$-after-eof
   (implies (and (force (state-p state))
                 (force (symbolp channel))
                 (force (open-input-channel-p channel :character state))
                 (not (car (read-char$ channel state))))
            (not (car (read-char$ channel (mv-nth 1 (read-byte$ channel state))))))
   :hints(("Goal" :in-theory (e/d (read-char$)
                                  (statep-functions))))))


(in-theory (disable state-p1 open-input-channel-p1 read-char$))