1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
|
# Create format and lint rules for a file manifest
#
# usage:
# ~~~
# format_and_lint(<slug>
# <file-list>
# [BZL <bzl-file-list>]
# [CMAKE <cmake-file-list>]
# [CC <cc-file-list>]
# [JS <js-file-list>]
# [PY <py-file-list>]
# [SHELL <sh-file-list>])
# ~~~
#
# Will create rules `${slug}_lint` and `${slug}_format` using the standard code
# formatters and lint checkers for the appropriate language. These tools are:
#
# ~~~
# BZL:
# formatter: buildifier
#
# CMAKE:
# formatter: cmake-format
# linter: cmake-lint
#
# CC:
# formatter: clang-format
# linter: cpplint, clang-tidy
#
# JS:
# formatter: js-beautify
# linter: eslint
#
# PY:
# formatter: autopep8
# linter: pylint, flake8
# ~~~
if(EXISTS ${CMAKE_SOURCE_DIR}/cmakelang)
set(CMAKE_FORMAT_CMD python -Bm cmakelang.format)
set(CMAKE_LINT_CMD python -Bm cmakelang.lint)
else()
set(CMAKE_FORMAT_CMD cmake-format)
set(CMAKE_LINT_CMD cmake-lint)
endif()
# TODO(josh): need to build this dynamically over the course of the
# configure-time, and then build the format and lint commands after we
# know all of the python path that needs to be included
set(_pythonpath "${CMAKE_SOURCE_DIR}:${CMAKE_BINARY_DIR}/pynix")
# Generate targets to format or lint the list of files
#
# Usage:
# ~~~
# format_and_lint(<slug>
# [BZL filepath1 [filepath2 [...]]]
# [CMAKE filepath1 [filepath2 [...]]]
# [CC filepath1 [filepath2 [...]]]
# [CCDEPENDS filepath1 [filepath2 [...]]]
# [JS filepath1 [filepath2 [...]]]
# [PY filepath1 [filepath2 [...]]]
# [SHELL filepath1 [filepath2 [...]]]
# )
# ~~~
function(format_and_lint slug)
# cmake-lint: disable=R0912,R0915
set(multiargs
BZL
CMAKE
CC
CCDEPENDS
JS
PY
SHELL)
cmake_parse_arguments(_args "" "" "${multiargs}" ${ARGN})
set(unknown_files)
foreach(arg ${_args_UNPARSED_ARGUMENTS})
if("${arg}" MATCHES ".*\\.bzl$"
OR "${arg}" MATCHES "(.*/)?BUILD"
OR "${arg}" MATCHES "(.*/)?WORKSPACE")
list(APPEND _args_BZL ${arg})
elseif("${arg}" MATCHES ".*\\.cmake$" OR "${arg}" MATCHES
".*CMakeLists.txt")
list(APPEND _args_CMAKE ${arg})
elseif("${arg}" MATCHES ".*\\.py$")
list(APPEND _args_PY ${arg})
elseif("${arg}" MATCHES ".*\\.(h|(hh)|(hpp))$")
list(APPEND _args_CC ${arg})
elseif("${arg}" MATCHES ".*\\.tcc$")
list(APPEND _args_CC ${arg})
elseif("${arg}" MATCHES ".*\\.(c|(cc)|(cpp))$")
list(APPEND _args_CC ${arg})
elseif("${arg}" MATCHES ".*\\.js(\\.tpl)?$")
list(APPEND _args_JS ${arg})
elseif("${arg}" MATCHES ".*\\.sh$")
list(APPEND _args_SHELL ${arg})
else()
list(APPEND unknown_files ${arg})
endif()
endforeach()
# NOTE(josh): we create this dummy target which touches a dummy file that all
# the rules below depend on. This gives us a synchronization point where we
# can add dependencies and ensure these dependencies happen before any of the
# rules below.
set(lintdep_witness ${CMAKE_CURRENT_BINARY_DIR}/lint-${slug}-deps.witness)
add_custom_target(
lint-${slug}-deps
COMMAND touch -a ${lintdep_witness}
BYPRODUCTS ${lintdep_witness}
COMMENT "Dependency fence for lint-${slug}")
if(NOT CMAKE_GENERATOR STREQUAL "Ninja")
add_custom_command(
OUTPUT ${lintdep_witness}
COMMAND true
DEPENDS lint-${slug}-deps
COMMENT "Makefile stub for lint-${slug} dependency fence")
endif()
set(bzl_lintdeps)
set(bzl_fmtdeps)
set(bzl_chkfmtdeps)
foreach(filename ${_args_BZL})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
COMMAND buildifier -indent 2 -mode check
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
DEPENDS ${filename} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND bzl_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
COMMAND buildifier -indent 2 -mode fix
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND bzl_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
COMMAND buildifier -indent 2 -mode check
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND bzl_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
endforeach()
set(cmake_lintdeps)
set(cmake_fmtdeps)
set(cmake_chkfmtdeps)
foreach(filename ${_args_CMAKE})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
COMMAND ${CMAKE_LINT_CMD} --suppress-decorations ${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
DEPENDS ${filename} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND cmake_lintdeps
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
COMMAND ${CMAKE_FORMAT_CMD} -i ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND cmake_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
COMMAND ${CMAKE_FORMAT_CMD} --check
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND cmake_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
endforeach()
set(cc_lintdeps)
set(cc_fmtdeps)
set(cc_chkfmtdeps)
foreach(filename ${_args_CC})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
if("${filename}" MATCHES ".*\\.(c|(cc)|(cpp))$")
# NOTE(josh): clang-tidy doesn't work on header files. It will check
# headers that it finds in the inclusion of translation units it
# understands
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy
COMMAND
clang-tidy-8 -p ${CMAKE_BINARY_DIR} -header-filter=${CMAKE_SOURCE_DIR}
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy
DEPENDS ${filename} ${_args_CCDEPENDS} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND cc_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy)
endif()
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint
COMMAND cpplint ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint
DEPENDS ${filename} ${_args_CCDEPENDS} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND cc_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
COMMAND clang-format-8 -style file -i ${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
DEPENDS ${filename} ${_args_CCDEPENDS}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND cc_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
COMMAND
COMMAND clang-format-8 -style file ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
"|" diff -u ${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
DEPENDS ${filename} ${_args_CCDEPENDS}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND cc_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
endforeach()
set(js_lintdeps)
set(js_fmtdeps)
set(js_chkfmtdeps)
foreach(filename ${_args_JS})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
COMMAND eslint ${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
DEPENDS ${filename} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND js_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
COMMAND js-beautify -r ${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND js_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
COMMAND js-beautify ${CMAKE_CURRENT_SOURCE_DIR}/${filename} "|" diff -u
${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND js_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
endforeach()
set(py_lintdeps)
set(py_fmtdeps)
set(py_chkfmtdeps)
foreach(filename ${_args_PY})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
# NOTE(josh): --rcfile= is required because some of our python
# files are note entirely within the package tree from the root of
# the repository. As such pylint will not match the rcfile in the
# root of the repository.
COMMAND
env PYTHONPATH=${_pythonpath} pylint
--rcfile=${CMAKE_SOURCE_DIR}/pylintrc -sn -rn
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
# NOTE(josh): flake8 tries to use semaphores which fail in our
# containers https://bugs.python.org/issue3770 (probably due to
# /proc/shmem or something not being mounted)
COMMAND env PYTHONPATH=${_pythonpath} flake8 --jobs 1
${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND py_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
COMMAND autopep8 -i ${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
list(APPEND py_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
COMMAND autopep8 ${CMAKE_CURRENT_SOURCE_DIR}/${filename} "|" diff -u
${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
DEPENDS ${filename}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND py_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
endforeach()
set(shell_lintdeps)
set(shell_fmtdeps)
set(shell_chkfmtdeps)
foreach(filename ${_args_SHELL})
get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
DIRECTORY)
add_custom_command(
OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
COMMAND shellcheck ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
COMMAND ${CMAKE_COMMAND} -E touch
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
DEPENDS ${filename} ${lintdep_witness}
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
list(APPEND shell_lintdeps
${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
# NOTE(josh): beautysh is broken. It destroys shell scripts
# ~~~
# add_custom_command(
# OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
# COMMAND beautysh --indent-size=2 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
# COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
# COMMAND ${CMAKE_COMMAND} -E touch
# ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
# DEPENDS ${filename}
# WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
# list(APPEND shell_fmtdeps
# ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
#
# add_custom_command(
# OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
# COMMAND beautysh --indent-size=2 --check
# ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
# COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
# COMMAND ${CMAKE_COMMAND} -E touch
# ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
# DEPENDS ${filename}
# WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
# list(APPEND shell_chkfmtdeps
# ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
# ~~~
endforeach()
if(unknown_files)
string(REPLACE ";" "\n " filelist "${unknown_files}")
message(
WARNING "The following files will not be linted/formatted because their"
" extension is not recognized: \n ${filelist}")
endif()
file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${slug}.lint-manifest "")
foreach(listname _args_CC _args_CMAKE _args_JS _args_PY _args_SHELL)
if(${listname})
string(REPLACE ";" "\n" filenames "${${listname}}")
file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/${slug}.lint-manifest
"${filenames}\n")
endif()
endforeach()
set(langslugs bzl cc cmake js py shell)
add_custom_target(lint-${slug})
add_dependencies(lint lint-${slug})
foreach(langslug ${langslugs})
if(${langslug}_lintdeps)
add_custom_target(lint-${langslug}-${slug}
DEPENDS ${${langslug}_lintdeps})
add_dependencies(lint-${slug} lint-${langslug}-${slug})
endif()
endforeach()
add_custom_target(format-${slug})
add_dependencies(format format-${slug})
foreach(langslug ${langslugs})
if(${langslug}_fmtdeps)
add_custom_target(format-${langslug}-${slug}
DEPENDS ${${langslug}_fmtdeps})
add_dependencies(format-${slug} format-${langslug}-${slug})
endif()
endforeach()
add_custom_target(chkfmt-${slug})
add_dependencies(chkfmt chkfmt-${slug})
foreach(langslug ${langslugs})
if(${langslug}_chkfmtdeps)
add_custom_target(chkfmt-${langslug}-${slug}
DEPENDS ${${langslug}_chkfmtdeps})
add_dependencies(chkfmt-${slug} chkfmt-${langslug}-${slug})
endif()
endforeach()
endfunction()
|
