File: gxx-include-dir.m4

package info (click to toggle)
binutils-avr 2.26.20160125%2BAtmel3.6.1-4
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 365,520 kB
  • sloc: ansic: 2,480,046; asm: 892,791; exp: 188,218; cpp: 133,829; makefile: 63,887; sh: 32,194; yacc: 26,783; lisp: 16,707; xml: 7,490; perl: 6,449; python: 4,555; ada: 4,318; pascal: 3,174; lex: 2,250; cs: 879; sed: 334; f90: 298; awk: 168; objc: 134; java: 73; fortran: 43
file content (32 lines) | stat: -rw-r--r-- 1,106 bytes parent folder | download | duplicates (102) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
dnl Usage: TL_AC_GXX_INCLUDE_DIR
dnl
dnl Set $gxx_include_dir to the location of the installed C++ include
dnl directory.  The value depends on $gcc_version and the configuration
dnl options --with-gxx-include-dir and --enable-version-specific-runtime-libs.
dnl
dnl If you change the default here, you'll need to change the gcc and
dnl libstdc++-v3 subdirectories too.
AC_DEFUN([TL_AC_GXX_INCLUDE_DIR],
[
case "${with_gxx_include_dir}" in
  yes)
    AC_MSG_ERROR([--with-gxx-include-dir=[[dir]] requires a directory])
    ;;
  no | "")
    case "${enable_version_specific_runtime_libs}" in
      yes) gxx_include_dir='$(libsubdir)/include/c++' ;;
      *)
	libstdcxx_incdir='c++/$(gcc_version)'
	gxx_include_dir='include/$(libstdcxx_incdir)'
	if test -n "$with_cross_host" && 
           test x"$with_cross_host" != x"no"; then	
          gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
        else
          gxx_include_dir='${prefix}/'"$gxx_include_dir"
        fi;;
    esac ;;
  *) gxx_include_dir=${with_gxx_include_dir} ;;
esac
AC_SUBST(gxx_include_dir)
AC_SUBST(libstdcxx_incdir)
])