1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
|
From Corelib Require Import ssreflect ssrfun.
From HB Require Import structures.
(**************************************************************************)
(* Stage 5: AddMonoid ---> AddComoid ----> AddAG ----> Ring *)
(* \ \ / *)
(* -> +BiNearRing+ -> SemiRing - *)
(**************************************************************************)
HB.mixin Record AddMonoid_of_TYPE S := {
zero : S;
add : S -> S -> S;
addrA : associative add;
add0r : left_id zero add;
addr0 : right_id zero add;
}.
HB.structure Definition AddMonoid := { A of AddMonoid_of_TYPE A }.
HB.mixin Record AddComoid_of_AddMonoid A of AddMonoid A := {
addrC : commutative (add : A -> A -> A);
}.
HB.factory Record AddComoid_of_TYPE A := {
zero : A;
add : A -> A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
}.
HB.builders Context A (a : AddComoid_of_TYPE A).
Fact addr0 : right_id zero add.
Proof. by move=> x; rewrite addrC add0r. Qed.
HB.instance
Definition to_AddMonoid_of_TYPE :=
AddMonoid_of_TYPE.Build A zero add addrA add0r addr0.
HB.instance
Definition to_AddComoid_of_AddMonoid :=
AddComoid_of_AddMonoid.Build A addrC.
HB.end.
HB.structure Definition AddComoid := { A of AddComoid_of_TYPE A }.
(* End change *)
HB.mixin Record AddAG_of_AddComoid A of AddComoid A := {
opp : A -> A;
addNr : left_inverse zero opp add;
}.
HB.factory Record AddAG_of_TYPE A := {
zero : A;
add : A -> A -> A;
opp : A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
addNr : left_inverse zero opp add;
}.
HB.builders Context A (a : AddAG_of_TYPE A).
HB.instance
Definition to_AddComoid_of_TYPE :=
AddComoid_of_TYPE.Build A zero add addrA addrC add0r.
HB.instance
Definition to_AddAG_of_AddComoid :=
AddAG_of_AddComoid.Build A _ addNr.
HB.end.
HB.structure Definition AddAG := { A of AddAG_of_TYPE A }.
(* Begin changes *)
HB.mixin Record BiNearRing_of_AddMonoid A of AddMonoid A := {
one : A;
mul : A -> A -> A;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
mul0r : left_zero zero mul;
mulr0 : right_zero zero mul;
}.
HB.structure Definition BiNearRing := { A of AddMonoid A & BiNearRing_of_AddMonoid A }.
(* this factory is accidentally a duplicate of BiNearRing_of_AddMonoid *)
(* we alias it for backward compatilibity and uniformity purposes *)
HB.factory Definition SemiRing_of_AddComoid A of AddComoid A :=
BiNearRing_of_AddMonoid A.
HB.builders Context A (a : SemiRing_of_AddComoid A).
HB.instance
Definition to_BiNearRing_of_AddMonoid : BiNearRing_of_AddMonoid A := a.
HB.end.
(* End changes *)
HB.structure Definition SemiRing := { A of AddComoid A & SemiRing_of_AddComoid A }.
Set Implicit Arguments. (* The factory builder will have implicit arguments *)
#[doc="Builds a Ring from an Abelian Group: the absorbing properties mul0r and mul0r are derived from addrC and the other ring axioms, following a proof of Hankel (Gerhard Betsch. On the beginnings and development of near-ring theory. In Near-rings and near-fields. Proceedings of the conference held in Fredericton, New Brunswick, July 18-24, 1993, pages 1–11. Mathematics and its Applications, 336. Kluwer Academic Publishers Group, Dordrecht, 1995)."]
HB.factory Record Ring_of_AddAG A of AddAG A := {
one : A;
mul : A -> A -> A;
mulrA : associative mul;
mulr1 : left_id one mul;
mul1r : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
Unset Implicit Arguments.
HB.builders Context A (a : Ring_of_AddAG A).
Fact mul0r : left_zero zero mul.
Proof.
move=> x; rewrite -[LHS]add0r addrC.
rewrite -{2}(addNr (mul x x)) (addrC (opp _)) addrA.
by rewrite -mulrDl add0r addrC addNr.
Qed.
Fact mulr0 : right_zero zero mul.
Proof.
move=> x; rewrite -[LHS]add0r addrC.
rewrite -{2}(addNr (mul x x)) (addrC (opp _)) addrA.
by rewrite -mulrDr add0r addrC addNr.
Qed.
HB.instance
Definition to_SemiRing_of_AddComoid := SemiRing_of_AddComoid.Build A
_ mul mulrA mulr1 mul1r mulrDl mulrDr mul0r mulr0.
HB.end.
HB.factory Record Ring_of_AddComoid A of AddComoid A := {
opp : A -> A;
one : A;
mul : A -> A -> A;
addNr : left_inverse zero opp add;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
HB.builders Context A (a :Ring_of_AddComoid A).
HB.instance
Definition to_AddAG_of_AddComoid := AddAG_of_AddComoid.Build A _ addNr.
HB.instance
Definition to_Ring_of_AddAG := Ring_of_AddAG.Build A
mulrA mul1r mulr1 mulrDl mulrDr.
HB.end.
HB.factory Record Ring_of_TYPE A := {
zero : A;
one : A;
add : A -> A -> A;
opp : A -> A;
mul : A -> A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
addNr : left_inverse zero opp add;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
HB.builders Context A (a : Ring_of_TYPE A).
HB.instance
Definition to_AddComoid_of_TYPE := AddComoid_of_TYPE.Build A
zero add addrA addrC add0r.
HB.instance
Definition to_Ring_of_AddComoid := Ring_of_AddComoid.Build A
_ _ _ addNr mulrA mul1r mulr1 mulrDl mulrDr.
HB.end.
HB.structure Definition Ring := { A of Ring_of_TYPE A }.
(* Notations *)
Declare Scope hb_scope.
Delimit Scope hb_scope with G.
Local Open Scope hb_scope.
Notation "0" := zero : hb_scope.
Notation "1" := one : hb_scope.
Infix "+" := (@add _) : hb_scope.
Notation "- x" := (@opp _ x) : hb_scope.
Infix "*" := (@mul _) : hb_scope.
Notation "x - y" := (x + - y) : hb_scope.
(* Theory *)
Section Theory.
Variable R : Ring.type.
Implicit Type (x : R).
(* Not general enough anymore, subsumed by Monoid addr0 *)
(* Lemma addr0 : right_id (@zero R) add.
Proof. by move=> x; rewrite addrC add0r. Qed. *)
Lemma addrN : right_inverse (@zero R) opp add.
Proof. by move=> x; rewrite addrC addNr. Qed.
Lemma subrr x : x - x = 0.
Proof. by rewrite addrN. Qed.
Lemma addrNK x y : x + y - y = x.
Proof. by rewrite -addrA subrr addr0. Qed.
End Theory.
HB.graph "hierarchy_5.dot".
(* we check the alias factory is abstracted over the whole section *)
HB.check (SemiRing_of_AddComoid.axioms_ : forall A, forall m : AddMonoid_of_TYPE.axioms_ A, AddComoid_of_AddMonoid.axioms_ A m -> Type).
|
