1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
|
;; Copyright (C) 2017, Regents of the University of Texas
;; Written by Cuong Chau
;; License: A 3-clause BSD license. See the LICENSE file distributed with
;; ACL2.
;; Cuong Chau <ckcuong@cs.utexas.edu>
;; May 2019
(in-package "ADE")
(include-book "../link-joint")
(include-book "../tv-if")
(local (include-book "arithmetic-3/top" :dir :system))
(local (in-theory (disable nth)))
;; ======================================================================
;;; Table of Contents:
;;;
;;; 1. DE Module Generator of ALT-MERGE
;;; 2. Specify and Prove a State Invariant
;; ======================================================================
;; 1. DE Module Generator of ALT-MERGE
;;
;; Construct a DE module generator for an alternate merge, ALT-MERGE, using the
;; link-joint model. Prove the value and state lemmas for this module
;; generator.
(defconst *alt-merge$go-num* 2)
(defun alt-merge$data-ins-len (data-size)
(declare (xargs :guard (natp data-size)))
(+ 3 (* 2 (mbe :logic (nfix data-size)
:exec data-size))))
(defun alt-merge$ins-len (data-size)
(declare (xargs :guard (natp data-size)))
(+ (alt-merge$data-ins-len data-size)
*alt-merge$go-num*))
;; DE module generator of ALT-MERGE
(module-generator
alt-merge* (data-size)
(si 'alt-merge data-size)
(list* 'full-in0 'full-in1 'empty-out-
(append (sis 'data0-in 0 data-size)
(sis 'data1-in 0 data-size)
(sis 'go 0 *alt-merge$go-num*)))
(list* 'act 'act0 'act1
(sis 'data-out 0 data-size))
'(select select-buf)
(list
;; LINKS
;; Select
'(select (select-status select-out)
link1
(buf-act act select-in))
;; Select-buf
'(select-buf (select-buf-status select-buf-out)
link1
(act buf-act select-buf-in))
;; JOINTS
;; Alt-Merge
'(g0 (select-out~) b-not (select-out))
'(g1 (m-full-in0) b-and3 (full-in0 select-status select-out~))
'(g2 (m-full-in1) b-and3 (full-in1 select-status select-out))
'(g3 (m-empty-out-) b-or (empty-out- select-buf-status))
(list 'alt-merge-cntl0
'(act0)
'joint-cntl
(list 'm-full-in0 'm-empty-out- (si 'go 0)))
(list 'alt-merge-cntl1
'(act1)
'joint-cntl
(list 'm-full-in1 'm-empty-out- (si 'go 0)))
'(alt-merge-cntl (act) b-or (act0 act1))
(list 'alt-merge-op0
(sis 'data-out 0 data-size)
(si 'tv-if (tree-number (make-tree data-size)))
(cons 'select-out
(append (sis 'data1-in 0 data-size)
(sis 'data0-in 0 data-size))))
'(alt-merge-op1 (select-buf-in) b-not (select-out))
;; Buffer
(list 'buf-cntl
'(buf-act)
'joint-cntl
(list 'select-buf-status 'select-status (si 'go 1)))
'(buf-op (select-in) b-buf (select-buf-out)))
(declare (xargs :guard (natp data-size))))
(make-event
`(progn
,@(state-accessors-gen 'alt-merge '(select select-buf) 0)))
;; DE netlist generator. A generated netlist will contain an instance of
;; ALT-MERGE.
(defund alt-merge$netlist (data-size)
(declare (xargs :guard (natp data-size)))
(cons (alt-merge* data-size)
(union$ (link1$netlist)
*joint-cntl*
(tv-if$netlist (make-tree data-size))
:test 'equal)))
;; Recognizer for ALT-MERGE
(defund alt-merge& (netlist data-size)
(declare (xargs :guard (and (alistp netlist)
(natp data-size))))
(b* ((subnetlist (delete-to-eq (si 'alt-merge data-size) netlist)))
(and (equal (assoc (si 'alt-merge data-size) netlist)
(alt-merge* data-size))
(link1& subnetlist)
(joint-cntl& subnetlist)
(tv-if& subnetlist (make-tree data-size)))))
;; Sanity check
(local
(defthmd check-alt-merge$netlist-64
(and (net-syntax-okp (alt-merge$netlist 64))
(net-arity-okp (alt-merge$netlist 64))
(alt-merge& (alt-merge$netlist 64) 64))))
;; Constraints on the state of ALT-MERGE
(defund alt-merge$valid-st (st)
(b* ((select (nth *alt-merge$select* st))
(select-buf (nth *alt-merge$select-buf* st)))
(and (link1$valid-st select)
(link1$valid-st select-buf))))
;; Extract the input and output signals for ALT-MERGE
(progn
;; Extract the 1st input data item
(defun alt-merge$data0-in (inputs data-size)
(declare (xargs :guard (and (true-listp inputs)
(natp data-size))))
(take (mbe :logic (nfix data-size)
:exec data-size)
(nthcdr 3 inputs)))
(defthm len-alt-merge$data0-in
(equal (len (alt-merge$data0-in inputs data-size))
(nfix data-size)))
(in-theory (disable alt-merge$data0-in))
;; Extract the 2nd input data item
(defun alt-merge$data1-in (inputs data-size)
(declare (xargs :guard (and (true-listp inputs)
(natp data-size))))
(b* ((size (mbe :logic (nfix data-size)
:exec data-size)))
(take size
(nthcdr (+ 3 size) inputs))))
(defthm len-alt-merge$data1-in
(equal (len (alt-merge$data1-in inputs data-size))
(nfix data-size)))
(in-theory (disable alt-merge$data1-in))
;; Extract the "act0" signal
(defund alt-merge$act0 (inputs st data-size)
(b* ((full-in0 (nth 0 inputs))
(empty-out- (nth 2 inputs))
(go-signals (nthcdr (alt-merge$data-ins-len data-size) inputs))
(go-alt-merge (nth 0 go-signals))
(select (nth *alt-merge$select* st))
(select.s (nth *link1$s* select))
(select.d (nth *link1$d* select))
(select-buf (nth *alt-merge$select-buf* st))
(select-buf.s (nth *link1$s* select-buf))
(m-full-in0 (f-and3 full-in0 (car select.s) (f-not (car select.d))))
(m-empty-out- (f-or empty-out- (car select-buf.s))))
(joint-act m-full-in0 m-empty-out- go-alt-merge)))
(defthm alt-merge$act0-inactive
(implies (or (not (nth 0 inputs))
(equal (nth 2 inputs) t))
(not (alt-merge$act0 inputs st data-size)))
:hints (("Goal" :in-theory (enable f-and3 alt-merge$act0))))
;; Extract the "act1" signal
(defund alt-merge$act1 (inputs st data-size)
(b* ((full-in1 (nth 1 inputs))
(empty-out- (nth 2 inputs))
(go-signals (nthcdr (alt-merge$data-ins-len data-size) inputs))
(go-alt-merge (nth 0 go-signals))
(select (nth *alt-merge$select* st))
(select.s (nth *link1$s* select))
(select.d (nth *link1$d* select))
(select-buf (nth *alt-merge$select-buf* st))
(select-buf.s (nth *link1$s* select-buf))
(m-full-in1 (f-and3 full-in1 (car select.s) (car select.d)))
(m-empty-out- (f-or empty-out- (car select-buf.s))))
(joint-act m-full-in1 m-empty-out- go-alt-merge)))
(defthm alt-merge$act1-inactive
(implies (or (not (nth 1 inputs))
(equal (nth 2 inputs) t))
(not (alt-merge$act1 inputs st data-size)))
:hints (("Goal" :in-theory (enable f-and3 alt-merge$act1))))
;; Extract the "act" signal
(defund alt-merge$act (inputs st data-size)
(f-or (alt-merge$act0 inputs st data-size)
(alt-merge$act1 inputs st data-size)))
(defthm alt-merge$act-inactive
(implies (or (and (not (nth 0 inputs))
(not (nth 1 inputs)))
(equal (nth 2 inputs) t))
(not (alt-merge$act inputs st data-size)))
:hints (("Goal" :in-theory (enable alt-merge$act))))
)
;; The value lemma for ALT-MERGE
(defthm alt-merge$value
(b* ((inputs (list* full-in0 full-in1 empty-out-
(append data0-in data1-in go-signals)))
(select (nth *alt-merge$select* st))
(select.d (nth *link1$d* select)))
(implies (and (posp data-size)
(alt-merge& netlist data-size)
(true-listp data0-in)
(equal (len data0-in) data-size)
(true-listp data1-in)
(equal (len data1-in) data-size)
(true-listp go-signals)
(equal (len go-signals) *alt-merge$go-num*))
(equal (se (si 'alt-merge data-size) inputs st netlist)
(list* (alt-merge$act inputs st data-size)
(alt-merge$act0 inputs st data-size)
(alt-merge$act1 inputs st data-size)
(fv-if (car select.d) data1-in data0-in)))))
:hints (("Goal"
:do-not-induct t
:expand (:free (inputs data-size)
(se (si 'alt-merge data-size) inputs st netlist))
:in-theory (e/d (de-rules
alt-merge&
alt-merge*$destructure
alt-merge$act
alt-merge$act0
alt-merge$act1)
(de-module-disabled-rules)))))
;; This function specifies the next state of ALT-MERGE.
(defun alt-merge$step (inputs st data-size)
(b* ((go-signals (nthcdr (alt-merge$data-ins-len data-size) inputs))
(go-buf (nth 1 go-signals))
(select (nth *alt-merge$select* st))
(select.s (nth *link1$s* select))
(select.d (nth *link1$d* select))
(select-buf (nth *alt-merge$select-buf* st))
(select-buf.s (nth *link1$s* select-buf))
(select-buf.d (nth *link1$d* select-buf))
(act (alt-merge$act inputs st data-size))
(buf-act (joint-act (car select-buf.s) (car select.s) go-buf))
(select-inputs (list buf-act act (car select-buf.d)))
(select-buf-inputs (list act buf-act (f-not (car select.d)))))
(list
;; Select
(link1$step select-inputs select)
;; Select-buf
(link1$step select-buf-inputs select-buf))))
;; The state lemma for ALT-MERGE
(defthm alt-merge$state
(b* ((inputs (list* full-in0 full-in1 empty-out-
(append data0-in data1-in go-signals))))
(implies (and (alt-merge& netlist data-size)
(equal (len data0-in) data-size)
(equal (len data1-in) data-size)
(true-listp go-signals)
(equal (len go-signals) *alt-merge$go-num*))
(equal (de (si 'alt-merge data-size) inputs st netlist)
(alt-merge$step inputs st data-size))))
:hints (("Goal"
:do-not-induct t
:expand (:free (inputs data-size)
(de (si 'alt-merge data-size) inputs st netlist))
:in-theory (e/d (de-rules
alt-merge&
alt-merge*$destructure
alt-merge$act
alt-merge$act0
alt-merge$act1)
(de-module-disabled-rules)))))
(in-theory (disable alt-merge$step))
;; ======================================================================
;; 2. Specify and Prove a State Invariant
;; Conditions on the inputs
(defund alt-merge$input-format (inputs data-size)
(declare (xargs :guard (and (true-listp inputs)
(natp data-size))))
(b* ((full-in0 (nth 0 inputs))
(full-in1 (nth 1 inputs))
(empty-out- (nth 2 inputs))
(data0-in (alt-merge$data0-in inputs data-size))
(data1-in (alt-merge$data1-in inputs data-size))
(go-signals (nthcdr (alt-merge$data-ins-len data-size) inputs)))
(and
(booleanp full-in0)
(booleanp full-in1)
(booleanp empty-out-)
(or (not full-in0) (bvp data0-in))
(or (not full-in1) (bvp data1-in))
(true-listp go-signals)
(= (len go-signals) *alt-merge$go-num*)
(equal inputs
(list* full-in0 full-in1 empty-out-
(append data0-in data1-in go-signals))))))
(defthm booleanp-alt-merge$act0
(implies (and (alt-merge$input-format inputs data-size)
(alt-merge$valid-st st))
(booleanp (alt-merge$act0 inputs st data-size)))
:hints (("Goal" :in-theory (enable f-and3
alt-merge$input-format
alt-merge$valid-st
alt-merge$act0)))
:rule-classes (:rewrite :type-prescription))
(defthm booleanp-alt-merge$act1
(implies (and (alt-merge$input-format inputs data-size)
(alt-merge$valid-st st))
(booleanp (alt-merge$act1 inputs st data-size)))
:hints (("Goal" :in-theory (enable f-and3
alt-merge$input-format
alt-merge$valid-st
alt-merge$act1)))
:rule-classes (:rewrite :type-prescription))
(defthm booleanp-alt-merge$act
(implies (and (alt-merge$input-format inputs data-size)
(alt-merge$valid-st st))
(booleanp (alt-merge$act inputs st data-size)))
:hints (("Goal" :in-theory (enable alt-merge$act)))
:rule-classes (:rewrite :type-prescription))
(defthm alt-merge$valid-st-preserved
(implies (and (alt-merge$input-format inputs data-size)
(alt-merge$valid-st st))
(alt-merge$valid-st (alt-merge$step inputs st data-size)))
:hints (("Goal"
:in-theory (e/d (f-sr
f-and3
alt-merge$input-format
alt-merge$valid-st
alt-merge$step
alt-merge$act
alt-merge$act0
alt-merge$act1)
()))))
;; A state invariant
(defund alt-merge$inv (st)
(b* ((select (nth *alt-merge$select* st))
(select.s (nth *link1$s* select))
(select-buf (nth *alt-merge$select-buf* st))
(select-buf.s (nth *link1$s* select-buf)))
(not (equal select.s select-buf.s))))
(defthm alt-merge$inv-preserved
(implies (and (alt-merge$input-format inputs data-size)
(alt-merge$valid-st st)
(alt-merge$inv st))
(alt-merge$inv (alt-merge$step inputs st data-size)))
:hints (("Goal"
:in-theory (e/d (f-sr
alt-merge$input-format
alt-merge$valid-st
alt-merge$inv
alt-merge$step
alt-merge$act
alt-merge$act0
alt-merge$act1)
()))))
|
