1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
/* -*- Mode: Asm -*- */
/* Copyright (c) 2002 Michael Stumpf <mistumpf@de.pepperl-fuchs.com>
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are met:
* Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.
* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in
the documentation and/or other materials provided with the
distribution.
* Neither the name of the copyright holders nor the names of
contributors may be used to endorse or promote products derived
from this software without specific prior written permission.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
POSSIBILITY OF SUCH DAMAGE.
*/
/*
ceil.S is part of FPlib V 0.3.0 ported to avr-as
for details see readme.fplib
*----------------------------------------------------------------------------------------
*
* A = ceil(A)
*
* grter ganzzahliger Wert, der nicht kleiner als arg ist
* fr X > 4B 7F FF FF : X = X (Zahlen haben keinen Bruchteil mehr)
* X >= 0
* X == (float)(long)X X = X (Zahlen hat keinen Bruchteil)
* X != (float)(long)X X = (float)(long)X+1 (Zahlen hat einen Bruchteil)
* X < 0 then
* X = (float)(long)X
*
* comments on ceil & floor
* 1.0 = 7F:80 00 00 00 ->
* denormalize to LSB of mantissa == 1.0
* 96:00 00 01
* 2.0 = 80:80 00 00 00 ->
* 96:00 00 02
*/
#include "gasava.inc"
#include "fplib.inc"
TEXT_SEG(fplib, ceil)
FUNCTION(ceil)
GLOBAL(ceil)
BST rA3,7
RCALL _U(__fp_split1) ; split up in sign : exp : fraction : fraction extention
; x T R19 R18:rSI0:R16: R1
CPI rA3,0x7F ; Exp >= 0x7F -> arg >= 1.0
BRCC _ceil_100 ;
BRTS _ceil_01 ; |arg| < 1.0 -> ceil = / 1.0 fr X > 0.0
TST rA3 ; \ 0.0 fr X <= 0.0
BREQ _ceil_01
LDI rA3,0x3F
LDI rA2,0x80
CLR rA1
CLR rA0
RET
_ceil_01:
RJMP _U(__fp_zero)
_ceil_100_1:
LSR rA2 ;
ROR rA1 ; shift out fractional bits to the right
ROR rA0 ; until mantissa is a normalized unsigned
adc rAE,rT1c ; rAE cleard by fp_split1, rT1c = __zero_reg__
INC rA3 ;
; |arg| >= 1.0
_ceil_100: ; |arg| >= 1.0
CPI rA3,0x96 ;
BRCS _ceil_100_1;
_ceil_200:
BRTS _ceil_300 ; LSB now is exactely 1 or greater
TST rAE ; any bit shiftet out? if LSB > 1 then rAE is zero
BREQ _ceil_300 ; no!
SUBI rA0,0xFF ; else next bigger value
SBCI rA1,0xFF
SBCI rA2,0xFF
_ceil_300:
CLR rAE ; rT0 must not be cleared : rAE=0 no rounding anyway
RJMP _U(__fp_merge)
ENDFUNC
|
