File: catsparse_lexing.dats

package info (click to toggle)
ats2-lang 0.4.0-1
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 40,064 kB
  • sloc: ansic: 389,637; makefile: 7,123; lisp: 812; sh: 657; php: 573; python: 387; perl: 365
file content (1164 lines) | stat: -rw-r--r-- 19,212 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
(* ****** ****** *)
//
// CATS-parsemit
//
(* ****** ****** *)
//
// HX-2014-07-02: start
//
(* ****** ****** *)
//
#include
"share/atspre_define.hats"
#include
"share/atspre_staload.hats"
//
(* ****** ****** *)

staload UN = $UNSAFE

(* ****** ****** *)

staload "./../SATS/catsparse.sats"

(* ****** ****** *)

macdef ENDL = char2int0('\n')

(* ****** ****** *)

implement
token_get_loc (tok) = tok.token_loc

(* ****** ****** *)
//
implement
token_make (loc, node) =
  '{ token_loc= loc, token_node= node }
//
(* ****** ****** *)

fun BLANK_test
  (i: int): bool = let
//
val c = int2char0 (i)
//
in
  case+ 0 of
  | _ when c = ' ' => true
  | _ when c = '\t' => true
  | _ (*rest-of-chars*) => false
end // end of [BLANK_test]

(* ****** ****** *)

fun
IDENTFST_test
  (i: int): bool = let
//
val c = int2char0 (i)
//
in
  case+ 0 of
  | _ when ('a' <= c andalso c <= 'z') => true
  | _ when ('A' <= c andalso c <= 'Z') => true
  | _ when c = '_' => true
  | _ (*rest-of-char*) => false
end (* end of [IDENTFST_test] *)

(* ****** ****** *)

fun
IDENTRST_test
  (i: int): bool = let
//
val c = int2char0 (i)
//
in
  case+ 0 of
  | _ when ('a' <= c andalso c <= 'z') => true
  | _ when ('A' <= c andalso c <= 'Z') => true
  | _ when ('0' <= c andalso c <= '9') => true
  | _ when c = '_' => true
  | _ when c = '$' => true
  | _ when c = '.' => true
  | _ when c = ':' => true
  | _ when c = '\'' => true
  | _ (*rest-of-char*) => false
end (* end of [IDENTRST_test] *)

(* ****** ****** *)

local
//
#define
SYMBOLIC "%&+-./:=@~`^|*!$#?<>"
//
in (* in-of-local *)
//
fun
SYMBOLIC_test
  (c: int): bool =
  strchr (SYMBOLIC, int2char0(c)) >= 0
//
end // end of [local]

(* ****** ****** *)
//
fun xX_test
  (i: int): bool = let
//
val c = int2char0 (i) in c = 'x' || c = 'X'
//
end // end of [xX_test]
//
fun eE_test
  (i: int): bool = let
//
val c = int2char0 (i) in c = 'e' || c = 'E'
//
end // end of [eE_test]
//
fun pP_test
  (i: int): bool = let
//
val c = int2char0 (i) in c = 'p' || c = 'P'
//
end // end of [pP_test]
//
(* ****** ****** *)
//
fun SIGN_test
  (c: int): bool = let
//
val c = int2char0(c) in (c = '+' || c = '-')
//
end // end of [SIGN_test]
//
(* ****** ****** *)
//
fun ZERO_test
  (i: int): bool = (i = char2int0('0'))
//
fun OCTAL_test (i: int): bool =
  (char2int0('0') <= i && i <= char2int0('7'))
//
fun DIGIT_test (i: int): bool =
  (char2int0('0') <= i && i <= char2int0('9'))
//
fun XDIGIT_test (i: int): bool = isxdigit (i)
//
(* ****** ****** *)
//
fun INTSP_test
  (i: int): bool = let
//
val c = toupper(int2char0(i)) in c = 'L' || c = 'U'
//
end // end of [INTSP_test]
//
fun FLOATSP_test
  (i: int): bool = let
