File: BUILD.gn

package info (click to toggle)
chromium 139.0.7258.127-1
  • links: PTS, VCS
  • area: main
  • in suites:
  • size: 6,122,068 kB
  • sloc: cpp: 35,100,771; ansic: 7,163,530; javascript: 4,103,002; python: 1,436,920; asm: 946,517; xml: 746,709; pascal: 187,653; perl: 88,691; sh: 88,436; objc: 79,953; sql: 51,488; cs: 44,583; fortran: 24,137; makefile: 22,147; tcl: 15,277; php: 13,980; yacc: 8,984; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (122 lines) | stat: -rw-r--r-- 3,151 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
# Copyright 2019 the V8 project authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("../../gni/snapshot_toolchain.gni")
import("../../gni/v8.gni")

config("internal_config") {
  visibility = [ ":*" ]  # Only targets in this file can depend on this.

  if (is_component_build) {
    defines = [ "BUILDING_V8_DEBUG_HELPER" ]
  }

  configs = [ "../..:v8_tracing_config" ]

  include_dirs = [
    ".",
    "../..",
    "$target_gen_dir",
    "$target_gen_dir/../..",
  ]
}

# This config should be applied to code using v8_debug_helper.
config("external_config") {
  if (is_component_build) {
    defines = [ "USING_V8_DEBUG_HELPER" ]
  }

  configs = [ "../..:external_config" ]

  include_dirs = [ "." ]
}

action("run_mkgrokdump") {
  testonly = true
  visibility = [ ":*" ]

  deps = [
    "../..:run_mksnapshot_default",
    "../../test/mkgrokdump:mkgrokdump($v8_generator_toolchain)",
  ]

  script = "../run.py"

  outputs = [ "$target_gen_dir/v8heapconst.py" ]

  args = [
    "./" + rebase_path(
            get_label_info(
                    "../../test/mkgrokdump:mkgrokdump($v8_generator_toolchain)",
                    "root_out_dir") + "/mkgrokdump",
            root_build_dir),
    "--outfile",
    rebase_path("$target_gen_dir/v8heapconst.py", root_build_dir),
  ]
}

action("gen_heap_constants") {
  testonly = true
  visibility = [ ":*" ]
  deps = [ ":run_mkgrokdump" ]
  script = "gen-heap-constants.py"
  outputs = [ "$target_gen_dir/heap-constants-gen.cc" ]
  args = [
    rebase_path(target_gen_dir, root_build_dir),
    rebase_path("$target_gen_dir/heap-constants-gen.cc", root_build_dir),
  ]
}

v8_component("v8_debug_helper_internal") {
  testonly = true

  public = [ "debug-helper.h" ]

  sources = [
    "$target_gen_dir/../../torque-generated/class-debug-readers.cc",
    "$target_gen_dir/../../torque-generated/class-debug-readers.h",
    "$target_gen_dir/../../torque-generated/debug-macros.cc",
    "$target_gen_dir/../../torque-generated/debug-macros.h",
    "$target_gen_dir/../../torque-generated/instance-types.h",
    "$target_gen_dir/heap-constants-gen.cc",
    "../../src/common/ptr-compr.cc",
    "compiler-types.cc",
    "debug-helper-internal.cc",
    "debug-helper-internal.h",
    "debug-helper.h",
    "get-object-properties.cc",
    "heap-constants.cc",
    "heap-constants.h",
  ]

  deps = [
    ":gen_heap_constants",
    "../..:generate_bytecode_builtins_list",
    "../..:run_torque",
    "../..:v8_abseil",
    "../..:v8_headers",
    "../..:v8_internal_headers",
    "../..:v8_libbase",
    "../..:v8_shared_internal_headers",
    "../..:v8_tracing",
  ]
  if (v8_enable_temporal_support) {
    deps += [ "//third_party/rust/temporal_capi" ]
  }

  configs = [ ":internal_config" ]
  if (v8_enable_i18n_support) {
    configs += [ "$v8_icu_path:icu_config" ]
  }

  remove_configs = [ "//build/config/compiler:no_rtti" ]
  configs += [ "//build/config/compiler:rtti" ]
}

group("v8_debug_helper") {
  testonly = true
  public_deps = [ ":v8_debug_helper_internal" ]
  public_configs = [ ":external_config" ]
}