1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
# cmpversion --- compare versions of Debian packages.
# The function returns:
# < 0 if a < b
# == 0 if a == b
# > 0 if a > b
# This function depends on cmpbignum.
#
# Copyright (c) 2001 Herbert Xu <herbert@debian.org>
# $Id: cmpversion.awk,v 1.3 2006/12/06 02:49:29 herbert Exp $
function _cmpversion_segment(a, b, i, j, k, l, m, n, p, q, d) {
k = length(a)
l = length(b)
while (k > 0 && l > 0) {
i = match(a, /[0-9]/)
if (!i) {
i = k + 1
}
j = match(b, /[0-9]/)
if (!j) {
j = l + 1
}
m = 1
n = 1
while (m < i && n < j) {
p = substr(a, m, 1)
if (p == "~") {
p = "!"
}
q = substr(b, n, 1)
if (q == "~") {
q = "!";
}
d = (p ~ /[A-Za-z]/) - (q ~ /[A-Za-z]/)
if (d) {
return d
}
if (p != q) {
return p < q ? -1 : 1
}
m++
n++
}
d = (m < i) - (n < j)
if (d) {
return d
}
a = substr(a, i)
b = substr(b, j)
k -= i - 1
l -= j - 1
if (k <= 0 || l <= 0) {
break
}
i = match(a, /[^0-9]/)
if (!i) {
i = k + 1
}
j = match(b, /[^0-9]/)
if (!j) {
j = l + 1
}
d = cmpbignum(substr(a, 1, i - 1), substr(b, 1, j - 1))
if (d) {
return d
}
a = substr(a, i)
b = substr(b, j)
k -= i - 1
l -= j - 1
}
if (k <= 0) {
a = "0";
}
if (l <= 0) {
b = "0";
}
a = substr(a, 1, 1);
b = substr(b, 1, 1);
d = (b ~ /~/) - (a ~ /~/);
if (d) {
return d;
}
return (k > 0) - (l > 0)
}
function cmpversion(a, b, i, j, k, l, d) {
if (a == b) {
return 0
} else if (a == "-") {
return 1
} else if (b == "-") {
return -1
}
i = index(a, ":")
j = index(b, ":")
if (i > 1 || j > 1) {
d = (i > 1) - (j > 1)
if (d) {
return d
}
d = cmpbignum(substr(a, 1, i - 1), substr(b, 1, j - 1))
if (d) {
return d
}
i++
j++
} else {
i = 1
j = 1
}
a = substr(a, i)
b = substr(b, j)
k = match(a, /.*-/)
if (k) {
k = RLENGTH - 1
i = k + 2
} else {
k = length(a)
i = k + 1
}
l = match(b, /.*-/)
if (l) {
l = RLENGTH - 1
j = l + 2
} else {
l = length(b)
j = l + 1
}
d = _cmpversion_segment(substr(a, 1, k), substr(b, 1, l))
if (d) {
return d
}
return _cmpversion_segment(substr(a, i), substr(b, j))
}
|
