File: BUILD.gn

package info (click to toggle)
chromium 138.0.7204.183-1~deb12u1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm-proposed-updates
  • size: 6,080,960 kB
  • sloc: cpp: 34,937,079; ansic: 7,176,967; javascript: 4,110,704; python: 1,419,954; asm: 946,768; xml: 739,971; pascal: 187,324; sh: 89,623; perl: 88,663; objc: 79,944; sql: 50,304; cs: 41,786; fortran: 24,137; makefile: 21,811; php: 13,980; tcl: 13,166; yacc: 8,925; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (65 lines) | stat: -rw-r--r-- 1,340 bytes parent folder | download | duplicates (4) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
 
# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")
import("//build/config/ui.gni")

static_library("common") {
  public = [
    "cached_signal.h",
    "common_types.h",
    "platform_utils.h",
    "signals_constants.h",
  ]

  sources = [
    "common_types.cc",
    "platform_utils.cc",
    "signals_constants.cc",
  ]

  public_deps = [ "//third_party/abseil-cpp:absl" ]

  deps = [
    "//base",
    "//components/policy/core/common",
  ]

  if (is_win) {
    sources += [ "win/platform_utils_win.cc" ]
    libs = [
      "propsys.lib",
      "secur32.lib",
    ]
  }

  if (is_mac || is_linux) {
    sources += [ "posix/platform_utils_posix.cc" ]
  }

  if (is_mac) {
    sources += [ "mac/platform_utils_mac.mm" ]
  }

  if (is_linux) {
    if (use_glib) {
      deps += [ "//ui/base/glib" ]
    }
    sources += [ "linux/platform_utils_linux.cc" ]
  }

  # platform_utils_linux uses a "defined(USE_GIO)" macro, so if it's refactored
  # away from this file make sure gio_config is still added to configs.
  if (use_gio) {
    configs += [ "//build/linux:gio_config" ]
  }
}

source_set("features") {
  public = [ "signals_features.h" ]

  sources = [ "signals_features.cc" ]

  public_deps = [ "//base" ]
}