File: apertium-kaz.kaz.rlx

package info (click to toggle)
apertium-kaz 0.1.0~r61338-1
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 21,436 kB
  • sloc: python: 368; sh: 203; makefile: 154; xml: 94
file content (1230 lines) | stat: -rw-r--r-- 33,572 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230


# ============================================================================ #
#            A COMMENTARY ON FORMATTING OF MAJORITY OF RULES
#              (read: a wannabe FORMATTING GUIDELINES)
# ============================================================================ #

# Lines do not exceed 79 characters.
#
# Rule layout
# ===========
#
# There are two alternative layouts for writing a rule. An example for the
# first one (of course the body of the rule won't be commented out):
#
#        # INPUT: ^терістік/тер<v><tv><coop><ifi><p1><pl>/терістік<n><attr>/
#        #        терістік<n><nom>$ ^бетіндегі/бет<n><px3sp><loc><attr>/
#        #        бет<n><px3sp><loc><subst><nom>/$
#        # OUTPUT: [0]^терістік/терістік<n><attr>/терістік<n><nom>$
#                   ^бетіндегі/бет<n><px3sp><loc><attr>...$
#         REMOVE V IF
#                (0 PRE-N)
#                (1C N)
#        ;
#        # any additional comments here (if necessary)
#
# An abstract example of the second layout:
#
#        # An explanation of what the rule does (if it's not obvious from
#        # code!), a name or any other comment that clarifies its purpose
#         SELECT ABC IF
#                (0 DEF)
#                (1 GHI)
#        ;
#        ## A sentence with the [0]form the rule was written for.
#        ## (!) A corner-case-sentence: the rule mispredicted on it initially
#        ## but was modified accordingly (additional constraints etc.); or the
#        ## rule still mispredicts on it, but this kind of sentences aren't
#        ## that frequent. (Alternatively, place the corner-case sentence on
#        ## the same line as the additional constraint).
#
# The first layout is more appropriate when you come up with a rule inductively
# (i.e. you see a sentence badly translated because of errors in disambiguation
# and want to fix it), the second one when you arrived at it deductively. E.g:
#
#        # Participle appears immediately before a verb (verbal adverb doesn't)
#         REMOVE Participle IF
#                (NOT 1C V OR Vaux)
#        ;
#        ## Есік [0]ашып, ол үйге кірді.
#
# In context of apertium-kaz, the difference between a participle and a verbal
# adverb is that participle immediately precedes a verb and verbal adverb
# doesn't. We know this even without looking at tests, but it is a good idea
# to back up the rule with a test case.
#
# Sometimes you can't fully disambiguate a form with only one rule. In that
# case, several rules dealing with the same thing can be grouped together:
#
#         # What the rule does?
#          SELECT ABC IF
#                 (0 DEF)
#                 (1 KLM)
#         ;
#          REMOVE XYZ IF
#                 (0 DEF)
#                 (1 NOP)
#                 (2 QRS)
#          ;
#          ## Example sentences for both of the rules.
#          ## Another example sentence.
#
# Where a rule is placed?
# =======================

#                                   Any context involved?
#                                   /                   \
#                                 YES                   NO
#                                 /                       \
#                 Disambiguates a particular wordform?   "Heuristics" section
#                   /                         \          at the end of the file
#                 YES                         NO
#                 /                             \
#     "Wordform/lemma specific rules"        Readings of
#            section                        different POS?
#                                           /           \
#                                        YES            NO
#                                        /                \
#                                "POS marking"             \
#                              at the beginning             \
#                                                   Corresponding section
#                                                   ("Verbs", "Adjectives" etc.)

# ============================ #
# END OF FORMATTING GUIDELINES #
# ============================ #

# ========== #
# Delimiters #
# ========== #

DELIMITERS = "<.>" "<!>" "<?>" "<...>" "<¶>" ;
SOFT-DELIMITERS = "<,>" ;

SUBREADINGS = LTR ; # Alternate, left-to-right (main reading on the left)

# ============= #
# Tags and sets #
# ============= #

SETS

LIST BOS = (>>>) ;
LIST EOS = (<<<) ;

# First-level/Parts-of-speech tags
# ================================

LIST A = adj ;
LIST Adv = adv ;
LIST Pron = prn ;
LIST Pron-Pers = (prn pers) ;
LIST N = n ;
LIST IJ = ij ;
LIST Prop = np ;
LIST V = v ;
LIST Vaux = vaux ;
LIST Cop = cop ;
LIST Det = det ;
LIST CC = cnjcoo ;
LIST CS = cnjsub ;
LIST Interj = ij ;
LIST Num = num ;
LIST Post = post ;
LIST Postadv = postadv ;
LIST Cm = cm ;
LIST Rquot = rquot ;

# POS sub-categories
# ==================

LIST Pers = pers ;
LIST Interr = itg ;

# "Syntactic" tags
# ================

