1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
|
<!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01//EN"
"http://www.w3.org/TR/html4/strict.dtd">
<html lang="en">
<head>
<title>
Autoconf Macro: ax_compare_version
</title>
<link rel="stylesheet" type="text/css" href="ac-archive.css">
</head>
<body>
<table summary="web navigation" style="width:100%;">
<tbody>
<tr>
<td style="width:50%;" align="center">
<a href="http://autoconf-archive.cryp.to/ax_compare_version.m4">Download
M4 Source</a>
</td>
<td style="width:50%;" align="center">
<a href="macros-by-category.html">Macro Index Page</a>
</td>
</tr>
</tbody>
</table>
<hr>
<h1>
ax_compare_version
</h1>
<h2>
Synopsis
</h2>
<p class="indent" style="white-space:nowrap;">
<code>AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE],
[ACTION-IF-FALSE])</code>
</p>
<h2>
Description
</h2>
<div class="indent">
<p>
This macro compares two version strings. It is used heavily in the macro
_AX_PATH_BDB for library checking. Due to the various number of
minor-version numbers that can exist, and the fact that string comparisons
are not compatible with numeric comparisons, this is not necessarily
trivial to do in a autoconf script. This macro makes doing these
comparisons easy.
</p>
<p>
The six basic comparisons are available, as well as checking equality
limited to a certain number of minor-version levels.
</p>
<p>
The operator OP determines what type of comparison to do, and can be one
of:
</p>
<pre>
eq - equal (test A == B)
ne - not equal (test A != B)
le - less than or equal (test A <= B)
ge - greater than or equal (test A >= B)
lt - less than (test A < B)
gt - greater than (test A > B)
</pre>
<p>
Additionally, the eq and ne operator can have a number after it to limit
the test to that number of minor versions.
</p>
<pre>
eq0 - equal up to the length of the shorter version
ne0 - not equal up to the length of the shorter version
eqN - equal up to N sub-version levels
neN - not equal up to N sub-version levels
</pre>
<p>
When the condition is true, shell commands ACTION-IF-TRUE are run,
otherwise shell commands ACTION-IF-FALSE are run. The environment variable
'ax_compare_version' is always set to either 'true' or 'false' as well.
</p>
<p>
Examples:
</p>
<pre>
AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8])
AX_COMPARE_VERSION([3.15],[lt],[3.15.8])
</pre>
<p>
would both be true.
</p>
<pre>
AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8])
AX_COMPARE_VERSION([3.15],[gt],[3.15.8])
</pre>
<p>
would both be false.
</p>
<pre>
AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8])
</pre>
<p>
would be true because it is only comparing two minor versions.
</p>
<pre>
AX_COMPARE_VERSION([3.15.7],[eq0],[3.15])
</pre>
<p>
would be true because it is only comparing the lesser number of minor
versions of the two values.
</p>
<p>
Note: The characters that separate the version numbers do not matter. An
empty string is the same as version 0. OP is evaluated by autoconf, not
configure, so must be a string, not a variable.
</p>
<p>
The author would like to acknowledge Guido Draheim whose advice about the
m4_case and m4_ifvaln functions make this macro only include the portions
necessary to perform the specific comparison specified by the OP argument
in the final configure script.
</p>
</div>
<h2>
Author
</h2>
<p class="indent">
Tim Toolan <toolan@ele.uri.edu>
</p>
<h2>
Last Modified
</h2>
<p class="indent">
2004-03-01
</p>
<h2>
M4 Source Code
</h2>
<div class="indent">
<pre class="m4source">
dnl #########################################################################
AC_DEFUN([AX_COMPARE_VERSION], [
# Used to indicate true or false condition
ax_compare_version=false
# Convert the two version strings to be compared into a format that
# allows a simple string comparison. The end result is that a version
# string of the form 1.12.5-r617 will be converted to the form
# 0001001200050617. In other words, each number is zero padded to four
# digits, and non digits are removed.
AS_VAR_PUSHDEF([A],[ax_compare_version_A])
A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
-e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
-e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
-e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
-e 's/[[^0-9]]//g'`
AS_VAR_PUSHDEF([B],[ax_compare_version_B])
B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \
-e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \
-e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \
-e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \
-e 's/[[^0-9]]//g'`
dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary
dnl # then the first line is used to determine if the condition is true.
dnl # The sed right after the echo is to remove any indented white space.
m4_case(m4_tolower($2),
[lt],[
ax_compare_version=`echo "x$A
x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"`
],
[gt],[
ax_compare_version=`echo "x$A
x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"`
],
[le],[
ax_compare_version=`echo "x$A
x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"`
],
[ge],[
ax_compare_version=`echo "x$A
x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"`
],[
dnl Split the operator from the subversion count if present.
m4_bmatch(m4_substr($2,2),
[0],[
# A count of zero means use the length of the shorter version.
# Determine the number of characters in A and B.
ax_compare_version_len_A=`echo "$A" | awk '{print(length)}'`
ax_compare_version_len_B=`echo "$B" | awk '{print(length)}'`
# Set A to no more than B's length and B to no more than A's length.
A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"`
B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"`
],
[[0-9]+],[
# A count greater than zero means use only that many subversions
A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"`
],
[.+],[
AC_WARNING(
[illegal OP numeric parameter: $2])
],[])
# Pad zeros at end of numbers to make same length.
ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`"
B="$B`echo $A | sed 's/./0/g'`"
A="$ax_compare_version_tmp_A"
# Check for equality or inequality as necessary.
m4_case(m4_tolower(m4_substr($2,0,2)),
[eq],[
test "x$A" = "x$B" && ax_compare_version=true
],
[ne],[
test "x$A" != "x$B" && ax_compare_version=true
],[
AC_WARNING([illegal OP parameter: $2])
])
])
AS_VAR_POPDEF([A])dnl
AS_VAR_POPDEF([B])dnl
dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE.
if test "$ax_compare_version" = "true" ; then
m4_ifvaln([$4],[$4],[:])dnl
m4_ifvaln([$5],[else $5])dnl
fi
]) dnl AX_COMPARE_VERSION
</pre>
</div>
</body>
</html>
|
