1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
|
cmake_minimum_required(VERSION 3.18)
project(ccache LANGUAGES C CXX ASM ASM_MASM)
if(MSVC)
enable_language(ASM_MASM)
else()
enable_language(ASM)
endif()
set(CMAKE_PROJECT_DESCRIPTION "a fast C/C++ compiler cache")
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED YES)
set(CMAKE_CXX_EXTENSIONS NO)
set(CMAKE_C_STANDARD 99)
set(CMAKE_C_STANDARD_REQUIRED YES)
set(CMAKE_C_EXTENSIONS NO)
# Always export compile_commands.json since it's useful for many tools.
set(CMAKE_EXPORT_COMPILE_COMMANDS TRUE)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
#
# Minimum compiler requirements (fail gracefully instead of producing cryptic
# C++ error messages)
#
if((CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.8)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 7.0))
message(
FATAL_ERROR
"The compiler you are using is too old, sorry.\n"
"You need one listed here: https://ccache.dev/platform-compiler-language-support.html")
endif()
if((CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4)
OR (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS 6))
message(
WARNING
"The compiler you are using is rather old.\n"
"If anything goes wrong you might be better off with one listed here:"
" https://ccache.dev/platform-compiler-language-support.html")
# Warnings from old compilers are probably useless anyway.
option(WARNINGS_AS_ERRORS "Treat compiler warnings as errors" FALSE)
endif()
#
# Settings
#
include(CcacheVersion)
if(NOT DEFINED CCACHE_DEV_MODE)
if("${CCACHE_VERSION_ORIGIN}" STREQUAL git OR DEFINED ENV{CI})
set(CCACHE_DEV_MODE ON)
else()
set(CCACHE_DEV_MODE OFF)
endif()
endif()
message(STATUS "Ccache dev mode: ${CCACHE_DEV_MODE}")
option(ENABLE_IPO "Enable interprocedural (link time, LTO) optimization" OFF)
if(ENABLE_IPO AND NOT MINGW)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION ON)
endif()
include(Utils)
include(CIBuildType)
include(DefaultBuildType)
include(UseFastestLinker)
include(StaticLinkSupport)
include(StandardSettings)
include(StandardWarnings)
include(EnableCcache)
#
# Configuration
#
option(REDIS_STORAGE_BACKEND "Enable Redis remote storage" ON)
option(HTTP_STORAGE_BACKEND "Enable HTTP remote storage" ON)
option(ENABLE_TESTING "Enable tests" ON)
include(InstallDirs)
include(GenerateConfigurationFile)
include(GenerateVersionFile)
include(Dependencies)
#
# Special flags
#
# Note: Cppcheck will scan everything after this point. zstd is above so it
# doesn't get scanned.
#
include(CodeAnalysis)
#
# Source code
#
add_subdirectory(src/third_party)
add_subdirectory(src/ccache)
# Win32 version library
if(WIN32)
add_library(ccache_win32_manifest OBJECT "${CMAKE_CURRENT_BINARY_DIR}/version.rc")
set_property(TARGET ccache_win32_manifest PROPERTY INCLUDE_DIRECTORIES "")
endif()
#
# ccache executable
#
add_executable(ccache src/ccache/main.cpp)
target_link_libraries(ccache PRIVATE standard_settings standard_warnings ccache_framework)
if(WIN32)
if(MSVC)
target_link_options(ccache PUBLIC "/MANIFEST:NO")
endif()
target_link_libraries(ccache PRIVATE ccache_win32_manifest)
endif()
#
# Documentation
#
option(ENABLE_DOCUMENTATION "Enable documentation" ON)
if(ENABLE_DOCUMENTATION)
add_subdirectory(doc)
endif()
#
# Installation
#
install(TARGETS ccache DESTINATION ${CMAKE_INSTALL_BINDIR})
#
# Packaging
#
include(CcachePackConfig)
#
# Tests
#
if(ENABLE_TESTING)
enable_testing()
add_subdirectory(unittest)
add_subdirectory(test)
list(APPEND CMAKE_CTEST_ARGUMENTS "--output-on-failure")
# Add "check" target which compiles and runs tests.
set(
check_command
${CMAKE_CTEST_COMMAND} --force-new-ctest-process --output-on-failure)
if(CMAKE_CONFIGURATION_TYPES)
list(APPEND check_command --build-config "$<CONFIGURATION>")
endif()
add_custom_target(
check
COMMAND ${check_command}
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
DEPENDS ccache unittest)
endif()
#
# Special formatting targets
#
add_custom_target(
format
COMMAND misc/format-files --all
COMMENT "Formatting code"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
add_custom_target(
check_format
COMMAND misc/format-files --all --check
COMMENT "Checking code formatting"
USES_TERMINAL
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
#
# Configuration summary
#
message(STATUS)
message(STATUS "Configuration summary:")
message(STATUS " Storage backends:")
message(STATUS " file ON")
message(STATUS " http ${HTTP_STORAGE_BACKEND}")
message(STATUS " redis ${REDIS_STORAGE_BACKEND}")
message(STATUS " Dependencies:")
print_dependency_summary(" ")
message(STATUS)
|