//
val c = toupper(int2char0(i)) in c = 'F' || c = 'L'
//
end // end of [FLOATSP_test]
//
(* ****** ****** *)
//
extern
fun
ftesting_one
(
  buf: &lexbuf >> _, f: int -> bool
) : intGte(0) // end of [ftesting_one]
//
implement
ftesting_one
  (buf, f) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if (
i > 0
) then (
  if f(i) then 1 else (lexbuf_incby_nback (buf, 1); 0)
) else (0)
//
end // end of [ftesting_one]
//
(* ****** ****** *)
//
extern
fun
ftesting_opt
(
  buf: &lexbuf >> _, f: int -> bool
) : intGte(0) // end of [ftesting_opt]
//
implement
ftesting_opt
  (buf, f) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if (
i > 0
) then (
  if f(i) then 1 else (lexbuf_incby_nback (buf, 1); 0)
) else (0)
//
end // end of [ftesting_opt]
//
(* ****** ****** *)
//
extern
fun
ftesting_seq0
(
  buf: &lexbuf >> _, f: int -> bool
) : intGte(0) // end of [ftesting_seq0]
implement
ftesting_seq0
  (buf, f) = let
//
fun loop
(
  buf: &lexbuf >> _, nchr: intGte(0)
) : intGte(0) = let
  val i = lexbuf_get_char (buf)
in
//
if (
i > 0
) then (
//
if f(i)
  then
    loop (buf, succ(nchr))
  // end of [then]
  else let
    val () = lexbuf_incby_nback (buf, 1) in nchr
  end // end of [else]
//
) else (nchr)
//
end // end of [loop]
//
in
  loop (buf, 0)
end // end of [ftesting_seq0]

(* ****** ****** *)
//
(*
fun
skip_blankseq0
(
  buf: &lexbuf >> _
) : intGte(0) = let
//
fun loop
(
  buf: &lexbuf >> _
, pos: &position >> _, nchr: intGte(0)
) : intGte(0) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then (
  if isspace(i)
    then let
      val c = int2char0 (i)
      val () = position_incby_char (pos, c)
    in
      loop (buf, pos, succ(nchr))
    end // end of [then]
    else nchr // end of [else]
  // end of [if]
) (* end of [then] *)
else nchr // end of [else]
//
end // end of [loop]
//
var pos: position
val () = lexbuf_get_position (buf, pos)
val nchr = loop (buf, pos, 0)
val () = lexbuf_remove (buf, nchr)
val () = lexbuf_set_position (buf, pos)
//
in
  nchr
end // end of [skip_blankseq0]
*)
//
(* ****** ****** *)
//
fun
testing_blankseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, BLANK_test)
//
(* ****** ****** *)
//
fun
testing_identrstseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, IDENTRST_test)
//
(* ****** ****** *)
//
fun
testing_symbolicseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, SYMBOLIC_test)
//
(* ****** ****** *)
//
extern
fun
lexing_IDENT_alp
  (buf: &lexbuf): token
//
implement
lexing_IDENT_alp
  (buf) = let
//
val nchr =
  testing_identrstseq0(buf)
val nchr1 = succ(nchr)
val name = lexbuf_takeout(buf, nchr1)
val name = strptr2string(name)
//
val loc =
  lexbuf_getincby_location(buf, nchr1)
//
val kwd = keyword_search (name)
//
in
//
case+ kwd of
//
| KWORDnone () =>
    token_make (loc, T_IDENT_alp(name))
  // end of [KWORDnone]
| _ (*keyword*) => token_make (loc, T_KWORD(kwd))
//
end // end of [lexing_IDENT_alp]

(* ****** ****** *)
//
extern
fun
lexing_IDENT_sym
  (buf: &lexbuf): token
//
implement
lexing_IDENT_sym
  (buf) = let
//
val nchr =
  testing_symbolicseq0 (buf)
val nchr1 = succ(nchr)
val name = lexbuf_takeout (buf, nchr1)
val name = strptr2string (name)
//
val loc = lexbuf_getincby_location (buf, nchr1)
//
in
//
case+ name of
| "<" => token_make (loc, T_LT)
| ">" => token_make (loc, T_GT)
//
| "-" => token_make (loc, T_MINUS)
//
| ":" => token_make (loc, T_COLON)
//
| _ (*rest*) => token_make (loc, T_IDENT_sym(name))
//
end // end of [lexing_IDENT_sym]

(* ****** ****** *)
//
fun
testing_octalseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, OCTAL_test)
//
(* ****** ****** *)
//
fun
testing_digitseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, DIGIT_test)
//
(* ****** ****** *)
//
fun
testing_xdigitseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, XDIGIT_test)
//
(* ****** ****** *)
//
fun
testing_intspseq0
  (buf: &lexbuf): intGte(0) =
  ftesting_seq0 (buf, INTSP_test)
