File: PIE_validator.cmake

package info (click to toggle)
cmake 4.2.1-2
  • links: PTS, VCS
  • area: main
  • in suites: forky
  • size: 152,344 kB
  • sloc: ansic: 403,894; cpp: 303,807; sh: 4,097; python: 3,582; yacc: 3,106; lex: 1,279; f90: 538; asm: 471; lisp: 375; cs: 270; java: 266; fortran: 239; objc: 215; perl: 213; xml: 198; makefile: 108; javascript: 83; pascal: 63; tcl: 55; php: 25; ruby: 22
file content (32 lines) | stat: -rw-r--r-- 896 bytes parent folder | download | duplicates (7) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 

include_guard(GLOBAL)

function (CHECK_EXECUTABLE executable result)
  set (${result} "UNKNOWN" PARENT_SCOPE)

  if (CMAKE_SYSTEM_NAME STREQUAL "Darwin")
    set (tool otool -hv)
  else()
    set (tool "${CMAKE_COMMAND}" -E env LANG=C LC_ALL=C readelf -lW)
  endif()

  execute_process(COMMAND ${tool} "${executable}"
                  OUTPUT_VARIABLE output
                  ERROR_VARIABLE output)

  if (CMAKE_SYSTEM_NAME STREQUAL "Darwin")
    if (output MATCHES "( |\t)PIE( |\n|$)")
      set (${result} "PIE" PARENT_SCOPE)
    else()
      set (${result} "NO_PIE" PARENT_SCOPE)
    endif()
  else()
    if (output MATCHES "Elf file type is DYN")
      set (${result} "PIE" PARENT_SCOPE)
    elseif (output MATCHES "Elf file type is EXEC")
      set (${result} "NO_PIE" PARENT_SCOPE)
    else()
      message(SEND_ERROR "Did not find a known file type")
    endif()
  endif()
endfunction()