1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
|
;; ----- Basic Set Theory Stuff ----
#|
(certify-book "no-dup-set-facts" 0)
|#
;; Sun Dec 21 22:06:19 2003
;;
;; This books contains set of lemmas about set-differences.
;;
(in-package "ACL2")
(defconst *no-dup-set-facts-basic-functions*
'(mem notMem subset del app set-diff set-equal nodup-set))
;; This set of functions are defined in ACL2 package.
;; some function are used in typechecker.lisp
;----------------------------------------------------------
;----------------------------------------------------
(acl2::set-verify-guards-eagerness 2)
(defun mem (c cl)
(if (not (consp cl))
nil
(or (equal (car cl) c)
(mem c (cdr cl)))))
(defun notMem (c cl)
(not (mem c cl)))
(defun subset (s1 s2)
(if (not (consp s1))
t
(and (mem (car s1) s2)
(subset (cdr s1) s2))))
(defun del (a y)
(if (not (consp y))
nil
(if (equal (car y) a)
(cdr y)
(cons (car y) (del a (cdr y))))))
(defun app (a b)
(if (not (consp a))
b
(cons (car a) (app (cdr a) b))))
;------------------------------------------------------
(acl2::set-verify-guards-eagerness 1)
(defun set-diff (total seen) ;; *14*
(declare (xargs :guard (and (true-listp total)
(true-listp seen))))
(if (endp total)
nil
(if (mem (car total) seen)
(set-diff (cdr total) seen)
(cons (car total) (set-diff (cdr total) (cons (car total) seen))))))
;; *14* Note:
;; Set-Diff returns a non-duplicated list that represent
;; the set
;; some work Set Theory stuff
;; mainly about set-diff, nodup-set, the size of the nodup-set
;;
;; this is used for proving termination of class superclass resolution
;; Originally. I did somework with permuation.
;; Later found out Set-equal + Non-Dup suffice.
(defun set-equal (a b)
(declare (xargs :guard (and (true-listp a)
(true-listp b))))
(and (subset a b)
(subset b a)))
;(set-match-free-error nil)
(defthm subset-cons
(implies (subset a b)
(subset a (cons x b))))
(defthm subset-reflexive
(subset x x))
(defthm mem-subset
(implies (and (mem x a)
(subset a b))
(mem x b)))
(defthm subset-transitive
(implies (and (subset a b)
(subset b c))
(subset a c)))
(defthm set-equal-transitive
(implies (and (set-equal a b)
(set-equal b c))
(set-equal a c)))
(defequiv set-equal)
(defcong set-equal equal (mem x s) 2
:hints (("Subgoal *1/4" :cases ((mem x (cdr s))))
("Subgoal *1/4.2"
:use (:instance mem-subset (a acl2::s-equiv) (b s))
:in-theory (disable mem-subset))))
(defthm set-equal-cons
(implies (set-equal a b)
(set-equal (cons x a) (cons x b))))
(defthm set-equal-mem-cons-2
(implies (mem x l)
(set-equal (cons x l) l)))
(in-theory (disable set-equal))
(defun set-diff-cong-induct (s s-equiv total)
(if (endp total)
(cons s s-equiv)
(if (mem (car total) s)
(set-diff-cong-induct s s-equiv (cdr total))
(set-diff-cong-induct (cons (car total) s) (cons (car total) s-equiv) (cdr total)))))
(defthm set-equal-cons-f
(implies (not (set-equal (cons x a) (cons x b)))
(not (set-equal a b)))
:hints (("Goal" :in-theory (enable set-equal)))
:rule-classes :forward-chaining)
(defcong set-equal equal (set-diff total acl2::seen) 2
:hints (("Goal" :in-theory (disable set-equal-cons)
:induct (set-diff-cong-induct acl2::seen acl2::seen-equiv total))))
(defun subset-set-diff-induct (total a b)
(if (endp total)
(cons a b)
(subset-set-diff-induct (cdr total) (cons (car total) a) (cons (car total) b))))
(defthm subset-set-diff
(implies (subset a b)
(subset (set-diff total b) (set-diff total a)))
:hints (("Goal" :induct (subset-set-diff-induct total a b))))
;;--------------------------------------------------------------------
; ---- nodup-set -----
(defun nodup-set (s)
(declare (xargs :guard (true-listp s)))
(if (endp s)
t
(and (not (mem (car s) (cdr s)))
(nodup-set (cdr s)))))
(defthm mem-set-diff
(implies (mem a seen)
(not (mem a (set-diff total seen)))))
(defthm set-diff-is-a-nodup-set
(nodup-set (set-diff total seen))
:rule-classes :type-prescription)
(defun subset-nodup-set-size-induct (s1 s2)
(if (endp s1)
s2
(subset-nodup-set-size-induct (cdr s1) (del (car s1) s2))))
(defthm del-set-len
(implies (mem x s)
(equal (len s) (+ 1 (len (del x s))))))
(defthm mem-del
(implies (not (equal a b))
(equal (mem a (del b x))
(mem a x))))
(defthm del-nodups
(implies (nodup-set s)
(nodup-set (del x s))))
(defthm del-nodup-set-subset
(implies (and (subset (cons x s1) s2)
(nodup-set (cons x s1)))
(subset s1 (del x s2))))
; --- to talk about termination, we talk about the number of unseen
; --- classes decrease.
(defthm subset-nodup-set-size
(implies (and (subset s1 s2)
(nodup-set s1)
(nodup-set s2))
(<= (len s1) (len s2)))
:hints (("Goal" :induct (subset-nodup-set-size-induct s1 s2)))
:rule-classes :linear)
(defun len-set-equal-nodup-set-x-induct (s1 s2)
(if (endp s1)
s2
(len-set-equal-nodup-set-x-induct (cdr s1) (del (car s1) s2))))
(defthm len-set-equal-nodup-set-x
(implies (and (mem a s2)
(not (mem a s1))
(subset s1 s2)
(nodup-set s1)
(nodup-set s2))
(< (len s1) (len s2)))
:hints (("Goal" :induct (len-set-equal-nodup-set-x-induct s1 s2))))
(defthm mem-set-diff-x
(implies (and (mem a total)
(not (mem a seen)))
(mem a (set-diff total seen))))
(defthm len-set-diff-mem
(implies (and (not (mem a seen))
(mem a total))
(< (len (set-diff total (cons a seen)))
(len (set-diff total seen))))
:hints (("Goal" :do-not-induct t
:use ((:instance len-set-equal-nodup-set-x
(s1 (set-diff total (cons a seen)))
(s2 (set-diff total seen))))))
:rule-classes :linear)
;; ----------- Above enough rules about set-diff -----------
|
