1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
/* Copyright (c) 2002, 2007 Marek Michalkiewicz
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are met:
* Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.
* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in
the documentation and/or other materials provided with the
distribution.
* Neither the name of the copyright holders nor the names of
contributors may be used to endorse or promote products derived
from this software without specific prior written permission.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
POSSIBILITY OF SUCH DAMAGE. */
/* $Id: strncmp.S,v 1.7.2.1 2009/04/01 23:12:16 arcanum Exp $ */
/** \file */
/** \ingroup avr_string
\fn int strncmp(const char *s1, const char *s2, size_t len)
\brief Compare two strings.
The strncmp() function is similar to strcmp(), except it only compares the
first (at most) n characters of s1 and s2.
\returns The strncmp() function returns an integer less than, equal to, or
greater than zero if s1 (or the first n bytes thereof) is found,
respectively, to be less than, to match, or be greater than s2. */
#if !defined(__DOXYGEN__)
#include "macros.inc"
#define s1_hi r25
#define s1_lo r24
#define s2_hi r23
#define s2_lo r22
#define len_hi r21
#define len_lo r20
#define ret_hi r25
#define ret_lo r24
ASSEMBLY_CLIB_SECTION
.global _U(strncmp)
.type _U(strncmp), @function
_U(strncmp):
X_movw ZL, s2_lo
X_movw XL, s1_lo
.L_strncmp_loop:
subi len_lo, lo8(1)
sbci len_hi, hi8(1)
brcs .L_strncmp_equal
ld ret_lo, X+
ld __tmp_reg__, Z+
sub ret_lo, __tmp_reg__
brne .L_strncmp_done
tst __tmp_reg__
brne .L_strncmp_loop
.L_strncmp_equal:
sub ret_lo, ret_lo ; clear ret_lo and C flag
.L_strncmp_done:
; ret_hi = SREG.C ? 0xFF : 0
sbc ret_hi, ret_hi
ret
.L_strncmp_end:
.size _U(strncmp), .L_strncmp_end - _U(strncmp)
#endif /* not __DOXYGEN__ */
|