LIST Advl = advl ;
LIST Attr = attr ;
LIST Subst = subst ;
LIST N-LIKE = subst n np prn ; # Actually, see NOMINAL

# Morphosyntactic properties   # if you find yourself embracing the same tag in
# ==========================   # brackets over and over again, you may want to
                               # add it here

LIST Sg = sg ;
LIST Pl = pl ;

LIST Nom = nom ;
LIST Gen = gen ;
LIST Dat = dat ;
LIST Acc = acc ;
LIST Abl = abl ;
LIST Loc = loc ;
LIST Ins = ins ;

LIST P1 = p1 ;
LIST P2 = p2 ;
LIST P3 = p3 ;

LIST PersonalPossessives = px1sg px2sg px3sp px1pl px2pl ;

# Specific lexemes 
# ==========================

LIST Year = "жылғы" "жыл" ; 

# Noun sets 
# ==============

SET NGDAALI = Nom | Dat | Dat | Acc | Abl | Loc | Ins ;

# Adjective sets
# ==============

LIST A/Advl = (adj advl) ;
LIST A/Subst = (adj subst nom) ;
SET A1-Nom = A/Advl | A/Subst ;

# Verb sets
# =========

LIST FiniteVerb = pres aor past ifi ifi_evid fut fut_plan imp opt;
LIST V-P3 = (v p3) (vaux p3) (cop p3) ;
LIST Gerund = ger ger_ppot ger_past ger_perf ger_impf ger_abs ;
SET V-NotGerund = V - Gerund ;
LIST Participle = prc_perf prc_impf prc_cond prc_vol prc_plan ;
LIST Prc-vol = prc_vol ;
LIST VerbalAdverb = gna_perf gna_cond gna_until gna_after ;
LIST VerbalAdjective = gpr_past gpr_fut gpr_pot gpr_impf ;
LIST FourAuxiliaries = "тұр" "жүр" "отыр" "жат" ;
LIST V-IV = (v iv) ;
LIST V-TV = (v tv) ;

# All possible word categories
# ============================

SET WORD = N | V | A | Post | Postadv | Pron | Det | Adv | CC | CS | Interj |
           Num | ("\?") ;

SET PRE-N =  A | Det | Postadv | Num | (n gen) | (prn gen) | CC | (attr) ;

SET MARK =  Cm | ("\\") | ("\;") | ("\(") ;

SET WORDMARK = WORD | MARK ;

SET N-MOD = A | Det | Num | (n gen) | (prn gen) ;

SET ADJ-MOD = Postadv | Adv ;

SET NPMARK = N-MOD | ADJ-MOD ;

SET NOMINAL = N | Prop | Pron | Subst | Gerund ;

# Categories which cannot be part of a noun phrase
# ================================================

SET NPNH = WORDMARK - PRE-N ;
SET NPNHA = WORDMARK - PRE-N - Adv ;
SET NOT-ADV = WORDMARK - Adv ;

# Barriers
# ========

SET S-BOUNDARY = CS | Interr | EOS ;


# ======= #
  SECTION # (COPULAS)
# ======= #


#




 REMOVE SUB:1 Cop IF
        (NOT 1 EOS OR MARK)
;
 REMOVE SUB:1 Cop IF
        (-1 BOS OR MARK) ## Headings or enumerations
;
##


#
# SELECT SUB:1 Cop IF
#        (1 EOS OR MARK)
#        (NOT 0 Interj) ## Дұрыс, оның мысығы бар.
#        (NOT 0 FiniteVerb) ## 74 ... барлығы 53 ел [0]қатысты.
#;
## Жоқ, Айгүлдің күшігі [0]жоқ, оның мысығы [0]бар.


# ======= #
  SECTION
# ======= #



# POS marking
# ===========

SELECT N IF
        (0 ("сурет"i))
        (-1 (adj advl) OR Det OR A)
       ;


# This rule is too general, breaks a few things.Corrected

#INPUT: ^әдемі/әдемі<adj> 
#^жер/же<v><tv><gpr_fut>/жер<n><nom>/жер<n><attr>/же<v><tv><fut><p3><pl>/же<v><tv><fut><p3><sg>/же<v><tv><gpr_fut><subst><nom>/жер<v><iv><imp><p2><sg>/жер<v><tv><imp><p2><sg>/жер<n><nom>+е<cop><aor><p3><pl>/жер<n><nom>+е<cop><aor><p3><sg>$
#OUPUT:  ^әдемі/әдемі<adj> 
#^жер/жер<n><nom>$

SELECT N IF
	(0 ("жер"))
	(-1 A)
;

# INPUT: for examle: "ата келді" translated as "grandfather come" 
SELECT N IF
	(0 ("ата"))
       ( (NOT -1 N) OR (NOT -1 BOS))
	( (NOT -1 (Nacc)) OR (NOT -1 BOS))



