1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
/* -*- Mode: Asm -*- */
/* Copyright (c) 2002 Michael Stumpf <mistumpf@de.pepperl-fuchs.com>
Copyright (c) 2005 Anatoly Sokolov <aesok@post.ru>
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are met:
* Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.
* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in
the documentation and/or other materials provided with the
distribution.
* Neither the name of the copyright holders nor the names of
contributors may be used to endorse or promote products derived
from this software without specific prior written permission.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
POSSIBILITY OF SUCH DAMAGE.
*/
/* $Id: fp_split.S,v 1.8.2.2 2006/09/29 20:35:42 joerg_wunsch Exp $ */
/*
fp_split.S is part of FPlib V 0.3.0 ported to avr-as
for details see readme.fplib
*----------------------------------------------------------------------------------------------
* split up in exponent : fraction : fraction extention
* x rA3 rA2:rA1:rA0: rAE
* y rB3 rB2:rB1:rB0: rBE
* signs are lost !
*
* if defined FPLIB_CHECK_FOR_NAN
* does not return to calling function in case of NaN !
* -> call fp_split before pushing locals to stack!!!
*
* split 2 incoming operands , x and y, y first
*/
#if !defined(__DOXYGEN__)
#include "gasava.inc"
#include "macros.inc"
#include "fplib.inc"
TEXT_SEG(fplib, __fp_split)
FUNCTION(__fp_split3)
GLOBAL(__fp_split3)
MOV rT0,rB3 ;
EOR rT0,rA3 ;
BST rT0,7 ; different signs : T = 1
GLOBAL(__fp_split2)
ADD rB2,rB2 ; MSB of exponent to carry
adc rB3,rB3 ; whole exponent in rB3, sign in C
CPI rB3,0xFF ; check for NAN
BREQ .L_fp_split_nan ; if no jump then C as hidden one is set
CLR rBE ; clear fraction extension
cp rBE,rB3 ; set C if nonzero exponent. -MM 2000-11-25
brcs 1f
ldi rB3,1 ; zero exponent really means 1 with hidden bit = 0
1:
ROR rB2 ; sets hidden bit
GLOBAL(__fp_split1)
ADD rA2,rA2 ; MSB of exponent to carry
adc rA3,rA3 ; whole exponent in rA3, sign in C
CPI rA3,0xFF ; if no jump then C as hidden one is set
BREQ .L_fp_split_nan
CLR rAE ; clear fraction extension
cp rAE,rA3 ; set C if nonzero exponent. -MM 2000-11-25
brcs 1f
ldi rA3,1 ; zero exponent really means 1 with hidden bit = 0
1:
ROR rA2 ; sets hidden bit
RET
.L_fp_split_nan:
#ifdef __AVR_3_BYTE_PC__
POP rA3
#endif
POP rA3
POP rA3 ; pop return adress
#ifdef __ERRNO__
LDI rA3,EDOM ; NaN is argument domain error !
#endif
clr r1
RJMP _U(__fp_nan)
ENDFUNC
/*
*----------------------------------------------------------------------------------------------
* split up in sign : exp : fraction : fraction extention
* x T : rA3 : rA2:rA1:rA0: rAE
*
* if defined FPLIB_CHECK_FOR_NAN
* does not return to calling function in case of NaN !
* -> call fp_split before pushing locals to stack!!!
*
*/
FUNCTION(__fp_split_a)
GLOBAL(__fp_split_a)
BST rA3, 7 ; T = sign
ADD rA2, rA2 ; MSB of exponent to carry
adc rA3, rA3 ; whole exponent in rA3, sign in C
CPI rA3, 0xFF ; if no jump then C as hidden one is set
BREQ .L_fp_split_a_nan
CLR rAE ; clear fraction extension
CP rAE, rA3 ; set C if nonzero exponent.
BRCS 1f
LDI rA3, 1 ; zero exponent really means 1 with hidden bit = 0
1:
ROR rA2 ; sets hidden bit
RET
.L_fp_split_a_nan:
#ifdef __AVR_3_BYTE_PC__
POP rA3
#endif
POP rA3
POP rA3 ; pop return adress
#ifdef __ERRNO__
LDI rA3, EDOM ; NaN is argument domain error !
#endif
CLR r1
RJMP _U(__fp_nan)
ENDFUNC
#endif /* not __DOXYGEN__ */
|
