File: 25072012-apertium-tur.tur.twol

package info (click to toggle)
apertium-tur 0.2.0~r83161-2
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid
  • size: 2,860 kB
  • sloc: python: 476; sh: 119; makefile: 107; xml: 54
file content (145 lines) | stat: -rw-r--r-- 3,883 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
!! List of people who will hate this file:
!!     1. Firespeaker

Alphabet

 A B C Ç D E F G Ğ H I İ J K L M N O Ö P Q R S Ş T U Ü V W X Y Z 
 a b c ç d e f g ğ h ı i j k l m n o ö p q r s ş t u ü v w x y z 

 %{k%}:k  %{p%}:p  %{D%}:d %{K%}:k %{t%}:t %{c%}:ç %{LN%}:l %{e%}:e %{a%}:a
 %{bN%}:0 %{bY%}:0 %{bI%}:0 %{bS%}:0
 %{A%}:a  %{I%}:ı
 %{dup%}:0 %{del%}:0 %{dels%}:0 %{compn%}:0
 %{pA%}:a %{pU%}:u %{pO%}:o
 %{nin%}:0 %{nın%}:0 %{nun%}:0 %{un%}:0 %{in%}:0

 %>:0

 %' % ;


Sets

FrontVow = İ Ü E Ö 
           i ü e ö 
           %{nin%}; 

FrontVowNotUe = İ E Ö
                i e ö 
               %{nin%} ;

BackVowNotUO = I A 
          ı a ; 

BackVow = I U A O 
          ı u a o 
         %{nun%} %{nın%} %{un%}; 

Vow = İ Ü E Ö I U A O
      i ü e ö ı u a o
      %{A%} %{I%} %{bI%} ;


Cns = B C Ç D F G Ğ H J K L M N P Q R S Ş T V W X Y Z 
      b c ç d f g ğ h j k l m n p q r s ş t v w x y z 
      %{k%} %{p%} %{t%} %{D%} %{bN%} %{bY%} %' ;

UnvoicedCns = F Ş T K Ç P
              f ş t k ç p  ;

Rules 

"A Vowel Harmony"
%{A%}:e <=> [ :FrontVow :Cns* ]/[ %>: | %  | :0 | :i | :u ] _ ;
            except
                    %>: m _ %>: %{bI%}: ; 

"I Vowel Harmony (not ü)"
%{I%}:i <=> [ [ :i | :e ] :Cns* ]/[ %>: | % | :0 ] _ ;

"I Vowel Harmony (back 'u')"
%{I%}:u <=> [ [ %{un%}: | :o | :u ] :Cns* ]/[ %>: | % | :0 ] _ ;

"I Vowel Harmony (front 'ü')"
%{I%}:ü <=> [ [ :ö | :ü ] :Cns* ]/[ %>: | % | :0 ] _ ;

"Not 'buffer' N"
%{bN%}:n <=> [ :Vow | :Vow %' ]/[ %>: | % | :0 ] _ ; 
          except 
             [ %{in%}: | %{un%}: ] %' %>: _ ;

"Not 'buffer' {bI} Back (ı)"
%{bI%}:ı <=> [ :a :Cns* :Cns ]/[ %>: | :0 ] _ ; 
             [ :ı :Cns* :Cns ]/[ %>: | :0 ] _ ; 

"Not 'buffer' I Back (u)"
%{bI%}:u <=> [ :u :Cns* :Cns ]/[ %>: | :0 ] _ ; 
             [ :o :Cns* :Cns ]/[ %>: | :0 ] _ ; 

"Not 'buffer' I Front (i)"
%{bI%}:i <=> [ :i :Cns* :Cns ]/[ %>: | :0 ] _ ; 
             [ :e :Cns* :Cns ]/[ %>: | :0 ] _ ; 

"Not 'buffer' I Front (ü)"
%{bI%}:ü <=> [ :ü :Cns* :Cns ]/[ %>: | :0 ] _ ; 
             [ :ö :Cns* :Cns ]/[ %>: | :0 ] _ ; 

"Not 'buffer' Y"
%{bY%}:y <=> [ :Vow ]/[ %>: | :0 | :%' ] _ ; 

"Not 'buffer' S"
%{bS%}:s <=>  [ :Vow ]/[ %>: | :0 ] _ ;

"Final stop devoicing"
Vx:Vy <=> _ %>: [ :Vow | %{bN%}:0 :Vow | %{bY%}:0 :Vow | %{bS%}:0 :Vow ] ;
         where Vx         in ( %{p%} %{t%} %{c%} )
               Vy         in (   b     d     c   )
               matched ; 

"{k} devoicing"
%{k%}:ğ <=>  _ %>: [ :Vow | %{bN%}:0 :Vow | %{bY%}:0 :Vow | %{bS%}:0 :Vow ] ;
            except
                   :n _ %>: [ :Vow | %{bN%}:0 :Vow | %{bY%}:0 :Vow | %{bS%}:0 :Vow ] ; 

"{k} devoicing after n"
%{k%}:g <=>  :n  _ %>: [ :Vow | %{bN%}:0 :Vow | %{bY%}:0 :Vow | %{bS%}:0 :Vow ] ;

!  p ->  b : şarap -> şarabı 
!  ç ->  c : ağaç -> ağacı
!  k ->  ğ : bebek -> bebeği
! nk -> ng : renk -> rengi
!  t ->  d : tat  -> tadı

"d devoicing in ablative and locative"
%{D%}:t <=> [ %{k%}:k | %{t%}:t | %{p%}:p | UnvoicedCns ] %>: _ ;
            %{t%}: %>: _ %{I%}: r ;

"Exception for endings in -{t}"
%{t%}:0 <=> _ %>: %{D%}: %{I%}: r ; 

"l/n alternation in passive"
%{LN%}:n <=> [ :Vow | :l ]  %>: _ ;
             [ :Vow | :l ]  %>: %{bI%}: _ ; 
             [ %{e%}: | :Vow | :l ]  %>: %{bI%}:i _ ; 

! If stem ends with *a vowel or `l'* {LN} becomes `n'.
! Otherwise it is `l'.

"Exception for verbs de- and ye-"
%{e%}:0 <=> .#. [ d | y ] _ %>:  %{bI%}:  ;
            [ Vow | Cns ]* _ %>: %{bI%}: y o r ; 
          except
            .#. [ d | y ] _ %>: %{bI%}: %{LN%}: ;

"Exception for verbs ending in -a"
%{a%}:0 <=>  _ %>: %{bI%}: y o r  ;

"Exception for verbs de- and ye- (2)"
%{e%}:i <=> .#. [ d | y ] _ %>:  %{bY%}: :e  ;

"Buffer lol"
%{bI%}:i <=> .#. [ d | y ] :0 %>: _  ; 

"{A} deletion from negative before aorist"
%{A%}:0 <=> %>: m _ %>: %{bI%}: ;