1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 2015 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//tools/json_to_struct/json_to_struct.gni")
action("field_trial_testing_config_action") {
visibility = [ ":field_trial_config" ]
script = "//tools/variations/fieldtrial_to_struct.py"
source = "//testing/variations/fieldtrial_testing_config.json"
inputs = JSON_TO_STRUCT_FILES + [ source ]
out_name = "fieldtrial_testing_config"
outputs = [
"$target_gen_dir/$out_name.cc",
"$target_gen_dir/$out_name.h",
]
if (current_os == "win") {
platform = "windows"
} else {
platform = current_os
}
args = [
rebase_path(source, root_build_dir),
"--destbase=" + rebase_path(target_gen_dir, root_build_dir),
"--namespace=variations",
"--schema=" +
rebase_path("field_trial_testing_config_schema.json", root_build_dir),
"--platform=" + platform,
"--output=$out_name",
]
# At build-time, Android Chrome and WebView/WebLayer use the platform
# "android", but at run-time, variations has separate platforms "android",
# "android_webview" and "android_weblayer". So if building "android", also
# include WebView/WebLayer.
if (platform == "android") {
args += [
# TODO(peilinwang) investigate impact on test runtime, then enable the
# generation of the java fieldtrial testing config to be used when native
# isn't loaded.
# "--java",
"--platform=android_weblayer",
"--platform=android_webview",
]
}
}
static_library("field_trial_config") {
sources = [
"field_trial_util.cc",
"field_trial_util.h",
]
sources += get_target_outputs(":field_trial_testing_config_action")
deps = [
":field_trial_testing_config_action",
"//base",
"//components/variations",
"//components/variations/proto",
"//net",
]
public_deps = [ "//third_party/protobuf:protobuf_lite" ]
}
source_set("unit_tests") {
testonly = true
sources = [ "field_trial_util_unittest.cc" ]
deps = [
":field_trial_config",
"//base",
"//base/test:test_support",
"//components/variations",
"//components/variations/service",
"//components/version_info",
"//services/network/public/cpp",
"//testing/gtest",
]
}
|
