1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
|
(*
** For testing ats2cpp
*)
(* ****** ****** *)
#define ATS_DYNLOADFLAG 0
(* ****** ****** *)
%{^
#undef ATSextfcall
#define ATSextfcall(fun, funarg) fun funarg
%} // end of [%{^]
(* ****** ****** *)
//
#include
"share/atspre_staload.hats"
//
(* ****** ****** *)
%{^
//
#include <vector>
//
#define \
fvectorptr(elt) std::vector<elt>*
//
#define \
fvectorptr_new(elt) new std::vector<int>()
#define \
fvectorptr_free(elt, p0) \
delete(static_cast<std::vector<elt>*>(p0))
//
#define \
fvectorptr_get_at(elt, p0, i) \
(*(static_cast<std::vector<elt>*>(p0)))[i]
//
#define \
fvectorptr_push_back(elt, p0, x0) \
(static_cast<std::vector<elt>*>(p0))->push_back(x0)
//
%} // end of [%{^]
(* ****** ****** *)
//
absvtype
vectorptr(a:t@ype+) = $extype"fvectorptr"(a)
//
(* ****** ****** *)
//
extern
fun
{a:t@ype}
vectorptr_new(): vectorptr(a)
extern
fun
{a:t@ype}
vectorptr_free(vectorptr(a)): void
//
extern
fun
{a:t@ype}
vectorptr_get_at
(p0: !vectorptr(INV(a)), int): a
//
overload [] with vectorptr_get_at
//
extern
fun
{a:t@ype}
vectorptr_push_back
(p0: !vectorptr(INV(a)), a): void
//
(* ****** ****** *)
//
implement
{elt}
vectorptr_new
(
// argumentless
) =
$extfcall
(
vectorptr(elt), "fvectorptr_new", $tyrep(elt)
) (* vectorptr_new *)
//
(* ****** ****** *)
//
implement
{elt}
vectorptr_free
(
p0
) = let
//
val p0 = $UNSAFE.castvwtp0{ptr}(p0)
//
in
//
$extfcall
(void, "fvectorptr_free", $tyrep(elt), p0)
//
end // end of [vectorptr_free]
//
(* ****** ****** *)
//
implement
{elt}
vectorptr_get_at
(p0, i) = let
//
val p0 = $UNSAFE.castvwtp1{ptr}(p0)
//
in
//
$extfcall
(elt, "fvectorptr_get_at", $tyrep(elt), p0, i)
//
end // end of [vectorptr_get_at]
//
(* ****** ****** *)
//
implement
{a}(*tmp*)
vectorptr_push_back
(p0, x) = let
val p0 = $UNSAFE.castvwtp1{ptr}(p0)
in
$extfcall(void, "fvectorptr_push_back", $tyrep(a), p0, x)
end // end of [vectorptr_push_back]
//
(* ****** ****** *)
//
extern
fun
fact(n: int): int = "ext#"
//
(* ****** ****** *)
implement
fact(n) = res where
{
//
val p0 =
vectorptr_new<int>()
// end of [val]
val () = loop(p0, 0) where
{
fun
loop
(
p0: !vectorptr(int), i: int
) : void =
if i < n then
(
vectorptr_push_back(p0, i+1); loop(p0, i+1)
)
// end of [loop]
}
val res = loop(p0, 0, 1) where
{
fun
loop
(
p0: !vectorptr(int), i: int, res: int
) : int =
if i < n then loop(p0, i+1, res * p0[i]) else res
// end of [loop]
}
//
val ((*freed*)) = vectorptr_free(p0)
//
} (* end of [fact] *)
(* ****** ****** *)
(*
implement
main0() =
println! ("fact(10) = ", fact(10))
*)
(* ****** ****** *)
%{$
#include <iostream>
int main()
{
//
std::cout <<
"fact(10) = " << fact(10) << std::endl;
//
return 0;
//
} /* end of [main] */
%} // end of [%{$]
(* ****** ****** *)
(* end of [test02.dats] *)
|
