File: generate_grd.gni

package info (click to toggle)
chromium 139.0.7258.127-1
  • links: PTS, VCS
  • area: main
  • in suites:
  • size: 6,122,068 kB
  • sloc: cpp: 35,100,771; ansic: 7,163,530; javascript: 4,103,002; python: 1,436,920; asm: 946,517; xml: 746,709; pascal: 187,653; perl: 88,691; sh: 88,436; objc: 79,953; sql: 51,488; cs: 44,583; fortran: 24,137; makefile: 22,147; tcl: 15,277; php: 13,980; yacc: 8,984; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (73 lines) | stat: -rw-r--r-- 2,145 bytes parent folder | download | duplicates (11)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

template("generate_grd") {
  action(target_name) {
    script = "//ui/webui/resources/tools/generate_grd.py"

    forward_variables_from(invoker,
                           [
                             "deps",
                             "public_deps",
                             "testonly",
                             "visibility",
                           ])

    inputs = []
    outputs = [ invoker.out_grd ]

    grd_extension = get_path_info(invoker.out_grd, "extension")
    assert(grd_extension == "grd" || grd_extension == "grdp",
           "Invalid extension '${grd_extension}' found. Must use grd or grdp")

    args = [
      "--out-grd",
      rebase_path(invoker.out_grd, root_build_dir),
      "--grd-prefix",
      invoker.grd_prefix,
      "--root-gen-dir",
      rebase_path(root_gen_dir, root_build_dir),
    ]

    if (defined(invoker.manifest_files)) {
      inputs += invoker.manifest_files
      args += [ "--manifest-files" ] +
              rebase_path(invoker.manifest_files, root_build_dir)
    }

    if (defined(invoker.grdp_files)) {
      extension = get_path_info(invoker.out_grd, "extension")
      assert(extension == "grd", "grdp files can't be nested.")

      inputs += invoker.grdp_files
      args +=
          [ "--grdp-files" ] + rebase_path(invoker.grdp_files, root_build_dir)
    }

    if (defined(invoker.input_files)) {
      args += [
                "--input-files-base-dir",
                invoker.input_files_base_dir,
                "--input-files",
              ] + invoker.input_files
    }

    if (defined(invoker.output_files_base_dir)) {
      args += [
        "--output-files-base-dir",
        invoker.output_files_base_dir,
      ]
    }

    if (defined(invoker.resource_path_rewrites)) {
      args += [ "--resource-path-rewrites" ] + invoker.resource_path_rewrites
    }
    if (defined(invoker.resource_path_prefix)) {
      args += [
        "--resource-path-prefix",
        invoker.resource_path_prefix,
      ]
    }
  }
}