File: wayland_protocol_codegen.gni

package info (click to toggle)
chromium 138.0.7204.183-1~deb12u1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm-proposed-updates
  • size: 6,080,960 kB
  • sloc: cpp: 34,937,079; ansic: 7,176,967; javascript: 4,110,704; python: 1,419,954; asm: 946,768; xml: 739,971; pascal: 187,324; sh: 89,623; perl: 88,663; objc: 79,944; sql: 50,304; cs: 41,786; fortran: 24,137; makefile: 21,811; php: 13,980; tcl: 13,166; yacc: 8,925; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (49 lines) | stat: -rw-r--r-- 1,686 bytes parent folder | download | duplicates (8) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
template("wayland_protocol_codegen") {
  assert(defined(invoker.template),
         "Need template for for wayland_protocol_codegen")
  assert(defined(invoker.sources),
         "Need sources for for wayland_protocol_codegen")
  assert(defined(invoker.output_pattern),
         "Need output_pattern for for wayland_protocol_codegen")

  # If the invoker sets "reduce=true", we are generating a single output from
  # all the source protocols.
  if (defined(invoker.reduce) && invoker.reduce) {
    action = "action"
  } else {
    action = "action_foreach"
  }

  target(action, target_name) {
    forward_variables_from(invoker,
                           [
                             "data",
                             "data_deps",
                             "depfile",
                             "deps",
                             "metadata",
                             "pool",
                             "response_file_contents",
                             "sources",
                             "testonly",
                           ])

    script = "//components/exo/wayland/compatibility_test/wayland_protocol_codegen.py"
    inputs = [ invoker.template ]
    outputs = [ invoker.output_pattern ]

    clang_format_path = "//third_party/depot_tools/clang-format"

    args = [
      rebase_path("//third_party", root_build_dir),
      rebase_path(clang_format_path, root_build_dir),
      rebase_path(invoker.template, root_build_dir),
      rebase_path(invoker.output_pattern, root_build_dir),
    ]
    if (defined(invoker.reduce) && invoker.reduce) {
      args += rebase_path(sources, root_build_dir)
    } else {
      args += [ "{{source}}" ]
    }
  }
}