//
(* ****** ****** *)

fun
testing_fexponent
(
  buf: &lexbuf
) : intGte(0) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then let
//
val c = int2char0(i)
//
in
//
if
eE_test(i)
then let
//
val k1 =
  ftesting_opt (buf, SIGN_test)
val k2 = testing_digitseq0 (buf) // err: k2 = 0
//
val () =
if k2 = 0 then
{
  val loc =
    lexbuf_getincby_location (buf, k1+1)
  val err =
    lexerr_make (loc, LEXERR_FEXPONENT_nil)
  val ((*void*)) = the_lexerrlst_insert (err)
} (* end of [if] *) // end of [val]
//
in
  k1+k2+1
end // end of [then]
else (
  lexbuf_incby_nback (buf, 1); 0
) (* end of [else] *)
//
end // end of [then]
else (0) // end of [else]
//
end // end of [testing_fexponent]

(* ****** ****** *)

fun
testing_deciexp
(
  buf: &lexbuf
) : intGte(0) = let  
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then let
//
val c = int2char0(i)
//
in
//
if
c = '.'
then let
//
  val k1 = testing_digitseq0 (buf)
  val k2 = testing_fexponent (buf)
  val k12 = k1 + k2
//
in
  k12 + 1
end // end of [then]
else (
  lexbuf_incby_nback (buf, 1); 0
) (* end of [else] *)
//
end // end of [then]
else 0 // end of [else]
//
end // end of [testing_deciexp]

(* ****** ****** *)
//
extern
fun
lexing_INT_oct (buf: &lexbuf): token
//
extern
fun
lexing_INT_dec (buf: &lexbuf): token
//
extern
fun
lexing_FLOAT_deciexp (buf: &lexbuf): token
//
(* ****** ****** *)
//
implement
lexing_INT_oct
  (buf) = let
//
val k0 = testing_octalseq0 (buf)
//
in
//
if
k0 >= 2
then let
//
val k1 = testing_intspseq0 (buf)
val nchr = succ(k0 + k1)
val intrep = lexbuf_takeout (buf, nchr)
val intrep = strptr2string (intrep)
//
val loc = lexbuf_getincby_location (buf, nchr)
//
val base =
  (if k0 > 0 then 8 else 10): int
//
in
  token_make (loc, T_INT(base, intrep))
end // end of [then]
else lexing_INT_dec (buf)
//
end // end of [lexing_INT_oct]

(* ****** ****** *)
//
implement
lexing_INT_dec (buf) = let
//
val k0 =
  testing_digitseq0 (buf)
//
val k1 = testing_deciexp (buf)
//
in
//
if
k1 > 0
then let
//
  val nchr = succ(k0 + k1)
  val float = lexbuf_takeout (buf, nchr)
  val float = strptr2string (float)
//
  val loc = lexbuf_getincby_location (buf, nchr)
//
in
  token_make (loc, T_FLOAT(10(*base*), float))
end // end of [then]
else let
//
val k1 = testing_fexponent (buf)
//
in
//
if
k1 > 0
then let
//
  val nchr = succ(k0 + k1)
  val float = lexbuf_takeout (buf, nchr)
  val float = strptr2string (float)
//
  val loc = lexbuf_getincby_location (buf, nchr)
//
in
  token_make (loc, T_FLOAT(10(*base*), float))
end // end of [then]
else let
//
  val k1 = testing_intspseq0 (buf)
//
  val nchr = succ(k0 + k1)
  val intrep = lexbuf_takeout (buf, nchr)
  val intrep = strptr2string (intrep)
//
  val loc = lexbuf_getincby_location (buf, nchr)
//
in
  token_make (loc, T_INT(10(*base*), intrep))
end // end of [else]
//
end // end of [else]
//
end // end of [lexing_INT_dec]

(* ****** ****** *)

extern
fun
lexing_INT_hex (buf: &lexbuf): token
//
implement
lexing_INT_hex
  (buf) = let
//
val k0 =
  testing_xdigitseq0 (buf)
