1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
#------------------------------------------------------------------------------#
# Distributed under the OSI-approved Apache License, Version 2.0. See
# accompanying file Copyright.txt for details.
#------------------------------------------------------------------------------#
# This file contains the option and dependency logic for Python support,
# moved from DetectOptions.cmake to allow for multiple python versions.
# Python
if(PYVER)
set(PY3VER ${PYVER})
else()
set(PY3VER 3)
endif()
# Not supported on PGI
if(CMAKE_CXX_COMPILER_ID STREQUAL PGI)
if(ADIOS2_USE_Python STREQUAL ON)
message(FATAL_ERROR "Python bindings are not supported with the PGI compiler")
elseif(ADIOS2_USE_Python STREQUAL AUTO)
message(WARNING "Disabling python bindings as they are not supported with the PGI compiler")
set(ADIOS2_USE_Python OFF)
endif()
endif()
# Not supported without shared libs
if(NOT SHARED_LIBS_SUPPORTED)
if(ADIOS2_USE_Python STREQUAL ON)
message(FATAL_ERROR "Python bindings are not supported without shared library support")
elseif(ADIOS2_USE_Python STREQUAL AUTO)
message(WARNING "Disabling python bindings since no shared library support was detected.")
set(ADIOS2_USE_Python OFF)
endif()
endif()
if(ADIOS2_USE_Python STREQUAL AUTO)
if(PYVER)
find_package(Python ${PYVER} EXACT COMPONENTS Interpreter Development NumPy)
else()
find_package(Python 3 COMPONENTS Interpreter Development NumPy)
endif()
if(Python_FOUND AND ADIOS2_HAVE_MPI)
find_package(PythonModule COMPONENTS mpi4py mpi4py/mpi4py.h)
endif()
elseif(ADIOS2_USE_Python)
if(PYVER)
find_package(Python ${PYVER} EXACT REQUIRED COMPONENTS Interpreter Development NumPy)
else()
find_package(Python 3 REQUIRED COMPONENTS Interpreter Development NumPy)
endif()
if(ADIOS2_HAVE_MPI)
find_package(PythonModule REQUIRED COMPONENTS mpi4py mpi4py/mpi4py.h)
endif()
endif()
if(Python_FOUND)
if(ADIOS2_HAVE_MPI)
if(PythonModule_mpi4py_FOUND)
set(ADIOS2_HAVE_Python ON)
endif()
else()
set(ADIOS2_HAVE_Python ON)
endif()
endif()
# Even if no python support, we still want the interpreter for tests
if(BUILD_TESTING AND NOT Python_Interpreter_FOUND)
find_package(Python REQUIRED COMPONENTS Interpreter)
endif()
if(Python_Interpreter_FOUND)
# Setup output directories
if(Python_Development_FOUND)
lists_get_prefix("Python_INCLUDE_DIRS;Python_LIBRARIES;Python_SITEARCH" _Python_DEVPREFIX)
else()
lists_get_prefix("Python_EXECUTABLE;Python_SITEARCH" _Python_DEVPREFIX)
endif()
string_strip_prefix(
"${_Python_DEVPREFIX}" "${Python_SITEARCH}" CMAKE_INSTALL_PYTHONDIR_DEFAULT
)
set(CMAKE_INSTALL_PYTHONDIR "${CMAKE_INSTALL_PYTHONDIR_DEFAULT}"
CACHE PATH "Install directory for python modules"
)
mark_as_advanced(CMAKE_INSTALL_PYTHONDIR)
set(CMAKE_PYTHON_OUTPUT_DIRECTORY
${PROJECT_BINARY_DIR}/${CMAKE_INSTALL_PYTHONDIR}
)
endif()
|
