File: grpc_library.gni

package info (click to toggle)
chromium 139.0.7258.127-2
  • links: PTS, VCS
  • area: main
  • in suites: forky
  • size: 6,122,156 kB
  • sloc: cpp: 35,100,771; ansic: 7,163,530; javascript: 4,103,002; python: 1,436,920; asm: 946,517; xml: 746,709; pascal: 187,653; perl: 88,691; sh: 88,436; objc: 79,953; sql: 51,488; cs: 44,583; fortran: 24,137; makefile: 22,147; tcl: 15,277; php: 13,980; yacc: 8,984; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (52 lines) | stat: -rw-r--r-- 1,529 bytes parent folder | download | duplicates (10) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
# Copyright 2019 Google Inc. All Rights Reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Compile a grpc service.
#
# Example:
#  grpc_library("mylib") {
#    sources = [
#      "foo.proto",
#    ]
#  }

import("//build/config/sanitizers/sanitizers.gni")
import("//third_party/protobuf/proto_library.gni")

template("grpc_library") {
  assert(defined(invoker.sources), "Need sources for proto_library")
  proto_library(target_name) {
    forward_variables_from(invoker,
                           [
                             "cc_include",
                             "extra_configs",
                             "generate_python",
                             "import_dirs",
                             "link_deps",
                             "proto_in_dir",
                             "proto_out_dir",
                             "sources",
                             "testonly",
                             "visibility",
                             "deps",
                             "proto_deps",
                           ])

    if (defined(invoker.use_protobuf_full)) {
      use_protobuf_full = invoker.use_protobuf_full
    } else {
      cc_generator_options = "lite"
    }

    if (!defined(extra_configs)) {
      extra_configs = []
    }
    extra_configs += [ "//third_party/grpc:grpc_config" ]

    generate_cc = true

    generator_plugin_label = "//third_party/grpc:grpc_cpp_plugin"
    generator_plugin_suffix = ".grpc.pb"
  }
}