File: pi.b

package info (click to toggle)
bc 1.06-15
  • links: PTS
  • area: main
  • in suites: sarge
  • size: 1,576 kB
  • ctags: 812
  • sloc: ansic: 8,585; yacc: 970; sh: 633; lex: 378; makefile: 141
file content (53 lines) | stat: -rw-r--r-- 1,188 bytes parent folder | download | duplicates (25)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
/*
   This is a program to determine the distribution of digits in the
   fraction part of PI.   It will look at the first scale digits.

   The results are left in the global variable digits.
   digits[0] is the number of 0's in PI.

   This program requires the math library.
*/

define pi () {
  auto ix, pi, save_scale, work;

  save_scale = scale;
  scale += 5;
  print "\n\nCalculating PI to ",scale," digits.  Please wait . . .";
  pi = 4*a(1);
  scale -= 5;
  work = pi;

  print "\nCounting digits. . .";
  for (ix = 0; ix < 10; ix++) digits[ix] = 0;

  /* Extract the One's digit from pi. */
  scale = 0;
  one_digit = work / 1;

  for (ix = save_scale; ix > 0; ix--) {

    /* Remove the One's digit and multiply by 10. */
    scale = ix;
    work = (work - one_digit) / 1 * 10;

    /* Extract the One's digit. */
    scale = 0;
    one_digit = work / 1;

    digits[one_digit] += 1;
  }

  /* Restore the scale. */
  scale = save_scale;

  /* Report. */
  print "\n\n"
  print "PI to ", scale, " digits is:\n", pi/1, "\n\n"
  print "The frequency of the digits are:\n"
  for (ix = 0; ix < 10; ix++) {
    print "    ", ix, " - ", digits[ix], " times\n"
  }

  print "\n\n"
}