File: targmatch.sed

package info (click to toggle)
binutils 2.44.50.20250528-1
  • links: PTS, VCS
  • area: main
  • in suites: experimental
  • size: 378,628 kB
  • sloc: ansic: 1,499,442; asm: 820,332; cpp: 216,228; exp: 78,603; makefile: 71,875; sh: 25,561; yacc: 15,066; lisp: 13,579; perl: 13,404; lex: 1,714; ada: 1,681; pascal: 1,446; python: 1,251; cs: 879; java: 478; sed: 191; xml: 95; awk: 25
file content (33 lines) | stat: -rw-r--r-- 526 bytes parent folder | download | duplicates (86) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
1,/START OF targmatch.h/	d
/END OF targmatch.h/,$		d
/^[ 	]*case/,/^[ 	]*esac/ d
s/^#if/KEEP #if/
s/^#endif/KEEP #endif/
s/^[ 	]*#.*$//
s/^KEEP #/#/
s/[ 	]*\\$//
t lab1
	:lab1
s/[| 	][| 	]*\([^|() 	][^|() 	]*\)[ 	]*|/{ "\1", NULL },/g
s/[| 	][| 	]*\([^|() 	][^|() 	]*\)[ 	]*)/{ "\1",/g
t lab2
s/^[ 	]*targ_defvec=\([^ 	]*\)/#if !defined (SELECT_VECS) || defined (HAVE_\1)/
t lab3
s/.*=.*//
s/;;//
b
	:lab2
H
d
	:lab3
G
s/\n/%EOL%/g
s/\(defined (HAVE_\)\([^)]*\)\(.*\)/\1\2\3\
\&\2 },\
#endif/
s/%EOL%/\
/g
p
s/.*//g
s/\n//g
h