# INPUT:  "жүз теңге" translated as "hundred coins", екі жүз адам "two handred people"
#"адамдардың жүзі" translated a "face of people"
# ^жүз/жүз<num>/жүз<n><nom>/жүз<n><attr>/жүз<num><subst><nom>/жүз<v><iv><imp><p2><sg>/жүз<n><nom>+е<cop><aor><p3><pl>/жүз<n><nom>+е<cop><aor><p3><sg>/жүз<num><subst><nom>+е<cop><aor><p3><pl>/жүз<num><subst><nom>+е<cop><aor><p3><sg>$^
SELECT Num IF
	((0 Num) OR (-1 ))
	(1 N)
;


 SELECT FiniteVerb IF
      (1 EOS OR ("де"i))               # FIXME s/.*/SentenceBoundary/
       (NOT 0 ("шығар"i) OR ("бар"i))   # FIXME a better way?
;
## (!) 40 . Мүмкін бұл Азамат [0]шығар?
##  (!) 13 . Жоқ, Айгүлдің күшігі жоқ, оның мысығы [0]бар.
## Мағынасы төңкеріліп [0]кетті деп ойламағаным үшін ғафу етіңіз.


#
 SELECT Interj IF
        (-1 BOS)
        (1 Cm)
;
## "Мысалы, ежелгі заманның өзінде Арал теңізі көп елдерге мәлім болған."


# INPUT: ^Мен/Мен<cnjcoo>/Мен<post>/Мен<prn><pers><p1><sg><nom>$
#        ^қазақпын/қазақ<n><nom>+е<cop><p1><sg>$
# OUTPUT: [0]^Мен/Мен<cnjcoo>/Мен<prn><pers><p1><sg><nom>$
#         ^қазақпын/қазақ<n><nom>+е<cop><p1><sg>$
 REMOVE Post IF
        (NOT -1 NOMINAL)
;
#

# An adjective ending with -LI is ambiguous with: 1) a noun or adjective in
# accusative, and 2) with  a verb in <ifi> form.
 REMOVE Acc IF
        (0 (n acc) OR (adj subst nom))
        (0 A)
        (NOT 1 V)
;
 REMOVE V IF
        (0 A)
        (0 (ifi))
        (NOT 1 EOS OR Cm)
;
 SELECT A IF
        (-1 ("аса"i) OR ("өте"i))
        (0 A)
        (0 (n acc))
;
 "<атты>" SELECT A IF
                 (1 N)
;
 "<топырақты>" SELECT A IF
                      (1 N)
;
## 53 . Еуро-2012 туралы [0]қызықты статистикаға көз салыңыз.
## 91 . Өйткені, <...> Әл-Истахри келтірген мәліметтер аса [0]құнды саналады.
## 184 . Үшінші қабатта «Тәуелсіз Қазақстандағы жаңа Түркістан» [0]атты экспозициялар қойылған.


# Proper noun or not?
 SELECT Prop IF
        (0 ("[:upper:]+[:lower:]*"r))
        (NOT -1 BOS)
;
## 108. Өйткені бүгінгі [0]Арал деген атау сол XVII ғасырдан бергі жерге берілген.
 SELECT Prop IF
        (0 Prop)
        (0 ("<[:upper:][:upper:]+>"r))
;
## [0]АЗАМАТ ҚАЙДА?
 SELECT Prop IF
        (1 ("мен") + Post)
        (2 Prop)
;
## [0]Азамат пен Айгүл бақшада.


#
 SELECT Pron IF
        (0C Det OR Pron)
        (1 Adv)
;
## 44 . [0]Ол енді ол дыбысты анығырақ ести бастады.


# INPUT: ^терістік/тер<v><tv><coop><ifi><p1><pl>/терістік<n><attr>/
#        терістік<n><nom>$ ^бетіндегі/бет<n><px3sp><loc><attr>/
#        бет<n><px3sp><loc><subst><nom>/$
# OUTPUT: [0]^терістік/терістік<n><attr>/терістік<n><nom>$
#         ^бетіндегі/бет<n><px3sp><loc><attr>...$
 REMOVE V IF
        (0 PRE-N)
        (1C N)
;
#


# INPUT: ^бақша/бақша<n><nom>$ ^арқылы/арқылы<post>/арқылы<adv>$
# OUTPUT: ^бақша<n><nom>$ [0]^арқылы<post>$
 REMOVE Adv IF
        (0 Post)
        (-1 N)
        (NOT 0 ("бірге"i)) # мысығымен бірге<post> үйде<n>
                           # бақшада бірге<adv> ойнайды<v>
                           # бақша арқылы<post> барамын<v>
;
#kaz-eng


# INPUT: ^заңды/заң<n><acc>/заңды<adj>/заң<n>+лы<post>$
# INPUT: ^заңды/заң<n><acc>/заңды<adj>/заң<n>+лы<post>$
 REMOVE Sub:1 Post IF
 	(0 N)
	(0 A)
;


# Determiners
# ===========



