1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
|
!----------------------------------------------------------------------
!----------------------------------------------------------------------
! brc : A parabolic PDE (the Brusselator)
!----------------------------------------------------------------------
!----------------------------------------------------------------------
! (Discretized in space by polynomial collocation at Chebyshev points)
!----------------------------------------------------------------------
!----------------------------------------------------------------------
! NOTE: The value of the constant NE is defined in the module brc below.
!
! NE : the dimension of the PDE system
!
! NN : the number of Chebyshev collocation points in space is
! determined by the AUTO-constant NDIM:
! NN = NDIM/NE
!----------------------------------------------------------------------
!----------------------------------------------------------------------
MODULE brc
SAVE
INTEGER, PARAMETER :: NE=2
DOUBLE PRECISION, ALLOCATABLE :: D2(:,:)
END MODULE brc
SUBROUTINE FF(NE,U,PAR,F)
! ---------- --
! Define the nonlinear term
IMPLICIT NONE
INTEGER, INTENT(IN) :: NE
DOUBLE PRECISION, INTENT(IN) :: U(NE),PAR(*)
DOUBLE PRECISION, INTENT(OUT) :: F(NE)
DOUBLE PRECISION X,Y,A,B
X=U(1)
Y=U(2)
A=PAR(1)
B=PAR(2)
F(1)= X**2*Y - (B+1)*X + A
F(2)=-X**2*Y + B*X
END SUBROUTINE FF
SUBROUTINE SETDC(NE,DC,PAR)
! ---------- -----
! Set the diffusion constants (constant, or in terms of PAR)
IMPLICIT NONE
INTEGER, INTENT(IN) :: NE
DOUBLE PRECISION, INTENT(OUT) :: DC(NE)
DOUBLE PRECISION, INTENT(IN) :: PAR(*)
DC(1)=PAR(3)/PAR(5)**2
DC(2)=PAR(4)/PAR(5)**2
END SUBROUTINE SETDC
SUBROUTINE SETBC(NE,PAR,U0,U1)
! ---------- -----
! Set the boundary values (to be kept fixed in time)
IMPLICIT NONE
INTEGER, INTENT(IN) :: NE
DOUBLE PRECISION, INTENT(IN) :: PAR(*)
DOUBLE PRECISION, INTENT(OUT) :: U0(NE),U1(NE)
DOUBLE PRECISION A,B
A=PAR(1)
B=PAR(2)
U0(1)=A
U0(2)=B/A
U1(1)=A
U1(2)=B/A
END SUBROUTINE SETBC
SUBROUTINE STPNT(NDIM,U,PAR,T)
! ---------- -----
! Define the starting stationary solution on the spatial mesh
USE brc
IMPLICIT NONE
INTEGER, INTENT(IN) :: NDIM
DOUBLE PRECISION, INTENT(INOUT) :: U(NDIM/NE,NE),PAR(*)
DOUBLE PRECISION, INTENT(IN) :: T
INTEGER I,NN
DOUBLE PRECISION A,B,Dx,Dy,RL
! Set the parameter values
A=2.d0
B=5.45d0
Dx=0.008d0
Dy=0.004d0
RL=0.4
PAR(1)=A
PAR(2)=B
PAR(3)=Dx
PAR(4)=Dy
PAR(5)=RL
! Set the starting solution at the Chebyshev collocation points
NN=NDIM/NE
DO I=1,NN
U(I,1)=A
U(I,2)=B/A
ENDDO
END SUBROUTINE STPNT
!----------------------------------------------------------------------
!----------------------------------------------------------------------
! Problem-independent subroutines
!----------------------------------------------------------------------
!----------------------------------------------------------------------
SUBROUTINE FUNC(NDIM,U,ICP,PAR,IJAC,F,DFDU,DFDP)
! ---------- ----
USE brc
IMPLICIT NONE
INTEGER, INTENT(IN) :: NDIM, ICP(*), IJAC
DOUBLE PRECISION, INTENT(IN) :: U(NDIM/NE,NE), PAR(*)
DOUBLE PRECISION, INTENT(OUT) :: F(NDIM/NE,NE)
DOUBLE PRECISION, INTENT(INOUT) :: DFDU(NDIM,NDIM), DFDP(NDIM,*)
DOUBLE PRECISION W(NE),FW(NE),DC(NE),U0(NE),U1(NE)
INTEGER I,J,K,NN,NP
! Problem-independent initialization :
NN=NDIM/NE
NP=NN+1
CALL SETDC(NE,DC,PAR)
CALL SETBC(NE,PAR,U0,U1)
DO I=1,NN
DO K=1,NE
W(K)=U(I,K)
ENDDO
CALL FF(NE,W,PAR,FW)
DO J=1,NE
F(I,J)=FW(J) + DC(J)*(U0(J)*D2(I,0)+U1(J)*D2(I,NP))
DO K=1,NN
F(I,J)=F(I,J)+DC(J)*D2(I,K)*U(K,J)
ENDDO
ENDDO
ENDDO
END SUBROUTINE FUNC
SUBROUTINE GENCF(PAR,NN)
! ---------- -----
USE brc
IMPLICIT NONE
INTEGER, INTENT(IN) :: NN
DOUBLE PRECISION, INTENT(IN) :: PAR(*)
DOUBLE PRECISION, ALLOCATABLE :: X(:),XX(:,:),CC(:,:),RI(:,:)
INTEGER, ALLOCATABLE :: IR(:),IC(:)
DOUBLE PRECISION pi,C,DET
INTEGER I,J,K,M,NP
NP=NN+1
M=NN+2
ALLOCATE(D2(NN,0:NP))
ALLOCATE(X(M),XX(M,M),CC(M,0:NP),RI(M,M),IR(M),IC(M))
pi=4*ATAN(1.d0)
X(1)=0.d0
DO K=2,NP
C=COS( (2*K-3)*pi/(2*NN) )
X(K)=(1+C)/2
ENDDO
X(M)=1.d0
DO I=1,M
DO J=1,M
RI(I,J)=0.d0
XX(I,J)=X(I)**(J-1)
ENDDO
RI(I,I)=1.d0
ENDDO
CALL GE(0,M,M,XX,M,M,CC,M,RI,IR,IC,DET)
DO I=1,NN
DO J=0,NP
D2(I,J)=0.d0
DO K=2,M-1
D2(I,J)=D2(I,J)+CC(K+1,J)*K*(K-1)*X(I+1)**(K-2)
ENDDO
ENDDO
ENDDO
DEALLOCATE(X,XX,CC,RI,IR,IC)
END SUBROUTINE GENCF
SUBROUTINE BCND
END SUBROUTINE BCND
SUBROUTINE ICND
END SUBROUTINE ICND
SUBROUTINE FOPT
END SUBROUTINE FOPT
!----------------------------------------------------------------------
!----------------------------------------------------------------------
SUBROUTINE PVLS(NDIM,U,PAR)
! ---------- ----
USE brc
IMPLICIT NONE
INTEGER, INTENT(IN) :: NDIM
DOUBLE PRECISION, INTENT(IN) :: U(NDIM)
DOUBLE PRECISION, INTENT(INOUT) :: PAR(*)
LOGICAL, SAVE :: ifrst = .TRUE.
! Problem-independent initialization :
IF(ifrst)THEN
CALL GENCF(PAR,NDIM/NE)
ifrst=.FALSE.
ENDIF
END SUBROUTINE PVLS
|