val k1 = testing_intspseq0 (buf)
val nchr = k0 + k1 + 2
val intrep = lexbuf_takeout (buf, nchr)
val intrep = strptr2string (intrep)
//
val loc = lexbuf_getincby_location (buf, nchr)
//
in
  token_make (loc, T_INT(16(*base*), intrep))
end // end of [lexing_INT_hex]

(* ****** ****** *)
//
#define COMMA ','
#define COLON ':'
#define SEMICOLON ';'
//
#define QUOTE '''
#define DQUOTE '"'
//
#define LPAREN '\('
#define RPAREN ')';
#define LBRACE '\{'
#define RBRACE '}';
#define LBRACKET '\['
#define RBRACKET ']';
//
#define SHARP '#'
#define SLASH '/'
#define BACKSLASH '\\'
//
(* ****** ****** *)
//
extern
fun
lexing_SPACES
  (buf: &lexbuf >> _): token
//
implement
lexing_SPACES
  (buf) = let
//
val nchr =
  testing_blankseq0(buf)
//
val nchr1 = nchr + 1
val () = lexbuf_set_nspace (buf, nchr1)
val spaces = lexbuf_takeout (buf, nchr1)
val spaces = strptr2string (spaces)
val loc = lexbuf_getincby_location (buf, nchr1)
//
in
  token_make (loc, T_SPACES (spaces))
end // end of [lexing_SPACES]
//
(* ****** ****** *)
//
extern
fun
lexing_ENDL
  (buf: &lexbuf): token
//
implement
lexing_ENDL
  (buf) = let
//
val () = lexbuf_remove (buf, 1)
val loc = lexbuf_getbyrow_location (buf)
//
in
  token_make (loc, T_ENDL())
end // end of [lexing_ENDL]

(* ****** ****** *)
//
extern
fun
lexing_litchar
  (buf: &lexbuf, node: tnode): token
//
implement
lexing_litchar
  (buf, node) = let
//
val () = lexbuf_remove (buf, 1)
val loc = lexbuf_getincby_location (buf, 1)
//
in
  token_make (loc, node)
end // end of [lexing_litchar]
//
(* ****** ****** *)
//
extern
fun
lexing_SHARP (buf: &lexbuf): token
//
implement
lexing_SHARP
  (buf) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then let
//
val c = int2char0(i)
//  
in
//
case+ 0 of
| _ when
    IDENTFST_test(i) => let
    val nchr = testing_identrstseq0 (buf)
    val nchr2 = nchr + 2
    val name = lexbuf_takeout (buf, nchr2)
    val name = strptr2string (name)
    val loc = lexbuf_getincby_location (buf, nchr2)
    val kwd = keyword_search (name)
  in
    case+ kwd of
    | KWORDnone () =>
        token_make (loc, T_IDENT_srp(name))
      // end of [KWORDnone]
    | _(*keyword*) => token_make (loc, T_KWORD (kwd))
  end
| _ (* rest-of-char *) => let
    val nchr = testing_symbolicseq0 (buf)
    val nchr1 = succ(nchr)
    val name = lexbuf_takeout (buf, nchr1)
    val name = strptr2string (name)
    val loc = lexbuf_getincby_location (buf, nchr1)
  in
    token_make (loc, T_IDENT_alp(name))
  end
end // end of [then]
else let
  val () = lexbuf_remove (buf, 1)
  val loc = lexbuf_getincby_location (buf, 1)
in
  token_make (loc, T_SLASH((*void*)))
end // end of [else]
//
end // end of [lexing_SHARP]

(* ****** ****** *)
//
extern
fun
lexing_SLASH(buf: &lexbuf): token
extern
fun
lexing_SLASHSTAR(buf: &lexbuf): token
extern
fun
lexing_SLASHSLASH(buf: &lexbuf): token
//
(* ****** ****** *)

implement
lexing_SLASH
  (buf) = let
//
val i0 =
  lexbuf_get_char(buf)
//
in
//
if
i0 > 0
then let
//
val c0 = int2char0(i0)
//
in
//
case+ 0 of
//
| _ when c0 = '*' => lexing_SLASHSTAR(buf)
| _ when c0 = '/' => lexing_SLASHSLASH(buf)
//
| _ (*rest-of-char*) => lexing_litchar(buf, T_SLASH)
//
end // end of [then]
else lexing_litchar(buf, T_SLASH)
//
end // end of [lexing_SLASH]

