1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
(* ****** ****** *)
//
// Author: Hongwei Xi
// Start time: May, 2017
// Authoremail: gmhwxiATgmailDOTcom
//
(* ****** ****** *)
(*
** For supporting in ATS a form
** of meta-programming for OpenSCAD
*)
(* ****** ****** *)
//
#staload
UN =
"prelude/SATS/unsafe.sats"
//
(* ****** ****** *)
//
#staload
MATH =
"libats/libc/SATS/math.sats"
//
(* ****** ****** *)
//
#staload
"./../SATS/OpenSCAD.sats"
#staload
"./../SATS/OpenSCAD_util.sats"
//
(* ****** ****** *)
//
implement
point2_make_int2
(x, y) =
(
POINT2
(g0i2f(x), g0i2f(y))
)
//
implement
point2_make_float2
(x, y) = POINT2(x, y)
//
(* ****** ****** *)
//
implement
point3_make_int3
(x, y, z) =
(
POINT3
(g0i2f(x), g0i2f(y), g0i2f(z))
)
//
implement
point3_make_float3
(x, y, z) = POINT3(x, y, z)
//
(* ****** ****** *)
//
// HX:
// POINT2 and VECTOR2 must
// have the same representation!!!
//
implement
point2vector_2d(p2d) = $UN.cast(p2d)
implement
vector2point_2d(v2d) = $UN.cast(v2d)
//
(* ****** ****** *)
//
// HX:
// POINT3 and VECTOR3 must
// have the same representation!!!
//
implement
point2vector_3d(p3d) = $UN.cast(p3d)
implement
vector2point_3d(v3d) = $UN.cast(v3d)
//
(* ****** ****** *)
macdef sqrt = $MATH.sqrt_double
(* ****** ****** *)
//
implement
length_v2d(v2d) = let
val+VECTOR2(x, y) = v2d in sqrt(x*x+y*y)
end // end of [length_v2d]
//
implement
length_v3d(v3d) = let
val+VECTOR3(x, y, z) = v3d in sqrt(x*x+y*y+z*z)
end // end of [length_v3d]
//
(* ****** ****** *)
implement
distance_p2d_p2d
(p1, p2) = let
//
val+POINT2(x1, y1) = p1
val+POINT2(x2, y2) = p2
//
val x12 = x2 - x1 and y12 = y2 - y1
//
in
sqrt(x12*x12 + y12*y12)
end // end of [distance_p2d_p2d]
(* ****** ****** *)
implement
distance_p3d_p3d
(p1, p2) = let
//
val+POINT3(x1, y1, z1) = p1
val+POINT3(x2, y2, z2) = p2
//
val x12 = x2 - x1
and y12 = y2 - y1
and z12 = z2 - z1
//
in
sqrt(x12*x12 + y12*y12 + z12*z12)
end // end of [distance_p3d_p3d]
(* ****** ****** *)
implement
add_p3d_v3d
(p3d, v3d) = let
//
val POINT3(x, y, z) = p3d
val VECTOR3(vx, vy, vz) = v3d
//
in
POINT3(x+vx, y+vy, z+vz)
end // end of [add_p3d_v3d]
(* ****** ****** *)
implement
sub_p3d_v3d
(p3d, v3d) = let
//
val POINT3(x, y, z) = p3d
val VECTOR3(vx, vy, vz) = v3d
//
in
POINT3(x-vx, y-vy, z-vz)
end // end of [sub_p3d_v3d]
implement
sub_p3d_p3d
(p3d1, p3d2) = let
//
val POINT3(x1, y1, z1) = p3d1
val POINT3(x2, y2, z2) = p3d2
//
in
VECTOR3(x1-x2, y1-y2, z1-z2)
end // end of [sub_p3d_p3d]
(* ****** ****** *)
//
implement
mul_int_v3d
(c, v3d) = let
//
val VECTOR3(vx, vy, vz) = v3d
//
in
VECTOR3(c * vx, c * vy, c * vz)
end // end of [mul_int_v3d]
//
implement
mul_float_v3d
(c, v3d) = let
//
val VECTOR3(vx, vy, vz) = v3d
//
in
VECTOR3(c * vx, c * vy, c * vz)
end // end of [mul_float_v3d]
//
(* ****** ****** *)
//
implement
div_v3d_int
(v3d, c) = let
//
val VECTOR3(vx, vy, vz) = v3d
//
in
VECTOR3(vx / c, vy / c, vz / c)
end // end of [div_v3d_int]
//
implement
div_v3d_float
(v3d, c) = let
//
val VECTOR3(vx, vy, vz) = v3d
//
in
VECTOR3(vx / c, vy / c, vz / c)
end // end of [div_v3d_float]
//
(* ****** ****** *)
(* end of [OpenSCAD_util.dats] *)
|
