File: pa_func_snprintf.m4

package info (click to toggle)
chromium 139.0.7258.127-2
  • links: PTS, VCS
  • area: main
  • in suites: forky
  • size: 6,122,156 kB
  • sloc: cpp: 35,100,771; ansic: 7,163,530; javascript: 4,103,002; python: 1,436,920; asm: 946,517; xml: 746,709; pascal: 187,653; perl: 88,691; sh: 88,436; objc: 79,953; sql: 51,488; cs: 44,583; fortran: 24,137; makefile: 22,147; tcl: 15,277; php: 13,980; yacc: 8,984; ruby: 7,485; awk: 3,720; lisp: 3,096; lex: 1,327; ada: 727; jsp: 228; sed: 36
file content (39 lines) | stat: -rw-r--r-- 1,266 bytes parent folder | download | duplicates (19) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
dnl --------------------------------------------------------------------------
dnl PA_FUNC_SNPRINTF
dnl
dnl See if we have [_]snprintf(), using the proper prototypes in case
dnl it is a builtin of some kind.
dnl --------------------------------------------------------------------------
AC_DEFUN([PA_FUNC_SNPRINTF],
[AC_CACHE_CHECK([for sprintf], [pa_cv_func_snprintf],
 [pa_cv_func_snprintf=no
  for pa_try_func_snprintf in snprintf _snprintf
  do
  AS_IF([test $pa_cv_func_snprintf = no],
        [AC_LINK_IFELSE([AC_LANG_SOURCE([
AC_INCLUDES_DEFAULT
const char *snprintf_test(int x);
const char *snprintf_test(int x)
{
    static char buf[[256]];
    size_t sz;
    sz = $pa_try_func_snprintf(buf, sizeof buf, "Hello = %d", x);
    return (sz < sizeof buf) ? buf : NULL;
}

int main(void) {
    puts(snprintf_test(33));
    return 0;
}
])],
 [pa_cv_func_snprintf=$pa_try_func_snprintf])])
 done
 ])
 AS_IF([test $pa_cv_func_snprintf = no],
       [],
       [AC_DEFINE([HAVE_SNPRINTF], 1,
         [Define to 1 if you have some version of the snprintf function.])
	 AS_IF([test $pa_cv_func_snprintf = snprintf],
	       [],
	       [AC_DEFINE_UNQUOTED([snprintf], [$pa_cv_func_snprintf],
	         [Define if your snprintf function is not named snprintf.])])])])