File: BUILD.gn

package info (click to toggle)
chromium 138.0.7204.183-1~deb12u1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm-proposed-updates
  • size: 6,080,960 kB
  • sloc: cpp: 34,937,079; ansic: 7,176,967; javascript: 4,110,704; python: 1,419,954; asm: 946,768; xml: 739,971; pascal: 187,324; sh: 89,623; perl: 88,663; objc: 79,944; sql: 50,304; cs: 41,786; fortran: 24,137; makefile: 21,811; php: 13,980; tcl: 13,166; yacc: 8,925; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (67 lines) | stat: -rw-r--r-- 1,236 bytes parent folder | download | duplicates (6) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
 
# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

component("wifi") {
  sources = [
    "network_properties.cc",
    "network_properties.h",
    "wifi_export.h",
    "wifi_service.cc",
    "wifi_service.h",
  ]

  defines = [ "WIFI_IMPLEMENTATION" ]

  deps = [
    "//base",
    "//components/onc",
    "//crypto",
  ]

  if (is_win) {
    sources += [ "wifi_service_win.cc" ]
    libs = [ "iphlpapi.lib" ]
    deps += [
      "//third_party/libxml:xml_reader",  # Safe, data come from system.
      "//third_party/libxml:xml_writer",
    ]
  }

  if (is_mac) {
    sources += [ "wifi_service_mac.mm" ]
    frameworks = [
      "CoreWLAN.framework",
      "Foundation.framework",
      "SystemConfiguration.framework",
    ]
  }

  if (is_fuchsia) {
    sources += [ "wifi_service_fuchsia.cc" ]
  }
}

static_library("test_support") {
  sources = [
    "fake_wifi_service.cc",
    "fake_wifi_service.h",
  ]

  deps = [
    ":wifi",
    "//base",
    "//components/onc",
  ]
}

executable("wifi_test") {
  sources = [ "wifi_test.cc" ]

  deps = [
    ":wifi",
    "//base",
    "//build/win:default_exe_manifest",
    "//components/onc",
  ]
}