File: lessp.lisp

package info (click to toggle)
acl2 8.5dfsg-5
  • links: PTS
  • area: main
  • in suites: bookworm
  • size: 991,452 kB
  • sloc: lisp: 15,567,759; javascript: 22,820; cpp: 13,929; ansic: 12,092; perl: 7,150; java: 4,405; xml: 3,884; makefile: 3,507; sh: 3,187; ruby: 2,633; ml: 763; python: 746; yacc: 723; awk: 295; csh: 186; php: 171; lex: 154; tcl: 49; asm: 23; haskell: 17
file content (185 lines) | stat: -rw-r--r-- 6,266 bytes parent folder | download | duplicates (12)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
; Correctness of Less Than

; Problem: Define an M1 program to compute whether natural number x is less than
; natural number y.  Indicate true with 1 and false with 0.

; Design Plan: I will count x and y both down by 1 and stop when either reaches
; 0.  If y reaches 0 first (or at the same time), x < y was false.  If x
; reaches 0 before y, x < y was true.

; (0) Start ACL2
; (include-book "m1")

(in-package "M1")

; (1) Write your specification, i.e., define the expected inputs and the
; desired output, theta.

(defun ok-inputs (x y)
  (and (natp x)
       (natp y)))

(defun theta (x y)
  (if (< x y) 1 0))

; (2) Write your algorithm.  This will consist of a tail-recursive helper
; function and a wrapper, fn.

; Note:  In this case, the helper and the top-level fn are the same.  We
; don't need both, but we'll stick with the template.

(defun helper (x y)
  (cond ((zp y) 0)
        ((zp x) 1)
        (t (helper (- x 1) (- y 1)))))

(defun fn (x y) (helper x y))

; (3) Prove that the algorithm satisfies the spec, by proving first that the
; helper is appropriately related to theta and then that fn is theta on ok
; inputs.

; Important Note: When you verify your helper function, you must consider the
; most general case.  For example, if helper is defined with formal parameters
; n, m, a, and rest and fn calls helper initializing a to 0 and rest to nil,
; your helper theorem must be about (helper n m a rest), not just about the
; special case (helper n m 0 nil).

(defthm helper-is-theta
  (implies (and (natp x)
                (natp y))
           (equal (helper x y)
                  (theta x y))))

(defthm fn-is-theta
  (implies (ok-inputs x y)
           (equal (fn x y)
                  (theta x y))))

; Disable these two lemmas because they confuse the theorem prover when it is
; dealing with the code versus fn.

(in-theory (disable helper-is-theta fn-is-theta))

; (4) Write your M1 program with the intention of implementing your algorithm.

(defconst *pi*
  '((iload 1)   ;  0   lessp-loop:          -- the code for lessp
    (ifeq 12)   ;  1   if y=0, goto false
    (iload 0)   ;  2
    (ifeq 12)   ;  3   if x=0, goto to true
    (iload 0)   ;  4
    (iconst 1)  ;  5
    (isub)      ;  6
    (istore 0)  ;  7   x = x-1
    (iload 1)   ;  8
    (iconst 1)  ;  9
    (isub)      ; 10
    (istore 1)  ; 11   y = y-1
    (goto -12)  ; 12   goto lessp-loop
    (iconst 0)  ; 13   lessp is false
    (halt)      ; 14
    (iconst 1)  ; 15   lessp is true
    (halt)      ; 16   return a
    ))

; (5) Define the ACL2 function that clocks your program, starting with the
; loop clock and then using it to clock the whole program.  The clock
; should take the program from pc 0 to a HALT statement.  (Sometimes your
; clocks will require multiple inputs or other locals, but our example only
; requires the first local.)

(defun loop-clk (x y)
  (if (zp y)
      4
      (if (zp x)
          5
          (clk+ 13
                (loop-clk (- x 1) (- y 1))))))

(defun clk (x y)
  (loop-clk x y))

; (6) Prove that the code implements your algorithm, starting with the lemma
; that the loop implements the helper.  Each time you prove a lemma relating
; code to algorithm, disable the corresponding clock function so the theorem
; prover doesn't look any deeper into subsequent code.

; Important Note: Your lemmas about your loops must consider the general case.
; For example, if a loop uses the locals n, m, and a, you must characterize
; its behavior for arbitrary, legal n, m, and a, not just a special case (e.g.,
; where a is 0).

(defthm loop-is-helper
  (implies (and (natp x)
                (natp y))
           (equal (m1 (make-state 0
                                  (list x y)
                                  nil
                                  *pi*)
                      (loop-clk x y))
                  (make-state (if (< x y) 16 14)
                              (if (< x y)
                                  (list 0 (- y x))
                                  (list (- x y) 0))
                              (push (helper x y) nil)
                              *pi*))))

(in-theory (disable loop-clk))

(defthm program-is-fn
  (implies (ok-inputs x y)
           (equal (m1 (make-state 0
                                  (list x y)
                                  nil
                                  *pi*)
                      (clk x y))
                  (make-state (if (< x y) 16 14)
                              (if (< x y)
                                  (list 0 (- y x))
                                  (list (- x y) 0))
                              (push (fn x y) nil)
                              *pi*))))

(in-theory (disable clk))

; (7) Put the two steps together to get correctness.

(in-theory (enable fn-is-theta))

(defthm program-correct
  (implies (ok-inputs x y)
           (equal (m1 (make-state 0
                                  (list x y)
                                  nil
                                  *pi*)
                      (clk x y))
                  (make-state (if (< x y) 16 14)
                              (if (< x y)
                                  (list 0 (- y x))
                                  (list (- x y) 0))
                              (push (theta x y)
                                    nil)
                              *pi*))))

; This corollary just shows we did what we set out to do:

(defthm total-correctness
  (implies (and (natp x)
                (natp y)
                (equal sf (m1 (make-state 0
                                          (list x y)
                                          nil
                                          *pi*)
                              (clk x y))))
           (and (equal (next-inst sf) '(HALT))
                (equal (top (stack sf)) (if (< x y) 1 0))))
  :rule-classes nil)

; Think of the above theorem as saying: for all natural numbers x and y, there
; exists a clock (for example, the one constructed by (clk x y)) such that
; running *pi* with (list x y) as input produces a state, sf, that is halted
; and which contains 1 or 0 on top of the stack depending on whether x < y.
; Note that the algorithm used by *pi* is not specified or derivable from this
; formula.