(* ****** ****** *)
//
extern
fun
lexing_quote
(
  buf: &lexbuf, quote: char
) : token // end-of-fun
//
implement
lexing_quote
  (buf, quote) = let
//
fun
loop (
  buf: &lexbuf
, pos: &position >> _, nchr: intGte(0)
) : intGte(0) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then let
  val c = int2char0(i)
  val () = position_incby_char(pos, c)
  val nchr = succ(nchr)
in
  case+ 0 of
  | _ when c = quote => nchr
  | _ when c = BACKSLASH => loop2(buf, pos, nchr)
  | _ (*rest-of-char*) => loop(buf, pos, nchr)
end // end of [then]
else nchr // end of [else]
//
end // end of [loop]
//
and
loop2 (
  buf: &lexbuf
, pos: &position >> _, nchr: intGte(0)
) : intGte(0) = let
//
val i = lexbuf_get_char (buf)
//
in
//
if
i > 0
then let
//
val c = int2char0(i)
val () = position_incby_char(pos, c)
val nchr = succ(nchr)
//
in
  loop(buf, pos, nchr)
end // end of [then]
else nchr // end of [else]
//
end // end of [loop2]
//
var pos: position
//
val () =
lexbuf_get_position (buf, pos)
//
val () = position_incby1 (pos)
val nchr = loop (buf, pos, 0(*nchr*))
val loc = lexbufpos_get_location (buf, pos)
val strp = lexbuf_takeout (buf, nchr+1)
val () = lexbuf_set_position (buf, pos)
//
(*
val () = println! ("lexing_quote: loc = ", loc)
val () = println! ("lexing_quote: nchr = ", nchr)
val () = println! ("lexing_quote: strp = ", strp)
*)
//
in
  token_make(loc, T_STRING(strptr2string(strp)))
end // end of [lexing_quote]

(* ****** ****** *)
//
extern
fun
lexing_QUOTE(buf: &lexbuf): token
implement
lexing_QUOTE(buf) = lexing_quote(buf, QUOTE)
//
extern
fun
lexing_DQUOTE(buf: &lexbuf): token
implement
lexing_DQUOTE(buf) = lexing_quote(buf, DQUOTE)
//
(* ****** ****** *)
//
extern
fun
testing_until_literal
(
  buf: &lexbuf >> _, pos: &position >> _, lit: string
) : intGte(0) // end-of-function
//
implement
testing_until_literal
  (buf, pos, lit0) = let
//
val [n0:int]
  lit0 = g1ofg0 (lit0)
val n0 = length (lit0)
//
fun
loop
  {n:nat | n0 >= n}
(
  buf: &lexbuf >> _
, pos: &position >> _
, lit: string(n), n: size_t(n)
, nchr: intGte(0)
) : intGte(0) = let
in
//
if
n > 0
then let
  val i = lexbuf_get_char(buf)
in
//
if i <= 0
  then nchr
  else let
    val c = int2char0(i)
    val () = position_incby_char(pos, c)
  in
    if c != lit.head()
      then let
        val () =
        if (c != ENDL) then
        {
          val np = sz2i(n0 - n)
          val () = position_decby(pos, np)
          val () = lexbuf_incby_nback(buf, np)
        } (* end of [if] *)
      in
        loop(buf, pos, lit0, n0, succ(nchr))
      end // end of [then]
      else (
        loop(buf, pos, lit.tail(), pred(n), succ(nchr))
      ) (* end of [else] *)
  end // end of [else]
//
end // end of [then]
else nchr // end of [else]
//
end // end of [loop]
//
in
  loop(buf, pos, lit0, n0, 0)
end // end of [testing_until_literal]

(* ****** ****** *)

implement
lexing_SLASHSTAR
  (buf) = let
//
var pos: position
//
val () =
  lexbuf_get_position(buf, pos)
//
val () = position_incby (pos, 2)
//
#define STARSLASH "*/"
//
val nchr =
  testing_until_literal(buf, pos, STARSLASH)
//
val str = lexbuf_takeout (buf, nchr + 2)
val loc = lexbufpos_get_location (buf, pos)
val ((*void*)) = lexbuf_set_position (buf, pos)
//
in
  token_make(loc, T_COMMENT_block(strptr2string(str)))
end // end of [lexing_SLASHSTAR]

