1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
|
program psntest1
c
c Message Passing Layer: BLACS
c
c Example program to illustrate the idea of reverse communication
c for a standard nonsymmetric eigenvalue problem.
c
c We implement example one of ex-nonsym.doc in DOCUMENTS directory
c
c\Test-1
c ... Suppose we want to solve A*x = lambda*x in regular mode,
c where A is random diagonal matrix with 4 separated eigenvalues.
c ... OP = A and B = I.
c ... Assume "call av ( nloc, diag, x, y)" computes y = A*x.
c ... Use mode 1 of PDNAUPD.
c
c\BeginLib
c
c\Routines called:
c pdnaupd Parallel ARPACK reverse communication interface routine.
c pdneupd Parallel ARPACK routine that returns Ritz values and (optionally)
c Ritz vectors.
c dlapy2 LAPACK routine to compute sqrt(x**2+y**2) carefully.
c daxpy Level 1 BLAS that computes y <- alpha*x+y.
c pdnorm2 Parallel version of Level 1 BLAS that computes the norm of a vector.
c av Distributed matrix vector multiplication routine that computes A*x.
c
c\Author
c Kristi Maschhoff
c Dept. of Computational &
c Applied Mathematics
c Rice University
c Houston, Texas
c
c\SCCS Information:
c FILE: %M% SID: %I% DATE OF SID: %G% RELEASE: %R%
c
c\Remarks
c 1. None
c
c\EndLib
c---------------------------------------------------------------------------
c
include 'debug.h'
include 'stat.h'
c %-----------------%
c | BLACS INTERFACE |
c %-----------------%
c
integer comm, iam, nprocs, nloc,
& nprow, npcol, myprow, mypcol
c
external BLACS_PINFO, BLACS_SETUP, BLACS_GET,
& BLACS_GRIDINIT, BLACS_GRIDINFO
c
c %-----------------------------%
c | Define maximum dimensions |
c | for all arrays. |
c | MAXN: Maximum dimension |
c | of the distributed |
c | block of A allowed. |
c | MAXNEV: Maximum NEV allowed |
c | MAXNCV: Maximum NCV allowed |
c %-----------------------------%
c
integer maxn, maxnev, maxncv, ldv
parameter (maxn=100000, maxnev=12, maxncv=30, ldv=maxn)
c
c %--------------%
c | Local Arrays |
c %--------------%
c
integer iparam(11), ipntr(14), iseed(4)
logical select(maxncv)
Double precision
& ax(maxn), d(maxncv,3), resid(maxn), diag(maxn),
& v(ldv,maxncv), workd(3*maxn),
& workev(3*maxncv),
& workl(3*maxncv*maxncv+6*maxncv)
c
c %---------------%
c | Local Scalars |
c %---------------%
c
character bmat*1, which*2
integer ido, n, nx, nev, ncv, lworkl, info, j,
& ierr, nconv, maxitr, ishfts, mode, idist
Double precision
& tol, sigmar, sigmai
logical first, rvec
c
c %------------%
c | Parameters |
c %------------%
c
Double precision
& zero, one
parameter ( zero = 0.0, one = 1.0 )
c
c %-----------------------------%
c | BLAS & LAPACK routines used |
c %-----------------------------%
c
Double precision
& dlapy2, pdnorm2
external dlapy2, daxpy, pdnorm2, dlarnv
c
c %---------------------%
c | Intrinsic Functions |
c %---------------------%
c
intrinsic abs, sqrt
c
c %-----------------------%
c | Executable Statements |
c %-----------------------%
c
call BLACS_PINFO( iam, nprocs )
c
c If in PVM, create virtual machine if it doesn't exist
c
if (nprocs .lt. 1) then
if (iam .eq. 0) then
write(*,1000)
read(*, 2000) nprocs
endif
call BLACS_SETUP( iam, nprocs )
endif
c
1000 format('How many processes in machine?')
2000 format(I3)
c
c Set up processors in 1D Grid
c
nprow = nprocs
npcol = 1
c
c Get default system context, and define grid
c
call BLACS_GET( 0, 0, comm )
call BLACS_GRIDINIT( comm, 'Row', nprow, npcol )
call BLACS_GRIDINFO( comm, nprow, npcol, myprow, mypcol )
c
c If I'm not in grid, go to end of program
c
if ( (myprow .ge. nprow) .or. (mypcol .ge. npcol) ) goto 9000
c
ndigit = -3
logfil = 6
mnaupd = 1
c
n = maxn*nprocs
nev = 4
ncv = 20
c
c %--------------------------------------%
c | Set up distribution of data to nodes |
c %--------------------------------------%
c
nloc = maxn
c
if ( nloc .gt. maxn ) then
print *, ' ERROR with _NDRV1: NLOC is greater than MAXN '
go to 9000
else if ( nev .gt. maxnev ) then
print *, ' ERROR with _NDRV1: NEV is greater than MAXNEV '
go to 9000
else if ( ncv .gt. maxncv ) then
print *, ' ERROR with _NDRV1: NCV is greater than MAXNCV '
go to 9000
end if
bmat = 'I'
which = 'LM'
c
c %-----------------------------------%
c | Generate random diagonal matrix |
c | Isolate 4 extreamal eigenvalues |
c %-----------------------------------%
c
idist = 1
iseed(1) = 15
iseed(2) = 35
iseed(3) = 52
iseed(4) = 7
call dlarnv ( idist, iseed, nloc, diag )
diag(1) = diag(1) + 1.01
diag(2) = diag(2) + 1.01
diag(3) = diag(3) + 1.01
diag(4) = diag(4) + 1.01
c
c %-----------------------------------------------------%
c | The work array WORKL is used in PDNAUPD as |
c | workspace. Its dimension LWORKL is set as |
c | illustrated below. The parameter TOL determines |
c | the stopping criterion. If TOL<=0, machine |
c | precision is used. The variable IDO is used for |
c | reverse communication, and is initially set to 0. |
c | Setting INFO=0 indicates that a random vector is |
c | generated in PDNAUPD to start the Arnoldi iteration.|
c %-----------------------------------------------------%
c
lworkl = 3*ncv**2+6*ncv
tol = zero
ido = 0
info = 1
do 50 j=1,nloc
resid(j) = 1.0
50 continue
c
c %---------------------------------------------------%
c | This program uses exact shifts with respect to |
c | the current Hessenberg matrix (IPARAM(1) = 1). |
c | IPARAM(3) specifies the maximum number of Arnoldi |
c | iterations allowed. Mode 1 of PDNAUPD is used |
c | (IPARAM(7) = 1). All these options can be changed |
c | by the user. For details see the documentation in |
c | PDNAUPD. |
c %---------------------------------------------------%
c
ishfts = 1
maxitr = 300
mode = 1
c
iparam(1) = ishfts
iparam(3) = maxitr
iparam(7) = mode
c
c %-------------------------------------------%
c | M A I N L O O P (Reverse communication) |
c %-------------------------------------------%
c
10 continue
c
c %---------------------------------------------%
c | Repeatedly call the routine PDNAUPD and take|
c | actions indicated by parameter IDO until |
c | either convergence is indicated or maxitr |
c | has been exceeded. |
c %---------------------------------------------%
c
call pdnaupd(comm, ido, bmat, nloc, which, nev, tol, resid,
& ncv, v, ldv, iparam, ipntr, workd, workl, lworkl, info )
c
if (ido .eq. -1 .or. ido .eq. 1) then
c
c %-------------------------------------------%
c | Perform matrix vector multiplication |
c | y <--- OP*x |
c | The user should supply his/her own |
c | matrix vector multiplication routine here |
c | that takes workd(ipntr(1)) as the input |
c | vector, and return the matrix vector |
c | product to workd(ipntr(2)). |
c %-------------------------------------------%
c
call av ( nloc, diag, workd(ipntr(1)), workd(ipntr(2)))
c
c %-----------------------------------------%
c | L O O P B A C K to call PDNAUPD again.|
c %-----------------------------------------%
c
go to 10
c
end if
c
c %----------------------------------------%
c | Either we have convergence or there is |
c | an error. |
c %----------------------------------------%
c
if ( info .lt. 0 ) then
c
c %--------------------------%
c | Error message, check the |
c | documentation in PDNAUPD.|
c %--------------------------%
c
if ( myprow .eq. 0 ) then
print *, ' '
print *, ' Error with _naupd, info = ', info
print *, ' Check the documentation of _naupd'
print *, ' '
endif
c
else
c
c %-------------------------------------------%
c | No fatal errors occurred. |
c | Post-Process using PDNEUPD. |
c | |
c | Computed eigenvalues may be extracted. |
c | |
c | Eigenvectors may also be computed now if |
c | desired. (indicated by rvec = .true.) |
c %-------------------------------------------%
c
rvec = .true.
c
call pdneupd ( comm, rvec, 'A', select, d, d(1,2), v, ldv,
& sigmar, sigmai, workev, bmat, nloc, which, nev, tol,
& resid, ncv, v, ldv, iparam, ipntr, workd, workl,
& lworkl, ierr )
c
c %-----------------------------------------------%
c | The real part of the eigenvalue is returned |
c | in the first column of the two dimensional |
c | array D, and the imaginary part is returned |
c | in the second column of D. The corresponding |
c | eigenvectors are returned in the first NEV |
c | columns of the two dimensional array V if |
c | requested. Otherwise, an orthogonal basis |
c | for the invariant subspace corresponding to |
c | the eigenvalues in D is returned in V. |
c %-----------------------------------------------%
c
if ( ierr .ne. 0) then
c
c %------------------------------------%
c | Error condition: |
c | Check the documentation of PDNEUPD.|
c %------------------------------------%
c
if ( myprow .eq. 0 ) then
print *, ' '
print *, ' Error with _neupd, info = ', ierr
print *, ' Check the documentation of _neupd. '
print *, ' '
endif
c
else
c
first = .true.
nconv = iparam(5)
do 20 j=1, nconv
c
c %---------------------------%
c | Compute the residual norm |
c | |
c | || A*x - lambda*x || |
c | |
c | for the NCONV accurately |
c | computed eigenvalues and |
c | eigenvectors. (iparam(5) |
c | indicates how many are |
c | accurate to the requested |
c | tolerance) |
c %---------------------------%
c
if (d(j,2) .eq. zero) then
c
c %--------------------%
c | Ritz value is real |
c %--------------------%
c
call av( nloc, diag, v(1,j), ax)
call daxpy(nloc, -d(j,1), v(1,j), 1, ax, 1)
d(j,3) = pdnorm2( comm, nloc, ax, 1)
c
else if (first) then
c
c %------------------------%
c | Ritz value is complex. |
c | Residual of one Ritz |
c | value of the conjugate |
c | pair is computed. |
c %------------------------%
c
call av( nloc, diag, v(1,j), ax)
call daxpy(nloc, -d(j,1), v(1,j), 1, ax, 1)
call daxpy(nloc, d(j,2), v(1,j+1), 1, ax, 1)
d(j,3) = pdnorm2( comm, nloc, ax, 1)
call av( nloc, diag, v(1,j+1), ax)
call daxpy(nloc, -d(j,2), v(1,j), 1, ax, 1)
call daxpy(nloc, -d(j,1), v(1,j+1), 1, ax, 1)
d(j,3) = dlapy2(d(j,3), pdnorm2(comm,nloc,ax,1) )
d(j+1,3) = d(j,3)
first = .false.
else
first = .true.
end if
c
20 continue
c
c %-----------------------------%
c | Display computed residuals. |
c %-----------------------------%
c
call pdmout(comm, 6, nconv, 3, d, maxncv, -6,
& 'Ritz values (Real,Imag) and direct residuals')
end if
c
c %-------------------------------------------%
c | Print additional convergence information. |
c %-------------------------------------------%
c
if (myprow .eq. 0)then
if ( info .eq. 1) then
print *, ' '
print *, ' Maximum number of iterations reached.'
print *, ' '
else if ( info .eq. 3) then
print *, ' '
print *, ' No shifts could be applied during implicit
& Arnoldi update, try increasing NCV.'
print *, ' '
end if
c
print *, ' '
print *, '_NDRV1 '
print *, '====== '
print *, ' '
print *, ' Size of the matrix is ', n
print *, ' The number of processors is ', nprocs
print *, ' The number of Ritz values requested is ', nev
print *, ' The number of Arnoldi vectors generated',
& ' (NCV) is ', ncv
print *, ' What portion of the spectrum: ', which
print *, ' The number of converged Ritz values is ',
& nconv
print *, ' The number of Implicit Arnoldi update',
& ' iterations taken is ', iparam(3)
print *, ' The number of OP*x is ', iparam(9)
print *, ' The convergence criterion is ', tol
print *, ' '
c
endif
end if
c
c %---------------------------%
c | Done with program pdndrv1.|
c %---------------------------%
c
9000 continue
c
c %-------------------------%
c | Release resources BLACS |
c %-------------------------%
c
call BLACS_GRIDEXIT ( comm )
call BLACS_EXIT(0)
c
end
c
c==========================================================================
c
c parallel matrix vector subroutine
c
subroutine av (n, diag, v, w)
integer n, j
Double precision
& v(n), w(n), diag(n)
c
do 10 j = 1, n
w(j) = diag(j)*v(j)
10 continue
c
return
end
|
