1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
|
cmake_minimum_required(VERSION 3.25)
###########################################
#### Usage: cmake -P ci.cmake -- cmake args
###########################################
if(NOT CMAKE_SCRIPT_MODE_FILE)
message(FATAL_ERROR "Script mode is required")
endif()
cmake_path(GET CMAKE_SCRIPT_MODE_FILE PARENT_PATH CMAKE_SOURCE_DIR)
message(STATUS "CMAKE_VERSION: ${CMAKE_VERSION}")
message(STATUS "CMAKE_SOURCE_DIR: ${CMAKE_SOURCE_DIR}")
message(STATUS "CMAKE_BINARY_DIR: ${CMAKE_BINARY_DIR}")
if(CMAKE_COMMAND MATCHES " ")
set(CMAKE_COMMAND cmake)
endif()
if(CMAKE_CTEST_COMMAND MATCHES " ")
set(CMAKE_CTEST_COMMAND ctest)
endif()
set(IMPORT_PY ${CMAKE_SOURCE_DIR}/ci/import.py)
if(NOT DEFINED SPLIT)
if(DEFINED ENV{SPLIT})
set(SPLIT $ENV{SPLIT})
else()
set(SPLIT ON)
endif()
endif()
function(GET_PARAMS _params _definitions)
foreach(_arg RANGE ${CMAKE_ARGC})
if("${CMAKE_ARGV${_arg}}" STREQUAL "--")
math(EXPR delimiter "${_arg}+1")
break()
elseif("${CMAKE_ARGV${_arg}}" MATCHES "^-D")
list(APPEND definition ${CMAKE_ARGV${_arg}})
endif()
endforeach()
if(DEFINED delimiter)
foreach(_arg RANGE ${delimiter} ${CMAKE_ARGC})
list(APPEND param ${CMAKE_ARGV${_arg}})
endforeach()
set(${_params} "${param}" PARENT_SCOPE)
endif()
if(DEFINED definition)
set(${_definitions} "${definition}" PARENT_SCOPE)
endif()
endfunction()
function(CALC_CHECKSUM _out_checksum)
set(CHECKSUM_FILES ${CMAKE_SCRIPT_MODE_FILE} ${IMPORT_PY})
if(ARGN)
list(APPEND CHECKSUM_FILES ${ARGN})
endif()
foreach(file ${CHECKSUM_FILES})
file(MD5 "${file}" _hash)
string(MD5 hashes "${_hash}${hashes}")
endforeach()
set(${_out_checksum} ${hashes} PARENT_SCOPE)
endfunction()
function(CALC_REPATCH_CHECKSUM _out_checksum _out_repatch)
CALC_CHECKSUM(hashes)
if(SPLIT AND PATCHED AND NOT ${_out_checksum} STREQUAL hashes)
set(${_out_repatch} ON PARENT_SCOPE)
endif()
set(${_out_checksum} ${hashes} PARENT_SCOPE)
endfunction()
function(IMPORT_PATCH _out)
message(STATUS "Import patch(es)...")
find_package(Python REQUIRED)
step(${Python_EXECUTABLE} ${IMPORT_PY} ${ARGN} NO_ECHO OUTPUT output CHDIR ${CMAKE_SOURCE_DIR})
if(output MATCHES "Pending patch: (.+)")
string(STRIP "${CMAKE_MATCH_1}" PENDING_PATCH)
set(${_out} "${PENDING_PATCH}" PARENT_SCOPE)
endif()
endfunction()
function(STEP)
set(options NO_ECHO)
set(oneValueArgs CHDIR OUTPUT RESULT PATH INPUT_FILE OUTPUT_FILE)
set(multiValueArgs ENV)
cmake_parse_arguments(_PARAM "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
if(_PARAM_ENV)
set(ENV_CMD ${CMAKE_COMMAND} -E env)
foreach(env ${_PARAM_ENV})
if(env MATCHES "^PATH=")
message(FATAL_ERROR "Use explicit PATH parameter")
endif()
list(APPEND ENV_CMD "${env}")
endforeach()
list(APPEND ENV_CMD --)
endif()
if(NOT _PARAM_CHDIR OR (ECHO AND NOT _PARAM_NO_ECHO))
set(_PARAM_CHDIR ${CMAKE_BINARY_DIR})
endif()
if(_PARAM_OUTPUT)
set(OUTPUT_OPTION OUTPUT_VARIABLE)
set(OUTPUT _output)
endif()
if(_PARAM_INPUT_FILE)
set(INPUT_FILE_OPTION INPUT_FILE)
endif()
if(_PARAM_OUTPUT_FILE)
set(OUTPUT_FILE_OPTION OUTPUT_FILE)
endif()
if(_PARAM_NO_ECHO OR NOT ECHO)
set(COMMAND_ECHO STDOUT)
else()
set(ECHO_CMD ${CMAKE_COMMAND} -E echo)
set(COMMAND_ECHO NONE)
endif()
if(_PARAM_PATH)
set(TMP_PATH "$ENV{PATH}")
if(CMAKE_HOST_SYSTEM_NAME MATCHES "Windows")
set(SEP ";")
else()
set(SEP ":")
endif()
set(ENV{PATH} "${_PARAM_PATH}${SEP}$ENV{PATH}")
endif()
execute_process(COMMAND ${ECHO_CMD} ${ENV_CMD} ${_PARAM_UNPARSED_ARGUMENTS}
RESULT_VARIABLE _result
${OUTPUT_OPTION} ${OUTPUT}
${INPUT_FILE_OPTION} ${_PARAM_INPUT_FILE}
${OUTPUT_FILE_OPTION} ${_PARAM_OUTPUT_FILE}
ECHO_OUTPUT_VARIABLE
WORKING_DIRECTORY ${_PARAM_CHDIR}
COMMAND_ECHO ${COMMAND_ECHO})
if(TMP_PATH)
set(ENV{PATH} "${TMP_PATH}")
unset(TMP_PATH)
endif()
if(NOT ${_result} EQUAL 0)
if(_PARAM_RESULT)
set(${_PARAM_RESULT} ${_result} PARENT_SCOPE)
else()
message(FATAL_ERROR "Process failed: ${_result}")
endif()
endif()
if(_PARAM_OUTPUT)
set(${_PARAM_OUTPUT} ${${OUTPUT}} PARENT_SCOPE)
endif()
endfunction()
function(CALL_SCRIPT)
if(NOT SCRIPT)
message(FATAL_ERROR "SCRIPT is undefined")
endif()
SET_TEMPLATES()
if(EXISTS ${T_BUILD_DIR})
step(${CMAKE_COMMAND} -E rm -r ${T_BUILD_DIR})
endif()
if(NOT EXISTS "${CACHE_DIR}")
file(MAKE_DIRECTORY "${CACHE_DIR}")
endif()
cmake_path(RELATIVE_PATH SCRIPT BASE_DIRECTORY "${CMAKE_SOURCE_DIR}" OUTPUT_VARIABLE SCRIPT_PATH)
message(STATUS "Use SCRIPT: ${SCRIPT_PATH}")
block()
include(${SCRIPT})
endblock()
endfunction()
function(fetch_script _out_script _out_path _path _names)
file(GLOB scripts "${_path}/*.cmake")
foreach(part ${_names})
foreach(entry ${scripts})
cmake_path(GET entry STEM filename)
if(part STREQUAL filename)
if(IS_DIRECTORY "${entry}")
fetch_script(script ${_out_path} "${entry}" "${_names}")
else()
set(script ${entry})
endif()
if(script)
set(${_out_script} ${script} PARENT_SCOPE)
if(IS_DIRECTORY "${entry}")
set(${_out_path} ${${_out_path}} ${entry} PARENT_SCOPE)
endif()
return()
endif()
endif()
endforeach()
endforeach()
endfunction()
macro(PARSE_FROM_NAME)
if(DEFINED ENV{JOB_NAME} AND NOT NAME)
set(NAME $ENV{JOB_NAME})
endif()
if(DEFINED ENV{CI_JOB_NAME} AND NOT NAME)
set(NAME $ENV{CI_JOB_NAME})
endif()
if(NOT DEFINED ENV{CI} AND NOT NAME)
set(NAME ${CMAKE_HOST_SYSTEM_NAME})
message(STATUS "Automatic detection for developer: ${NAME}")
endif()
if(NAME)
string(REGEX MATCHALL "[A-Za-z0-9.-]+" NAMES "${NAME}")
message(STATUS "Use NAME: ${NAME}")
message(STATUS "Use NAMES: ${NAMES}")
if((NAME MATCHES "_Review_" OR DEFINED ENV{REVIEWBOARD_REVIEW_ID} OR DEFINED ENV{PATCH_URL}) AND NOT DEFINED REVIEW)
set(REVIEW ON)
elseif((NAME MATCHES "^Release_" OR DEFINED ENV{RELEASE}) AND NOT DEFINED RELEASE)
if(DEFINED ENV{GITLAB_CI})
set(RELEASE $ENV{RELEASE})
else()
set(RELEASE ON)
endif()
endif()
if(NOT SCRIPT)
set(CMAKE_CI_DIR "${CMAKE_SOURCE_DIR}/ci/cmake")
fetch_script(SCRIPT CMAKE_MODULE_PATH "${CMAKE_CI_DIR}" "${NAMES}")
list(APPEND CMAKE_MODULE_PATH ${CMAKE_CI_DIR})
endif()
endif()
if(NOT REVIEW AND NOT RELEASE)
set(DAILY ON)
endif()
endmacro()
macro(SET_TEMPLATES) # Provide some base templates for SCRIPTs
if(DEFINED ENV{WORKSPACE})
set(WORKSPACE $ENV{WORKSPACE})
elseif(DEFINED ENV{CI_PROJECT_DIR})
set(WORKSPACE $ENV{CI_PROJECT_DIR})
else()
set(WORKSPACE ${CMAKE_BINARY_DIR})
endif()
if(DEFINED ENV{CACHE_DIR})
set(CACHE_DIR $ENV{CACHE_DIR})
else()
set(CACHE_DIR ${WORKSPACE}/cache)
endif()
set(T_TEMP "${WORKSPACE}/tmp")
set(ENV{TMP} "${T_TEMP}")
set(ENV{TEMP} "${T_TEMP}")
set(ENV{TMPDIR} "${T_TEMP}")
if(NOT EXISTS "${T_TEMP}")
file(MAKE_DIRECTORY "${T_TEMP}")
endif()
set(CMAKE_DIR "${CMAKE_SOURCE_DIR}/cmake")
if(DEFINED LIBS)
set(T_LIBS_DIR ${LIBS})
else()
set(T_LIBS_DIR libs)
endif()
if(DEFINED BUILD)
set(T_BUILD_DIR ${BUILD})
else()
set(T_BUILD_DIR build)
endif()
set(T_DIST_DIR ${T_BUILD_DIR}/dist)
set(T_BUILD ${CMAKE_COMMAND} --build ${T_BUILD_DIR})
set(T_TARGET ${T_BUILD} --target)
set(T_CTEST ${CMAKE_CTEST_COMMAND} --test-dir ${T_BUILD_DIR} --output-on-failure)
set(T_CMAKE_FRESH ${CMAKE_COMMAND} --fresh)
set(T_CFG ${T_CMAKE_FRESH} ${PARAMS} -S ${CMAKE_SOURCE_DIR} -B ${T_BUILD_DIR})
set(T_CFG_LIBS ${T_CMAKE_FRESH} ${PARAMS} -S ${CMAKE_SOURCE_DIR}/libs -B ${T_LIBS_DIR})
set(T_CFG_LIBS_DEPS ${T_CMAKE_FRESH} -S ${CMAKE_SOURCE_DIR}/libs -B ${T_LIBS_DIR})
endmacro()
function(hashsum)
set(options NO_FILENAME)
set(multiValueArgs ALGORITHM)
cmake_parse_arguments(_PARAM "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
if(NOT DEFINED _PARAM_ALGORITHM)
set(_PARAM_ALGORITHM SHA256)
endif()
foreach(entry ${_PARAM_UNPARSED_ARGUMENTS})
foreach(algo ${_PARAM_ALGORITHM})
string(TOLOWER "${algo}" fileending)
file(${algo} ${entry} fileHash)
cmake_path(GET entry FILENAME fileName)
set(hashfile ${entry}.${fileending})
file(WRITE ${hashfile} "${fileHash}")
if(NOT ${_PARAM_NO_FILENAME})
file(APPEND ${hashfile} " ${fileName}")
endif()
file(APPEND ${hashfile} "\n")
endforeach()
endforeach()
endfunction()
function(RESPAWN_PATCHED)
if(SPLIT)
set(SPLIT_PARAM --split)
endif()
if(NOT PATCHED)
set(CLEAN_PARAM --clean)
endif()
if(REPATCH)
set(REPATCH_PARAM --repatch)
endif()
if(NOT PATCHED OR SPLIT)
unset(PENDING_PATCH CACHE)
IMPORT_PATCH(PENDING_PATCH ${SPLIT_PARAM} ${CLEAN_PARAM} ${REPATCH_PARAM})
if(PENDING_PATCH OR NOT PATCHED)
set(PATCHED_OPTION "-DPATCHED=ON")
if(NOT PATCHED_OPTION IN_LIST DEFINITIONS)
list(APPEND DEFINITIONS ${PATCHED_OPTION})
endif()
set(PENDING_PATCH_OPTION "-DPENDING_PATCH")
list(FILTER DEFINITIONS EXCLUDE REGEX "${PENDING_PATCH_OPTION}")
if(PENDING_PATCH)
list(APPEND DEFINITIONS "${PENDING_PATCH_OPTION}=${PENDING_PATCH}")
endif()
set(CHECKSUM_OPTION "-DCHECKSUM")
list(FILTER DEFINITIONS EXCLUDE REGEX "${CHECKSUM_OPTION}")
list(APPEND DEFINITIONS "${CHECKSUM_OPTION}=${CHECKSUM}")
if(NOT PATCHED AND SPLIT)
set(INITIAL_RUNNER INITIAL_RUNNER_FAILED)
endif()
message(STATUS "script runner: respawn")
step(${CMAKE_COMMAND} ${DEFINITIONS} -P ${CMAKE_SCRIPT_MODE_FILE} -- ${PARAMS} NO_ECHO RESULT ${INITIAL_RUNNER})
if(INITIAL_RUNNER)
if(CLEAN OR DEFINED ENV{JENKINS_HOME})
IMPORT_PATCH(_unused --clean-only)
endif()
if(INITIAL_RUNNER_FAILED)
message(FATAL_ERROR "script runner: failed")
else()
message(STATUS "script runner: done")
endif()
endif()
endif()
endif()
endfunction()
function(RUN)
PARSE_FROM_NAME()
GET_PARAMS(PARAMS DEFINITIONS)
CALC_REPATCH_CHECKSUM(CHECKSUM REPATCH)
if(NOT REPATCH AND (NOT REVIEW OR PATCHED))
CALL_SCRIPT()
endif()
if(REVIEW)
if(NOT PATCHED AND DEFINED ENV{GITLAB_CI})
include(Files)
set(patch.diff "${CMAKE_BINARY_DIR}/patch.diff")
if(DEFINED ENV{PATCH_URL})
step(uv pip install python-hglib)
handle_http("${patch.diff}" URLS $ENV{PATCH_URL})
elseif(DEFINED ENV{REVIEWBOARD_REVIEW_ID})
step(uv pip install rbtools python-hglib)
step(rbt patch --write ${patch.diff} --server $ENV{REVIEWBOARD_SERVER} --diff-revision $ENV{REVIEWBOARD_DIFF_REVISION} $ENV{REVIEWBOARD_REVIEW_ID})
elseif(EXISTS "${patch.diff}")
message(STATUS "Use existing patch: ${patch.diff}")
else()
message(FATAL_ERROR "Unknown patch source")
endif()
endif()
RESPAWN_PATCHED()
endif()
endfunction()
if(PATCH_ONLY)
IMPORT_PATCH(_unused --clean)
else()
RUN()
endif()
|
