File: src.pri

package info (click to toggle)
arora 0.11.0+qt5+git2014-04-06-1
  • links: PTS
  • area: main
  • in suites: jessie, jessie-kfreebsd, sid
  • size: 6,972 kB
  • sloc: cpp: 25,252; sh: 293; xml: 133; makefile: 80
file content (139 lines) | stat: -rw-r--r-- 3,311 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
CONFIG += qt warn_on
contains(QT_BUILD_PARTS, tools): CONFIG += uitools
else : DEFINES += QT_NO_UITOOLS

win32|os2 : Debug : CONFIG += console

INCLUDEPATH += $$PWD
DEPENDPATH += $$PWD

QT += network
contains(QT_VERSION, ^5.*) {
    QT += widgets webkitwidgets printsupport
} else {
    QT += webkit
}

exists(../.git/HEAD) {
    GITVERSION=$$system(git log -n1 --pretty=format:%h)
    !isEmpty(GITVERSION) {
        GITCHANGENUMBER=$$system(git log --pretty=format:%h | wc -l)
        DEFINES += GITVERSION=\"\\\"$$GITVERSION\\\"\"
        DEFINES += GITCHANGENUMBER=\"\\\"$$GITCHANGENUMBER\\\"\"
    }
}

FORMS += \
    $$PWD/aboutdialog.ui \
    $$PWD/autofilldialog.ui \
    $$PWD/acceptlanguagedialog.ui \
    $$PWD/downloaditem.ui \
    $$PWD/downloads.ui \
    $$PWD/searchbanner.ui \
    $$PWD/settings.ui

HEADERS += \
    $$PWD/aboutdialog.h \
    $$PWD/acceptlanguagedialog.h \
    $$PWD/autosaver.h \
    $$PWD/autofilldialog.h \
    $$PWD/autofillmanager.h \
    $$PWD/browserapplication.h \
    $$PWD/browsermainwindow.h \
    $$PWD/clearprivatedata.h \
    $$PWD/clearbutton.h \
    $$PWD/downloadmanager.h \
    $$PWD/modelmenu.h \
    $$PWD/modeltoolbar.h \
    $$PWD/plaintexteditsearch.h \
    $$PWD/searchbar.h \
    $$PWD/searchbutton.h \
    $$PWD/searchlineedit.h \
    $$PWD/settings.h \
    $$PWD/sourcehighlighter.h \
    $$PWD/sourceviewer.h \
    $$PWD/tabbar.h \
    $$PWD/tabwidget.h \
    $$PWD/toolbarsearch.h \
    $$PWD/webactionmapper.h \
    $$PWD/webpage.h \
    $$PWD/webview.h \
    $$PWD/webviewsearch.h

SOURCES += \
    $$PWD/aboutdialog.cpp \
    $$PWD/acceptlanguagedialog.cpp \
    $$PWD/autosaver.cpp \
    $$PWD/autofilldialog.cpp \
    $$PWD/autofillmanager.cpp \
    $$PWD/browserapplication.cpp \
    $$PWD/browsermainwindow.cpp \
    $$PWD/clearprivatedata.cpp \
    $$PWD/clearbutton.cpp \
    $$PWD/downloadmanager.cpp \
    $$PWD/modelmenu.cpp \
    $$PWD/modeltoolbar.cpp \
    $$PWD/plaintexteditsearch.cpp \
    $$PWD/searchbar.cpp \
    $$PWD/searchbutton.cpp \
    $$PWD/searchlineedit.cpp \
    $$PWD/settings.cpp \
    $$PWD/sourcehighlighter.cpp \
    $$PWD/sourceviewer.cpp \
    $$PWD/tabbar.cpp \
    $$PWD/tabwidget.cpp \
    $$PWD/toolbarsearch.cpp \
    $$PWD/webactionmapper.cpp \
    $$PWD/webpage.cpp \
    $$PWD/webview.cpp \
    $$PWD/webviewsearch.cpp

include(adblock/adblock.pri)
include(bookmarks/bookmarks.pri)
include(history/history.pri)
include(locationbar/locationbar.pri)
include(network/network.pri)
include(opensearch/opensearch.pri)
include(qwebplugins/qwebplugins.pri)
include(utils/utils.pri)
include(useragent/useragent.pri)

RESOURCES += \
    $$PWD/data/data.qrc \
    $$PWD/data/graphics/graphics.qrc \
    $$PWD/data/searchengines/searchengines.qrc \
    $$PWD/htmls/htmls.qrc

DISTFILES += ../AUTHORS \
    ../ChangeLog \
    ../LICENSE.GPL2 \
    ../LICENSE.GPL3 \
    ../README

win32 {
    RC_FILE = $$PWD/browser.rc
    LIBS += -luser32
}

os2 {
    RC_FILE = $$PWD/browser_os2.rc
}

mac {
    ICON = browser.icns
    QMAKE_INFO_PLIST = Info_mac.plist
}

include(../webkittrunk.pri)

# To support both Qt4 and Qt5
DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x000000

unix {
    PKGDATADIR = $$DATADIR/arora
    DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
}

win32 {
    LIBS += -ladvapi32
}