1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
|
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//third_party/WebKit/Source/config.gni")
# All paths in this file should be absolute so targets in any directory can use
# them without worrying about the current directory.
_scripts_dir = "//third_party/WebKit/Source/build/scripts"
scripts_for_in_files = [
# jinja2/__init__.py contains version string, so sufficient as
# dependency for whole jinja2 package
"//third_party/jinja2/__init__.py",
"//third_party/markupsafe/__init__.py", # jinja2 dep
"$_scripts_dir/hasher.py",
"$_scripts_dir/in_file.py",
"$_scripts_dir/in_generator.py",
"$_scripts_dir/license.py",
"$_scripts_dir/name_macros.py",
"$_scripts_dir/name_utilities.py",
"$_scripts_dir/template_expander.py",
"$_scripts_dir/templates/macros.tmpl",
]
make_event_factory_files = scripts_for_in_files + [
"$_scripts_dir/make_event_factory.py",
"$_scripts_dir/templates/EventFactory.cpp.tmpl",
]
make_names_files = scripts_for_in_files + [
"$_scripts_dir/make_names.py",
"$_scripts_dir/templates/MakeNames.cpp.tmpl",
"$_scripts_dir/templates/MakeNames.h.tmpl",
]
make_qualified_names_files = scripts_for_in_files + [
"$_scripts_dir/make_qualified_names.py",
"$_scripts_dir/templates/MakeQualifiedNames.cpp.tmpl",
"$_scripts_dir/templates/MakeQualifiedNames.h.tmpl",
]
make_element_factory_files = make_qualified_names_files + [
"$_scripts_dir/make_element_factory.py",
"$_scripts_dir/templates/ElementFactory.cpp.tmpl",
"$_scripts_dir/templates/ElementFactory.h.tmpl",
"$_scripts_dir/templates/ElementWrapperFactory.cpp.tmpl",
"$_scripts_dir/templates/ElementWrapperFactory.h.tmpl",
]
make_element_type_helpers_files = make_qualified_names_files + [
"$_scripts_dir/make_element_type_helpers.py",
"$_scripts_dir/templates/ElementTypeHelpers.h.tmpl",
]
# The executables are relative to the build directory. Don't rebase it because
# on Posix we want to run the system one on the path.
if (is_win) {
perl_exe = rebase_path("//third_party/perl/perl/bin/perl.exe", root_build_dir)
gperf_exe = rebase_path("//third_party/gperf/bin/gperf.exe", root_build_dir)
bison_exe = rebase_path("//third_party/bison/bin/bison.exe", root_build_dir)
# Using cl instead of cygwin gcc cuts the processing time from
# 1m58s to 0m52s.
preprocessor = "--preprocessor \"cl.exe -nologo -EP -TP\""
} else {
perl_exe = "perl"
gperf_exe = "gperf"
bison_exe = "bison"
# We specify a preprocess so it happens locally and won't get
# distributed to goma.
# FIXME: /usr/bin/gcc won't exist on OSX forever. We want to
# use /usr/bin/clang once we require Xcode 4.x.
preprocessor = "--preprocessor \"/usr/bin/gcc -E -P -x c++\""
}
# Templates --------------------------------------------------------------------
_blink_gen_dir = "$root_gen_dir/blink"
# The GYP target make_core_generated has some deps and a bunch of actions on
# it, which means that the deps will be resolved before the actions run. Here
# we have separate targets for each action. Its not clear which actions depend
# on these deps, so for GYP compatibility, all of the below actions should
# depend on the following deps.
make_core_generated_deps = [
"//third_party/WebKit/Source/core:generated_testing_idls",
"//third_party/WebKit/Source/core:core_event_interfaces",
]
# Template to run most of scripts that process "*.in" files.
# script: script to run.
# in_files: ".in" files to pass to the script
# other_inputs: (optional) other input files the script depends on
# defaults to "scripts_for_in_files" (if specified, we assume
# that the contents of "scripts_for_in_files" are included in
# this list specified since this is how these lists are filled
# from the GYP build.
# outputs: expected results. Note that the directory of the 0th item in this
# list will be taken to be the output path.
# other_args: (optional) other arguements to pass to the script.
template("process_in_files") {
action(target_name) {
script = invoker.script
source_prereqs = invoker.in_files
if (defined(invoker.other_inputs)) {
source_prereqs += invoker.other_inputs
} else {
source_prereqs += scripts_for_in_files
}
outputs = invoker.outputs
# Extract the directory to write files to.
output_dir = get_path_info(outputs[0], "dir")
args = rebase_path(invoker.in_files, root_build_dir) + [
"--output_dir", rebase_path(output_dir, root_build_dir),
]
if (defined(invoker.other_args)) {
args += invoker.other_args
}
deps = make_core_generated_deps
}
}
# Template to run the make_names script. This is a special case of
# process_in_files.
# in_files: files to pass to the script
# outputs: expected results
template("make_names") {
process_in_files(target_name) {
script = "//third_party/WebKit/Source/build/scripts/make_names.py"
in_files = invoker.in_files
other_inputs = make_names_files
outputs = invoker.outputs
other_args = [ "--defines", feature_defines_string ]
}
}
# Template to run the make_qualified_names script. This is a special case of
# process_in_files.
# in_files: list of ".in" files to process.
# outputs: list of output files
template("make_qualified_names") {
process_in_files(target_name) {
script = "//third_party/WebKit/Source/build/scripts/make_qualified_names.py"
in_files = invoker.in_files
other_inputs = make_qualified_names_files
outputs = invoker.outputs
other_args = [ "--defines", feature_defines_string ]
}
}
# Calls the make_event_factory script. This is a special case of
# process_in_files.
# in_files: list of ".in" files to process.
# outputs: list of output files
template("make_event_factory") {
process_in_files(target_name) {
script = "//third_party/WebKit/Source/build/scripts/make_event_factory.py"
in_files = invoker.in_files
other_inputs = make_event_factory_files
outputs = invoker.outputs
}
}
# Calls the make_token_matcher script.
# input_file: The "*-in.cpp" file
# output_file: The output file
template("make_token_matcher") {
action(target_name) {
script = "//third_party/WebKit/Source/build/scripts/make_token_matcher.py"
source_prereqs = scripts_for_in_files + [ invoker.input_file ]
outputs = [ invoker.output_file ]
args = [
rebase_path(invoker.input_file, root_build_dir),
rebase_path(invoker.output_file, root_build_dir),
]
deps = make_core_generated_deps
}
}
|