# FIXME removes determiner even when there is a noun 1 to the right
#REMOVE Det IF
#       ((NEGATE 1 N OR Subst) OR (NEGATE 1 A LINK 1 N OR Subst))
#;
## 44 . Ол енді ол дыбысты анығырақ ести бастады.
## (!) 34 . Ол Азаматтың қайда екенін білсе де айтқысы келген жоқ.



# Nouns
# =====



#
 REMOVE Attr IF
       (0 N OR Prop)
       (NOT 0 Loc)
       (NOT 1 N OR Prop)
;
## 176. Орталықта Түркістанның төл тарихына арналған музейлік [0]экспозиция жасақталған.
## (!) 184 . Үшінші қабатта «Тәуелсіз [0]Қазақстандағы жаңа Түркістан» атты экспозициялар қойылған.


# Select attributive reading of the first noun of the II izafet construct
# (as Tatar grammars call it)
# SELECT Attr IF
#        (0C N OR Prop)
#        (1 N OR Prop OR Subst)
#        (1 (px3sp))
#;

# Select attributive reading of the first noun of the II izafet construct
# (as Tatar grammars call it)
 SELECT Nom IF
        (0C N OR Prop)
        (1 N OR Prop OR Subst)
        (1 (px3sp))
;
# Was: SELECT 'Attr'


## 111. Түркияның оңтүстік-шығысындағы [0]Газиантеп қаласында кеше болған жарылыстан қаза тапқандар саны 9-ға жетті.


# If a former gerund or verbal adjective was lexicalized as a noun, select noun
 SELECT N IF
        (0 N)
        (0 Gerund  OR (gpr_pot))
;
## professions, such as "оқушы"; -U gerunds , in theory other gerunds too


 SELECT Det IF
        (0 Det)
        (0 (gpr_ppot))
;
## жетерлік has both readings, but we almost always want to translate it as det


REMOVE PersonalPossessives IF
		(0 NOMINAL)
		(NOT 0 (gen))
		(1 (px3sp))
;
## only indefinite possessors can leave off the genitive suffix, and something possessed itself has to be definite,
## so: something possessed can only possess something else if it has gen case,
## so: px* with no gen cannot precede px3sp, so if that's one of the possible readings, you probably don't want it.
## 1929 ж. сырттай өлім жазасына кесілді.


# Adjectives
# ==========



# select adverbial reading of adjectives if any verbal form except gerund follows
# FIXME CHECK it might be a gerund as well
 SELECT Advl IF
         (1C V-NotGerund)
;
##


# select adj+cop reading at the end of a sentence
 SELECT Sub:1 Cop IF
        (0C A1-Nom)
        (1 EOS OR MARK)
;
 REMOVE Subst IF # we want adj+cop reading here, not adj.subst+cop
        (0C A1-Nom)
        (1 EOS OR MARK)
;
## 19 . Ол еш нәрсені көріп тұрған [0]жоқ, ол санап жатыр.


#
REMOVE SUB:1 P3 IF
       (0/1 Cop)
       (0/1 P1)
;
## "Біз [0]қуаныштымыз."



# Postpositions
# =============



#
"<қатар>" SELECT Post IF
                 (-1 Pron + Ins)
;
## 174 . Орталық сонымен [0]қатар оқушыларға тәрбие беруде де маңызды рөл атқарады.
## 148 . Ол АҚШ үкіметін WikiLeaks сайтын қудалауын тоқтатуға шақырып,
## өзін ресейлік Pussy Riot панк тобымен және New York Times басылымымен [0]қатар қойды.

#
 "<қарай>" SELECT Post IF
        (-1 Dat)
;
##


#
 "<қарағанда>" SELECT Post IF
        (-1 Dat)
;
##


#
 "<қарамастан>" SELECT Post IF
        (-1 Dat)
;
##


#
 "<дейін>" SELECT Post IF
        (-1 Dat)
;
##


#
 "<бері>" SELECT Post IF
        (-1 Abl)
;
##


#
 "<бірге>" SELECT Post IF
        (-1 Ins)
;
##


#
 "<қоса>" SELECT Post IF
        (-1 Dat)
;
##


#
 "<кейін>" SELECT Post IF
                (-1 Abl)
;
## 23. Айгүл санап біткеннен кейін айналасына қарады.



# Verbs
# =====



#
 REMOVE Participle IF
        (NOT 1C V OR Vaux)
;
##


# <prc_cond> vs. <gna_cond>
 REMOVE (prc_cond) IF
        (NOT 1 ("бол") + V)
;
## 34 . Ол Азаматтың қайда екенін [0]білсе де айтқысы келген жоқ.


#
 SELECT Participle IF
        (0C Participle OR VerbalAdverb)
        (1 Vaux)
;
## 16 . Азамат ескі үлкен бір ағашқа қарай қатты [?]жүгіріп бара жатыр, ол сол
## ағаштың артына Айгүлден [0]жасырынып жатыр.


#
 REMOVE Vaux IF
        (NOT -1 Participle)
;
 SELECT Vaux IF
        (-1C Participle) 
        (NOT 1 Vaux) 
