File: generate_allowlist_from_histograms_file.gni

package info (click to toggle)
chromium 138.0.7204.157-1
  • links: PTS, VCS
  • area: main
  • in suites: sid, trixie
  • size: 6,071,864 kB
  • sloc: cpp: 34,936,859; ansic: 7,176,967; javascript: 4,110,704; python: 1,419,953; asm: 946,768; xml: 739,967; pascal: 187,324; sh: 89,623; perl: 88,663; objc: 79,944; sql: 50,304; cs: 41,786; fortran: 24,137; makefile: 21,806; php: 13,980; tcl: 13,166; yacc: 8,925; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (43 lines) | stat: -rw-r--r-- 1,587 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Copyright 2023 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Generates a C++ header file that contains a list of values under a specific variant
# or enum. The list can be used for ensuring that values in C++ are in sync with the
# histogram file. The header file provides a function to check if a value in is the list.
#
# Parameters:
#   input_xml_file: Input file that contains the allow list. This should be a
#     .xml file under path //tools/metrics/histograms/ or its subfolders.
#
#   namespace:
#     C++ namespace in which the generated code should be scoped.
#
#   tag:
#     XML tag that contains the values. Should be either "variant" or "enum".
#
#   allow_list_name:
#     Name of the variant or enum list in the histogram file.
#
#   output_file:
#     Name of the generated file to be used for checking if a value exists in the list.
#
template("generate_allowlist_from_histograms_file") {
  action(target_name) {
    output_file = "$target_gen_dir/" + invoker.output_file

    script =
        "//tools/metrics/histograms/generate_allowlist_from_histograms_file.py"
    outputs = [ output_file ]
    sources = [ invoker.input_xml_file ]

    args = [
      "--allow_list_name=" + invoker.allow_list_name,
      "--namespace=" + invoker.namespace,
      "--tag=" + invoker.tag,
      "--output_dir=" + rebase_path(root_gen_dir, root_build_dir),
      "--file=" + rebase_path(output_file, root_gen_dir),
      "--input=" + rebase_path(invoker.input_xml_file, root_build_dir),
    ]
  }
}