1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
|
#! /bin/sh
#!perl -w # --*- Perl -*--
eval 'exec perl -x $0 ${1+"$@"}'
if 0;
#------------------------------------------------------------------------------
#$Author: andrius $
#$Date: 2017-10-26 09:07:06 +0300 (Kt, 26 spal. 2017) $
#$Revision: 5663 $
#$URL: svn://www.crystallography.net/cod-tools/tags/v2.3/scripts/cif_sort_atoms $
#------------------------------------------------------------------------------
#*
#* Sort atoms in a CIF file in given order.
#*
#* USAGE:
#* $0 --options input1.cif input*.cif
#**
use strict;
use warnings;
use File::Basename qw( basename );
use COD::AtomProperties;
use COD::CIF::Data::AtomList qw( extract_atom );
use COD::CIF::Parser qw( parse_cif );
use COD::CIF::Tags::CanonicalNames qw( canonicalize_all_names );
use COD::CIF::Tags::Print qw( print_cif );
use COD::ErrorHandler qw( process_errors process_warnings
process_parser_messages report_message );
use COD::SOptions qw( getOptions get_value );
use COD::SUsage qw( usage options );
use COD::ToolsVersion;
my $order = \&get_lexicographic_order;
my $direction = 1;
my $use_parser = 'c';
my $die_on_errors = 0;
my $die_on_warnings = 0;
my $die_on_notes = 0;
my $die_on_error_level = {
ERROR => $die_on_errors,
WARNING => $die_on_warnings,
NOTE => $die_on_notes
};
#* OPTIONS:
#* -l, --lexicographic
#* Sort by lexicographic order (default).
#* -Z, --atomic-number
#* Sort by atomic number.
#*
#* -r, --reverse
#* Reverse the ordering.
#*
#* --use-perl-parser
#* Use Perl parser for CIF parsing.
#* --use-c-parser
#* Use Perl & C parser for CIF parsing (default).
#*
#* --help, --usage
#* Output a short usage message (this message) and exit.
#* --version
#* Output version information and exit.
#**
@ARGV = getOptions(
'-l,--lexicographic' => sub { $order = \&get_lexicographic_order },
'-Z,--atomic-number' => sub { $order = \&get_atomic_order },
'-r,--reverse' => sub { $direction = -1 },
'--use-perl-parser' => sub{ $use_parser = 'perl' },
'--use-c-parser' => sub{ $use_parser = 'c' },
'--options' => sub { options; exit },
'--help,--usage' => sub { usage; exit },
'--version' => sub { print 'cod-tools version ',
$COD::ToolsVersion::Version, "\n";
exit }
);
@ARGV = ( '-' ) unless @ARGV;
binmode STDOUT, ':encoding(UTF-8)';
binmode STDERR, ':encoding(UTF-8)';
for my $filename (@ARGV) {
my $options = { parser => $use_parser,
no_print => 1 };
my( $data, $err_count, $messages ) = parse_cif( $filename, $options );
process_parser_messages( $messages, $die_on_error_level );
if( !@{$data} || !defined $data->[0] || !defined $data->[0]{name} ) {
report_message( {
'program' => $0,
'filename' => $filename,
'err_level' => 'WARNING',
'message' => 'file seems to be empty'
}, 0 );
next;
}
canonicalize_all_names( $data );
for my $dataset (@$data) {
my $values = $dataset->{values};
my $dataname = 'data_' . $dataset->{name};
local $SIG{__WARN__} = sub {
process_warnings( {
'message' => @_,
'program' => $0,
'filename' => $filename,
'add_pos' => $dataname
}, $die_on_error_level )
};
eval {
my @order = $order->( $values, $direction );
my $atom_loop = $dataset->{inloop}{_atom_site_label};
if( defined $atom_loop ) {
for my $tag (@{$dataset->{loops}[$atom_loop]}) {
for my $key (qw( precisions types values )) {
$dataset->{$key}{$tag} =
[ @{$dataset->{$key}{$tag}}[@order] ];
}
}
}
print_cif( $dataset,
{
preserve_loop_order => 1,
keep_tag_order => 1
} );
};
if ( $@ ) {
process_errors( {
'message' => $@,
'program' => $0,
'filename' => $filename,
'add_pos' => $dataname
}, $die_on_errors )
}
}
}
sub get_lexicographic_order
{
my( $dataset, $direction ) = @_;
$direction = 1 unless defined $direction;
return sort { $direction *
($dataset->{_atom_site_label}[$a] cmp
$dataset->{_atom_site_label}[$b]) }
0..$#{$dataset->{_atom_site_label}};
}
sub get_atomic_order
{
my( $dataset, $direction ) = @_;
$direction = 1 unless defined $direction;
my $unity = [ [ 1, 0, 0, 0 ],
[ 0, 1, 0, 0 ],
[ 0, 0, 1, 0 ],
[ 0, 0, 0, 1 ] ]; # fake f2o matrix
my @types = map { $_->{chemical_type} }
map { extract_atom( $dataset->{_atom_site_label}[$_],
$dataset, $_, $unity ) }
0..$#{$dataset->{_atom_site_label}};
return sort { $direction *
($COD::AtomProperties::atoms{$types[$a]}{atomic_number} <=>
$COD::AtomProperties::atoms{$types[$b]}{atomic_number}) }
0..$#{$dataset->{_atom_site_label}};
}
|