;
## 187 . Біздің дәуірімізден 1 миллион жыл бұрын өмір сүрген "тік жүретін адамнан" [0]бастап, өз замандастарына дейінгі
## кезеңдерді қамтитын, ... орталықтың экспозициясы негізгі сегіз ірі бөлімнен тұрады.

 REMOVE Vaux IF 
        (0 Vaux OR V)
        (1 Vaux) 
; 
       

# Imperative or not?
# ------------------


# <Vaux p3> is more common, so let's set it as default
# Rules for selecting imperative reading of these three (if any) must be placed
# before this rule
 SELECT (vaux p3) IF
        (-1 (prc_perf))
        (0 ("<жүр>") OR ("<тұр>") OR ("<отыр>"))
;
## 15. Олардың анасы мысығымен бірге үйде, ол терезеден Азамат пен Айгүлдің
## ойнағанына қарап [0]тұр.
## 36 . Әлі де болса Азаматты табуға әрекет етіп [0]жүр.


# 2p sg imperative form is a bare stem, so it is often ambigious with other
# parts of speech
 REMOVE (imp) IF
        (NOT 1 EOS OR MARK OR ("де"))
;
##  96 . Ал оң жақ жағалауы батпақты, онда [0]қалың орман өскен.
## [0]Бар деп айттым мен оған.


# ----------


#
 SELECT (gpr_past) IF
        (0C (ger_past) + Nom)
        (1 N)
;


 REMOVE IJ IF
        (0 A)
        (1 N)
;

# e.g., дұрыс! (<ij>) | дұрыс жерден (<adj>)


##  172 . Сот арқылы немесе өзгеде осындай құзыреті бар мемлекеттік органдардың
## шешімі арқылы тәркіленген мұражайлық маңызы бар жинақтардың немесе
## [0]жекелеген заттардың есебінен;


###################   TO BE DONE   ####################


# Deciding about the number of a verb or copula in the 3 person
# Basic idea is to remove plural reading if subject is not in plural,
# but there a lot of corner cases, which lead to lots of mispredictions.
# So let's just delete plural reading for now.
#
# In Tatar, when the subject indicates the number, this LAR affix for the verbs
# in 3 person is kind of optional too, so singular reading will work/is right for
# the majority of cases.
#
# Selecting plural reading might be a more productive approach.
 REMOVE Pl IF
        (0 V OR Vaux OR Cop)
        (0 P3)
;
##

# Thought that the above rule should cover copulas, seems that sometimes it doesn't
  REMOVE SUB:1 Pl IF
        (0/1 Cop)
       (0/1 P3)
;


# Wordform/lemma-specific rules   # Adding new stuff here is discouraged.
# =============================   # Try to generalize, if possible, existing
                                  # rules.



#
 "<өте>" SELECT Adv IF (1 A) ;
## Бірақ кеше _өте_ суық еді!


# ugly and RISKY
 "<сол>" SELECT Det IF
        (NOT 1 ("қол"i) OR ("жақ"i))
;
## (!) Күйеуім - сол жақтың қазағы.


#
 "<аса>" SELECT Adv IF
         (1 A)
;
## "Әл-Истахри келтірген мәліметтер аса құнды саналады."


#
 "<ал>" REMOVE CC IF
        (NOT -1 BOS OR Cm )
;
## Бөлмеде шкаф бар, содан бiр кiтап ал.

#
 "<жылы>" SELECT N IF
        (-1 Num)
;
##


#
 "<жылы>" SELECT N IF
        (-1 A)
;
##


#
 "<қарасты>" SELECT A IF
        (-1 (dat))
;
## 177. Орталыққа _қарасты_ Түркістан қаласында Н.Оңдасынов атындағы
## тарихи-мемориалдық мұражайы атты филиал жұмыс жасайды.


#
 "<қайта>" SELECT Adv IF
        (1C V)
;
## 41 . Ол дыбыс қайта естіледі!
## Ол қайта алмайды.


#
 "<енді>" SELECT Adv IF
        (1* Acc BARRIER EOS)
        (1* V BARRIER EOS)
;
##


#
 "<көптеген>" SELECT Det IF
        (1 N + Pl)
;
##


# ambigious with v.pass
 "<құрал>" SELECT N IF
        (-1 A OR (n attr))
;
##


# UGLY
# "сый" is certainly not <v.iv.imp> in the following example,
# I don't think that сый<imp> is ever used
 "<сый>" SELECT N
;
## 171. Жеке және заңды тұлғалардан _сый_ немесе мұра ретінде қабылданған заттар
## есебінен.


# imperative of "ісу" ("to swell") - just like "<сый>" above sounds odd,
# but let's try to deal with it in a less ugly way
 "<іс>" SELECT N IF
        (-1 A)
;
## 178. ...тәрбиелік мәні бар іс-шараларды бірге ұйымдастыру...


# FIXME: could be achieved with a more general rule I think
 "<көрме>" SELECT N IF
        (1 ("зал"i))
