File: BUILD.gn

package info (click to toggle)
chromium 139.0.7258.127-1
  • links: PTS, VCS
  • area: main
  • in suites:
  • size: 6,122,068 kB
  • sloc: cpp: 35,100,771; ansic: 7,163,530; javascript: 4,103,002; python: 1,436,920; asm: 946,517; xml: 746,709; pascal: 187,653; perl: 88,691; sh: 88,436; objc: 79,953; sql: 51,488; cs: 44,583; fortran: 24,137; makefile: 22,147; tcl: 15,277; php: 13,980; yacc: 8,984; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (55 lines) | stat: -rw-r--r-- 1,867 bytes parent folder | download | duplicates (5)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//third_party/protobuf/proto_library.gni")

assert(is_chromeos)

device_policy_remover_path = "$target_gen_dir/device_policy_remover.cc"

action("device_policy_remover_generate") {
  script = "generate_device_policy_remover.py"
  descriptor_pool_path = "//third_party/protobuf/python"

  # This is provided by //components/policy/proto listed in public_deps.
  # The containing directory is in a separate variable because that's what
  # the script expects as an argument.
  chrome_device_policy_pb2_dir = "$root_out_dir/pyproto/components/policy/proto"
  chrome_device_policy_pb2_path =
      "$chrome_device_policy_pb2_dir/chrome_device_policy_pb2.py"

  sources = [
    # It's important to explicitly list which files provided by this action's
    # dependencies are actually used by this action, because the action is not
    # automatically re-run on changes in one of the public_deps. See
    # https://crbug.com/933359 for more information.
    chrome_device_policy_pb2_path,
  ]

  outputs = [ device_policy_remover_path ]

  args = [
    # generated file name
    rebase_path(device_policy_remover_path, root_build_dir),

    # directories for PATH variable to compile generated file
    rebase_path(descriptor_pool_path, root_build_dir),
    rebase_path(proto_python_root, root_build_dir),
    rebase_path(chrome_device_policy_pb2_dir, root_build_dir),
  ]

  deps = [
    "//components/policy/proto:proto_internal_gen",
    "//third_party/protobuf:py_proto",
  ]
}

static_library("device_policy_remover_generated") {
  sources = [ device_policy_remover_path ]
  deps = [
    ":device_policy_remover_generate",
    "//third_party/protobuf:protobuf_lite",
  ]
}