1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
#.rst:
# CGAL_SetupGMP
# -------------
#
# The module searches for the `GMP` and `MPFR` headers and libraries,
# by calling
#
# .. code-block:: cmake
#
# find_package(GMP)
# find_package(MPFR)
#
# and defines the function :command:`use_CGAL_GMP_support`.
if(CGAL_SetupGMP_included OR CGAL_DISABLE_GMP)
return()
endif()
set(CGAL_SetupGMP_included TRUE)
# Locally setting of CMAKE_MODULE_PATH, not exported to parent scope.
# That is required to find the FindGMP and FindMPFR modules.
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CGAL_MODULES_DIR})
find_package(GMP QUIET)
find_package(MPFR QUIET)
if (GMP_FOUND)
find_package(GMPXX QUIET)
endif()
if(NOT GMP_FOUND OR NOT MPFR_FOUND)
message(STATUS "GMP not found.")
set(CGAL_DISABLE_GMP ON)
return()
endif()
if(NOT GMPXX_FOUND)
option(CGAL_WITH_GMPXX "Use CGAL with GMPXX: use C++ classes of GNU MP instead of CGAL wrappers" OFF)
else()
option(CGAL_WITH_GMPXX "Use CGAL with GMPXX: use C++ classes of GNU MP instead of CGAL wrappers" ON)
endif()
#.rst:
# Provided Functions
# ^^^^^^^^^^^^^^^^^^
#
# .. command:: use_CGAL_GMP_support
#
# Link the target with the `GMP` and `MPFR` libraries::
#
# use_CGAL_GMP_support( target [INTERFACE] )
#
# If the option ``INTERFACE`` is passed, the dependencies are
# added using :command:`target_link_libraries` with the ``INTERFACE``
# keyword, or ``PUBLIC`` otherwise.
function(use_CGAL_GMP_support target)
if(NOT GMP_FOUND OR NOT MPFR_FOUND)
message(FATAL_ERROR "CGAL requires GMP and MPFR.")
return()
endif()
if(NOT GMP_INCLUDE_DIR STREQUAL "${CGAL_INSTALLATION_PACKAGE_DIR}/auxiliary/gmp/include")
target_include_directories(${target} SYSTEM INTERFACE ${GMP_INCLUDE_DIR})
else()
target_include_directories(${target} SYSTEM INTERFACE
$<BUILD_INTERFACE:${GMP_INCLUDE_DIR}>
$<INSTALL_INTERFACE:include>)
endif()
if(NOT MPFR_INCLUDE_DIR STREQUAL "${CGAL_INSTALLATION_PACKAGE_DIR}/auxiliary/gmp/include")
target_include_directories(${target} SYSTEM INTERFACE ${MPFR_INCLUDE_DIR})
else()
target_include_directories(${target} SYSTEM INTERFACE
$<BUILD_INTERFACE:${MPFR_INCLUDE_DIR}>
$<INSTALL_INTERFACE:include>)
endif()
if(WITH_GMPXX OR CGAL_WITH_GMPXX)
target_include_directories(${target} SYSTEM INTERFACE ${GMPXX_INCLUDE_DIR})
target_link_libraries(${target} INTERFACE ${GMPXX_LIBRARIES})
target_compile_definitions(${target} INTERFACE CGAL_USE_GMPXX=1)
endif()
target_link_libraries(${target} INTERFACE ${MPFR_LIBRARIES} ${GMP_LIBRARIES})
endfunction()
|