;
## 181. Ғимарат 3 қабаттан, 5 көрме залынан, конференция залынан,
## қолөнершілердің шеберханасы...


#
 SELECT N IF
        (0 ("же"i) + (gpr_fut))
        (0 ("жер"i) + N)
;
## 24 . Ол "Азамат қай [0]жерге кетті?  Оны көрдіңдер ме?" деп іздеп жатыр.


#
"<қарайды>" SELECT ("қара") IF
                   (-1 Dat)
;
## 30 . Айгүл терезеде тұрған анасына қарайды.


#
 SELECT CC IF
        (0 ("сондай-ақ"i))
        (-1 BOS OR Cm)
;
## 87 . Сондай-ақ, Арал теңізінің көлемі жайлы, Арал теңізі жайлы ұғымдар сонау
## ерте дүние әдебиеттерінде де кездеседі.


#
 SELECT N IF
        (0 ("құрама"i))
        (-1 PRE-N)
;
## 76 . Қазақстандық құрама «А» тобында соңғы орында қалып қойды.


#
 SELECT N IF
        (0 ("қор"))
        (-1 N)
;
## 169. Музей [0]қоры Қазақстан Республикасы Мәдениет және ақпарат министрінің...


#
 SELECT A IF
        (0 ("құрама"))
        (-1 (np top))
;
## 69. Франция құрамасының бұрынғы ойыншысы Мишель Платини...


#
 "<жинағы>" SELECT N IF
            (-1 N + Pl)
;
## 165. ...тарихи жәдігерлер жинағы арқылы көрсету.
## Қазақстан заңдарының жинағы


#
 "<Ертең>" SELECT Adv
;
 "<ертең>" SELECT Adv IF
           (1 V)
;
## Ертең келесің бе?
## Ертең Елбасы Нұрсұлтан Назарбаев Қазақстанның 2050 жылға дейінгі даму бағдарламасын жариялайды.
## Оны ертең еститін боласыздар.


#
 SELECT N IF
        (0 ("сыра"i))
        (1 ("іш") + V)
;
## Шелекпен сыра ішемін.


# да<postadv/conj>
 SELECT SUB:1 Postadv IF
        (0 (gna_cond))
;
## 34 . Ол Азаматтың қайда екенін [0]білсе+[0/1_or_-1]де айтқысы келген жоқ.  # with SUBREADINGS = LTR ; option
## Ол Азаматтың қайла екенін [0]білсе+[0/1]де+[0/2_or_-1]мі?                  # with SUBREADINGS = LTR ; option


#
 SELECT Adv IF
        (0 ("бірге"))
        (NOT -1 Ins)
        (1 V)
;
## 6 . Азамат пен Айгүл ойнағанды жақсы көреді, олар әрдайым үлкен үйдің алдындағы бақшада [0]бірге ойнайды.
## (!) Ол Азаматпен бірге келді.


#
 "<жасар>" SELECT A IF
                  (-1 Num)
;
## 7 . Азамат алты жасар кішкентай бала.

 SELECT Pron IF
        (0 ("<ешкім>"i))
## 70. Оның рекордын әзірше ешкім бұза алған жоқ.

###################   TEMPORARY HACKS TO GET THE STORY TRANSLATED   ####################
###################   SOME SHOULD BE REWRITTEN LATER                ####################


REMOVE N IF (0 ("ақырын"));
    ## Айгүл оны _ақырын_ тыңдайды.

SELECT A/Advl IF (0 ("ақырын"));
    ## Айгүл оны _ақырын_ тыңдайды.

REMOVE N IF (0 ("жылы")) (NOT -1 N OR Num) ;
    #! Ауа райы бүгін әбден жақсы, ^жылы/жыл<n><px3sp><nom>/жылы<adj>/жылы<adj><subst><nom>.

###############################################################################

REMOVE (pass) IF (0 ("қырыл"));
    ## жасушалардың қырылуы


 "<жаппай>" SELECT A IF
                 (1 N)
;
## Қытай мамандары ауыл тұрғындарының қалаға жаппай ағылуын тоқтататын жаңа
# саясат жүргізуге шақырып отыр.


#
"<бір>" SELECT Det IF (-1C A) (1 N);
## Әхмәт тиз генә иске зур _бер_ агачка йөгерә.
## Әхмәт акрын гына иске зур _бер_ агачка йөгерә.


# Must be placed before "SELECT Det IF (1* NPMARK BARRIER N OR MARK) ;"
"<бар>" REMOVE Det IF
               (1 ("енді"i))
               (2 Rquot) ;
## # Себебі Түрік Әуежолдары сынды бір серігіміз бар енді» деді.


