1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95
|
TEMPLATE = app
TARGET = boats
CONFIG += qt \
warn_on
include(animation/animation.pri)
include(graphicsview/graphicsview.pri)
include(itemviews/itemviews.pri)
include(model/model.pri)
include(locale/locale.pri)
INCLUDEPATH += $$PWD
HEADERS += \
boatapplication.h \
boats.h \
commontypes.h \
mainwindow.h \
situationprint.h \
situationwidget.h \
trace.h \
undocommands.h \
xmlsituationreader.h \
xmlsituationwriter.h
SOURCES += \
boatapplication.cpp \
boats.cpp \
main.cpp \
mainwindow.cpp \
situationprint.cpp \
situationwidget.cpp \
trace.cpp \
undocommands.cpp \
xmlsituationreader.cpp \
xmlsituationwriter.cpp
unix_deploy:RESOURCES = boats_unix.qrc
else:RESOURCES = boats.qrc
mac {
QMAKE_LFLAGS += -static
QMAKE_INFO_PLIST = Info.plist
ICON = boats.icns
mime.path = boats.app/Contents/Resources
mime.files = xbs.icns
INSTALLS += mime
}
contains(GIF_EXPORT,1) {
DEFINES += GIF_EXPORT
HEADERS += gifwriter.h
SOURCES += gifwriter.cpp
LIBS += -lgif
}
unix_deploy {
isEmpty(PREFIX):PREFIX = /usr/local
target.path = $${PREFIX}/bin
INSTALLS += target
desktop.path = $${PREFIX}/share/applications
desktop.files = boats.desktop
INSTALLS += desktop
icons.path = $${PREFIX}/share/icons
icons.files = images/icons/*
INSTALLS += icons
mimetype.path = $${PREFIX}/share/mime
mimetype.files = boats.xml
INSTALLS += mimetype
TRANSLATEDIR = $${PREFIX}/share/boats
translations.path = $${TRANSLATEDIR}
translations.files = locale/boats_*.qm
INSTALLS += translations
}
else:TRANSLATEDIR = ":/locale"
DEFINES += TRANSLATEDIR=\\\"$${TRANSLATEDIR}\\\"
PRE_TARGETDEPS += compiler_updateqm_make_all
MOC_DIR = .moc/
OBJECTS_DIR = .obj/
QMAKE_CFLAGS_RELEASE += -fvisibility=hidden
QMAKE_CXXFLAGS_RELEASE += -fvisibility=hidden -fvisibility-inlines-hidden
win32:RC_FILE = boats.rc
win32:QMAKE_LFLAGS += -static
|