File: findtypedef.l

package info (click to toggle)
coda 2.20-3
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 11,292 kB
  • sloc: ansic: 124,817; sh: 4,657; java: 2,391; python: 1,091; yacc: 1,003; makefile: 596; lex: 204; fortran: 60; xml: 5
file content (80 lines) | stat: -rw-r--r-- 1,806 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
%option noyywrap
%option always-interactive
%option noinput
%option nounput

%x COMMENT
%x STRING
%x TYPEDEF

%{
#ifdef HAVE_CONFIG_H
#include "config.h"
#endif

#include <ctype.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>

int depth;
%}

ID                  [a-zA-Z][a-zA-Z0-9_]*
%%

"/*"                BEGIN(COMMENT);
<COMMENT>"*/"       BEGIN(INITIAL);
"\""                BEGIN(STRING);
<STRING>"\\\""      /* eat escaped double quotes */
<STRING>"\""        BEGIN(INITIAL);
{ID}                {
                        if (strcmp(yytext,"typedef") == 0)
                        {
                            depth = 0;
                            BEGIN(TYPEDEF);
                        }
                    }
<TYPEDEF>"{"        depth++;
<TYPEDEF>"}"        depth--;
<TYPEDEF>{ID}("["[0-9, ]+"]")*[ \t\n]*";" {
                        if (depth == 0)
                        {
                            int n;
                            n = 0;
                            while (yytext[n] != ';' &&
                                   yytext[n] != '[' &&
                                   !isspace(yytext[n]))
                            {
                                n++;
                            }
                            yytext[n] = '\0';
                            fprintf(yyout, "%s\n", yytext);
                            BEGIN(INITIAL);
                        }
                    }
<*>.|"\n"           /* eat up characters */

%%

int main(int argc, char *argv[])
{
    if (argc > 1)
    {
        yyin = fopen(argv[1], "r");
        if (yyin == NULL)
        {
            fprintf(stderr, "ERROR: could not open file\n");
            exit(1);
        }
    }
    else
    {
        yyin = stdin;
    }
    yyout = stdout;

    yylex();

    return 0;
}