File: confclerk.pro

package info (click to toggle)
confclerk 0.6.1-1
  • links: PTS, VCS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 1,876 kB
  • ctags: 575
  • sloc: cpp: 3,529; sql: 251; makefile: 12
file content (52 lines) | stat: -rw-r--r-- 1,779 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# confclerk.pro

QMAKEVERSION = $$[QMAKE_VERSION]
ISQT4 = $$find(QMAKEVERSION, ^[2-9])
isEmpty( ISQT4 ) {
	error("Use the qmake include with Qt4.4 or greater, on Debian that is qmake-qt4");
}

TEMPLATE = subdirs
SUBDIRS = src

# The global.pri defines the VERSION of the project
include(src/global.pri)

QMAKE_EXTRA_TARGETS += changelog icon man release releaseclean tarball signature

changelog.target = ChangeLog
changelog.commands = \
	svn2cl --group-by-day --reparagraph
changelog.CONFIG = phony

icon.target = data/$${TARGET}.png
icon.commands = convert data/$${TARGET}.svg data/$${TARGET}.png
icon.depends = data/$${TARGET}.svg

man.target = data/$${TARGET}.1
man.commands = \
	pod2man --utf8 --center=\"Offline conference scheduler\" --release=\"Version $${VERSION}\" data/$${TARGET}.pod > data/$${TARGET}.1
man.depends = data/$${TARGET}.pod

releaseclean.commands = \
 $(DEL_FILE) data/$${TARGET}.png data/$${TARGET}.1 ChangeLog $${TARGET}-$${VERSION}.tar.gz.asc
release.depends = releaseclean tarball signature
#releaseclean.CONFIG = phony

tarball.target = $${TARGET}-$${VERSION}.tar.gz
tarball.commands = \
	$(DEL_FILE) -r $${TARGET}-$${VERSION} ; \
	$(MKDIR) $${TARGET}-$${VERSION} ; \
	$(COPY_DIR) * $${TARGET}-$${VERSION}/ ; \
	$(DEL_FILE) $${TARGET}-$${VERSION}/*.pro.user* \
		$${TARGET}-$${VERSION}/$${TARGET}-$${VERSION}.tar.gz \
		$(DEL_FILE) -r $${TARGET}-$${VERSION}/$${TARGET}-$${VERSION} \
		$${TARGET}-$${VERSION}/Makefile ; \
	tar -cz --exclude=.svn --exclude=*.tar.gz -f $$tarball.target $${TARGET}-$${VERSION} ; \
	$(DEL_FILE) -r $${TARGET}-$${VERSION}
tarball.depends = changelog icon man

signature.target = $${TARGET}-$${VERSION}.tar.gz.asc
signature.commands = \
	gpg --armor --detach-sign $${TARGET}-$${VERSION}.tar.gz
signature.depends = tarball