#
"<бар>" SELECT V IF (-1 Dat) ;
"<бар>" SELECT A IF (-1 (px3sp)) ;
"<бар>" SELECT Det IF (1* NPMARK BARRIER N OR MARK) ;
"<бар>" REMOVE Det IF (1 S-BOUNDARY OR MARK) ;
## 172. Сот арқылы немесе өзгеде осындай құзыреті _бар_ мемлекеттік органдардың
## шешімі арқылы тәркіленген мұражайлық маңызы бар жинақтардың немесе жекелеген
## заттардың есебінен.
## Бар<det> җирдән карый, әмма Әхмәтне таба алмый.
## Акча бармы? Бар<adj>.
## Акча бармы? Бар<adj>, ләкин бик аз!


# басым recognized as noun бас, select ADJ form
 "<басым>" SELECT A IF
        (1 (px3sp))
;
## Олардың басым бөлігі – 2011 жылы жұмыс іздеп,


# тұрғыны recognized as noun тұрғы should select тұрғын before қаза
 "<тұрғыны>" SELECT ("тұрғын") IF
        (1 ("қаза"))
;
## 2011 жылы 16 желтоқсанда 16 тұрғыны қаза тапқан


# V-Iп FourAuxiliaries-GAн жоқ-COP
 SELECT (gpr_past) IF
        (-1 (prc_perf))
        (0 FourAuxiliaries)
        (1 ("жоқ"))
;
 "<жоқ>" SELECT SUB:1 Cop IF
        (-2 (prc_perf))
        (-1 FourAuxiliaries)
;
 "<жоқ>" REMOVE Subst IF
        (-2 (prc_perf))
        (-1 FourAuxiliaries)
;
## 19 . Ол еш нәрсені көріп тұрған жоқ, ол санап жатыр.

#
 "<керек>" SELECT A
;
## 45 . Бұл Азамат болу керек!


# Сен бардың ба?
REMOVE (gen) IF
  (0 (ifi p2))
  (-1* (prn nom))


# INPUT: ^Мен/Мен<cnjcoo>/Мен<post>/Мен<prn><pers><p1><sg><nom>$
#        ^қазақпын/қазақ<n><nom>+е<cop><p1><sg>$
# OUTPUT: [0]^Мен<prn><pers><p1><sg><nom>$
#         ^қазақ<n><nom>+е<cop><p1><sg>$
 SELECT Pron-Pers IF
        (0 ("<Мен>"))
        (-1 BOS)
;


# INPUT: ^оның/ол<prn><dem><gen>/он<num><subst><px2sg><nom>/
#        ол<prn><pers><p3><sg><gen>$ ^үйі/үй<n><px3sp><nom>$
# OUTPUT: [0]^ол<prn><pers><p3><sg><gen>$ ^үй<n><px3sp><nom>$
 SELECT Pron-Pers IF
        (0 ("<оның>"i))
        (1* (n px3sp))
;
#kaz-eng

SELECT Pron-Pers IF
        (0 ("<онда>"i))
        (1 N)
;


# INPUT: ^онымен/он<num><subst><px3sp><ins>/ол<prn><pers><p3><sg><ins>$
# OUTPUT: [0]^ол<prn><pers><p3><sg><ins>$
 SELECT Pron-Pers IF
        (0 ("<онымен>"i))
        (NOT -1 (Pron-Pers))
;
#kaz-eng


# INPUT: ^Ол/ол<det><dem>/ол<prn><dem><nom>/ол<prn><pers><p3><sg><nom>$
#        ^дәрігер/дәрігер<n><nom>/дәрігер<n><attr>/дәрігер<n><nom>+
#        е<cop><p3><pl>/дәрігер<n><nom>+е<cop><p3><sg>$^./.<sent>$
# OUTPUT: ^Ол/ол<det><dem>/ол<prn><dem><nom>/ол<prn><pers><p3><sg><nom>$
#         [0]^дәрігер/дәрігер<n><nom>+е<cop><p3><sg>$^./.<sent>$
 SELECT SUB:1 Sg IF
        (-1 ("<Ол>"i) OR ("<Олар>"i))
        (0/1 Cop)
        (0/1 P3)
;
#kaz-eng
# FIXME this rule is unnecessary because of the next rule


# INPUT: ^Ол/ол<det><dem>/ол<prn><dem><nom>/ол<prn><pers><p3><sg><nom>$
#        ^әдемі/әдемі<adj>/әдемі<adj><advl>/әдемі<adj><subst><nom>$
#        ^қыз/қыз<n><nom>/қыз<n><attr>/қыз<v><iv><imp><p2><sg>/
#        қыз<n><nom>+е<cop><p3><pl>/қыз<n><nom>+е<cop><p3><sg>$^./.<sent>$
# OUTPUT: ^Ол/ол<det><dem>/ол<prn><dem><nom>/ол<prn><pers><p3><sg><nom>$
#         ^әдемі/әдемі<adj>/әдемі<adj><advl>/әдемі<adj><subst><nom>$
#         [0]^қыз/қыз<n><nom>+е<cop><p3><sg>$^./.<sent>$
 
SELECT SUB:1 Sg IF
        (-1* ("<Ол>"i) OR ("<Олар>"i))
        (0/1 Cop)
        (0/1 P3)