(* ****** ****** *)

implement
lexing_SLASHSLASH
  (buf) = let
//
val
nchr =
ftesting_seq0
(
  buf, lam i => i != ENDL
) (* end of [val] *)
//
// HX: Note that ENDL is not included
//
val str = lexbuf_takeout(buf, nchr + 2)
val loc = lexbuf_getincby_location(buf, nchr + 2)
//
in
  token_make(loc, T_COMMENT_line(strptr2string(str)))
end // end of [lexing_SLASHSLASH]

(* ****** ****** *)

local
//
fun
get_token_any
(
  buf: &lexbuf >> _
) : token = let
//
val i0 = lexbuf_get_char(buf)
//
in
//
if
i0 > 0
then let
//
val c0 = $UN.cast{charNZ}(i0)
//
in
//
case+ 0 of
//
| _ when
    BLANK_test (i0) => lexing_SPACES(buf)
//
| _ when
    IDENTFST_test (i0) => lexing_IDENT_alp(buf)
//
| _ when c0 = ENDL => lexing_ENDL(buf)
| _ when c0 = SHARP => lexing_SHARP(buf)
| _ when i0 = SLASH => lexing_SLASH(buf)
//
| _ when
    SYMBOLIC_test (i0) => lexing_IDENT_sym(buf)
//
| _ when DIGIT_test (i0) =>
  (
    if ZERO_test(i0)
      then let
        val k = ftesting_one(buf, xX_test)
      in
        if k = 0
          then lexing_INT_oct(buf) else lexing_INT_hex(buf)
        // end of [if]
      end // end of [then]
      else lexing_INT_dec(buf)
   )
//
| _ when i0 = COMMA => lexing_litchar(buf, T_COMMA)
| _ when i0 = SEMICOLON => lexing_litchar(buf, T_SEMICOLON)
//
| _ when i0 = LPAREN => lexing_litchar(buf, T_LPAREN)
| _ when i0 = RPAREN => lexing_litchar(buf, T_RPAREN)
| _ when i0 = LBRACE => lexing_litchar(buf, T_LBRACE)
| _ when i0 = RBRACE => lexing_litchar(buf, T_RBRACE)
| _ when i0 = LBRACKET => lexing_litchar(buf, T_LBRACKET)
| _ when i0 = RBRACKET => lexing_litchar(buf, T_RBRACKET)
//
| _ when i0 = QUOTE => lexing_QUOTE(buf)
| _ when i0 = DQUOTE => lexing_DQUOTE(buf)
//
| _ (*rest-of-char*) => let
//
// HX: skipping the unrecognized char
//
    val () = lexbuf_remove_all(buf)
//
    val loc = lexbuf_getincby_location(buf, 1)
    val err = lexerr_make (loc, LEXERR_UNSUPPORTED_char(c0))
    val ((*void*)) = prerrln! ("Warning(lex): ", err)
(*
    val ((*inserted*)) = the_lexerrlst_insert (err)
*)
//
  in
    lexbuf_get_token_any(buf)
  end // end of [rest-of-char]
//
end // end of [then]
else let
  val loc =
    lexbuf_getincby_location (buf, 0) in token_make (loc, T_EOF)
  // end of [val]
end // end of [else]
//
end // end of [get_token_any]
//
in
//
implement
lexbuf_get_token_any
  (buf) = let
//
val tok = get_token_any (buf)
//
in
//
case+
tok.token_node of
//
| T_SPACES _ => tok
| _ (*non-SPACES*) => let
    val () = lexbuf_set_nspace (buf, 0) in tok
  end // end of [non-SPACES]
//
end // end of [lexbuf_get_token_any]
//
end // end of [local]

(* ****** ****** *)

implement
lexbuf_get_token_skip
  (buf) = let
//
val tok = lexbuf_get_token_any (buf)
//
in
//
case+
tok.token_node of
| T_ENDL () => lexbuf_get_token_skip (buf)
| T_SPACES _ => lexbuf_get_token_skip (buf)
| T_COMMENT_line _ => lexbuf_get_token_skip (buf)
| T_COMMENT_block _ => lexbuf_get_token_skip (buf)
| _ (*non-skip-token*) => tok
//
end // end of [lexing_get_token_skip]

(* ****** ****** *)

(* end of [catsparse_lexing.dats] *)