File: Findsnappy.cmake

package info (click to toggle)
ceph 18.2.8%2Bds-1
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid
  • size: 1,186,356 kB
  • sloc: cpp: 6,282,106; ansic: 3,507,390; python: 375,284; asm: 216,381; java: 133,450; sh: 125,595; xml: 39,398; ruby: 32,026; makefile: 29,004; javascript: 23,994; cs: 18,980; perl: 9,709; sql: 7,833; lisp: 5,920; pascal: 3,109; ada: 1,681; yacc: 478; awk: 188; f90: 55; php: 1
file content (38 lines) | stat: -rw-r--r-- 1,025 bytes parent folder | download | duplicates (4) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
# - Find Snappy
# Find the snappy compression library and includes
#
# SNAPPY_INCLUDE_DIR - where to find snappy.h, etc.
# SNAPPY_LIBRARIES - List of libraries when using snappy.
# SNAPPY_FOUND - True if snappy found.

find_package(PkgConfig QUIET REQUIRED)
pkg_search_module(PC_snappy
  snappy QUIET)

find_path(SNAPPY_INCLUDE_DIR
  NAMES snappy.h
  HINTS
    ${PC_snappy_INCLUDE_DIRS}
    ${SNAPPY_ROOT_DIR}/include)

find_library(SNAPPY_LIBRARIES
  NAMES snappy
  HINTS
    ${PC_snappy_LIBRARY_DIRS}
    ${SNAPPY_ROOT_DIR}/lib)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(snappy
  DEFAULT_MSG SNAPPY_LIBRARIES SNAPPY_INCLUDE_DIR)

mark_as_advanced(
  SNAPPY_LIBRARIES
  SNAPPY_INCLUDE_DIR)

if(snappy_FOUND AND NOT (TARGET snappy::snappy))
  add_library(snappy::snappy UNKNOWN IMPORTED)
  set_target_properties(snappy::snappy PROPERTIES
    INTERFACE_INCLUDE_DIRECTORIES "${SNAPPY_INCLUDE_DIR}"
    IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
    IMPORTED_LOCATION "${SNAPPY_LIBRARIES}")
endif()