;

#kaz-eng
# FIXME doesn't work yet



 SELECT N IF
        (0 ("<үстінде>"i)OR ("<астында>" i)OR ("<артында>" i))
        (-1 N)
;
SELECT SUB:1 Pl IF
        (-1 ("<Біз>"i))
        (0/1 Cop)
        (0/1 P1)
;
#Біз бақыттымыз



 REMOVE SUB:1 Pl IF
		 (NOT -1* ("<Ол>"i) OR ("<Олар>"i))
;


SELECT  Cop IF
        (-1 ("<керек>"i))
        (0 Cop)
       
;
REMOVE Adv IF
		 (0 ("<емес>"i)) 
;
       

#"<мен>" SELECT Post IF
# 	(-1 NOMINAL)
#	(1 NOMINAL)
#;

#for choosing "астында" as n.px3sp.loc

#SELECT  N IF
#        (-1 N)
#        (0 (n.*.loc) OR Adv)
#       
#;


## two verbs қай
#SELECT V-IV IF
#	(0 ("қай"))
#	(-1* Dat BARRIER N-LIKE)
#;
### Сол жерге қайтып барасың ба?
#
#SELECT V-TV IF
#	(0 ("қай")) 
#	(-1* Acc BARRIER N-LIKE)
#;
### Соны қайтып қыласың?

SELECT V-IV IF
		(0 ("істе"))
		(NOT -1 NOMINAL)
;


# INPUT:  ^іш<v><tv><prc_vol><p3><pl>/іш<v><tv><prc_vol><p3><sg>/ішкі<adj><subst><px3sp><nom>$
#         кел<vaux><ifi><p3><pl>/кел<vaux><ifi><p3><sg>/кел<v><iv><ifi><p3><pl>/кел<v><iv><ifi><p3><sg>$
# OUTPUT: ^іш<v><tv><prc_vol><p3><pl>/іш<v><tv><prc_vol><p3><sg>$
#         ккел<vaux><ifi><p3><sg>/кел<v><iv><ifi><p3><pl>/кел<v><iv><ifi><p3><sg>$
SELECT Prc-vol IF (1 ("кел")) ;


        
;


# INPUT:  ^Орал/орал<n><nom>/орал<n><attr>/Орал<np><top><nom>/Орал<np><top><attr>/ора<v><tv><pass><imp><p2><sg>/Орал<np><ant><f><nom>/Орал<np><ant><m><nom>/орал<n><nom>+е<cop><aor><p3><pl>/орал<n><nom>+е<cop><aor><p3><sg>/Орал<np><top><nom>+е<cop><aor><p3><pl>/Орал<np><top><nom>+е<cop><aor><p3><sg>/Орал<np><ant><f><nom>+е<cop><aor><p3><pl>/Орал<np><ant><f><nom>+е<cop><aor><p3><sg>/Орал<np><ant><m><nom>+е<cop><aor><p3><pl>/Орал<np><ant><m><nom>+е<cop><aor><p3><sg>$ 
#^тауы/тауы<n><nom>/тауы<n><attr>/тау<n><px3sp><nom>/тауы<n><nom>+е<cop><aor><p3><pl>/тауы<n><nom>+е<cop><aor><p3><sg>/тау<n><px3sp><nom>+е<cop><aor><p3><pl>/тау<n><px3sp><nom>+е<cop><aor><p3><sg>$^

# OUTPUT:  ^Орал/Орал<np><top><attr>
#тау<n><px3sp><nom>
SELECT (np top attr) IF (1 ("тауы")) ;
        
;

###############################################################################
# FMT:

#Орыс мәдениетінің қалыптасу ерекшеліктері негізінен төмендегі факторларға тығыз байланысты болды.

REMOVE Acc IF 
      (1C V-IV) ;

REMOVE VerbalAdjective IF 
       (1 Cm) ;

"<қатар>" SELECT Post IF
                 (-1C N + Ins)
;

REMOVE Num + Subst IF 
      (0C Num) 
      (1C Num LINK 1 N) ;

REMOVE N + Attr IF 
      (1 PersonalPossessives) 
      (NOT -1* Gen OR Nom BARRIER (*) - N) ;

REMOVE A + Subst + $$NGDAALI IF 
      (0 N + $$NGDAALI) ;

REMOVE Num + Subst IF 
      (-1C Num) 
      (1C N) ;

REMOVE VerbalAdjective + Subst IF
       (-1C Gen)
       (1C N) ;

REMOVE A + Subst IF 
      (0C A - Subst OR A + Subst) ;

REMOVE Num + Subst IF 
      (0C Num - Subst OR Num + Subst) ;

REMOVE Num + Subst IF 
       (1C Year) ;

REMOVE Participle IF
      (NOT 1* Vaux) ;




#morph disambiquashion example кеңсе-(1-adj, 2-noun)
SELECT A IF  
       (1 N);

SELECT Adv IF (1 V);