1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
|
!--------------------------------------------------------------------------------------------------!
! CP2K: A general program to perform molecular dynamics simulations !
! Copyright (C) 2000 - 2018 CP2K developers group !
!--------------------------------------------------------------------------------------------------!
MODULE optimize_basis
USE admm_methods, ONLY: admm_fit_mo_coeffs
USE cp_blacs_env, ONLY: cp_blacs_env_type
USE cp_fm_types, ONLY: cp_fm_p_type,&
cp_fm_release
USE cp_log_handling, ONLY: cp_get_default_logger,&
cp_logger_get_default_unit_nr,&
cp_logger_type
USE cp_para_env, ONLY: cp_para_env_create,&
cp_para_env_release
USE cp_para_types, ONLY: cp_para_env_type
USE dbcsr_api, ONLY: dbcsr_p_type
USE f77_interface, ONLY: create_force_env,&
destroy_force_env,&
f_env_add_defaults,&
f_env_get_from_id,&
f_env_rm_defaults,&
f_env_type
USE force_env_types, ONLY: force_env_get,&
force_env_type
USE input_cp2k_read, ONLY: empty_initial_variables,&
read_input
USE input_section_types, ONLY: section_type,&
section_vals_release,&
section_vals_type
USE kinds, ONLY: default_path_length,&
dp
USE machine, ONLY: m_chdir,&
m_getcwd,&
m_walltime
USE message_passing, ONLY: mp_bcast,&
mp_comm_free,&
mp_comm_split,&
mp_sum,&
mp_sync
USE optbas_fenv_manipulation, ONLY: allocate_mo_sets,&
calculate_ks_matrix,&
calculate_overlap,&
calculate_overlap_inverse,&
create_opt_admm_env,&
modify_input_settings,&
update_basis_set
USE optbas_opt_utils, ONLY: evaluate_energy,&
evaluate_fval
USE optimize_basis_types, ONLY: basis_optimization_type,&
deallocate_basis_optimization_type,&
subset_type
USE optimize_basis_utils, ONLY: get_set_and_basis_id,&
optimize_basis_init_read_input,&
update_derived_basis_sets
USE powell, ONLY: powell_optimize
USE qs_environment_types, ONLY: get_qs_env,&
qs_environment_type
USE qs_ks_types, ONLY: qs_ks_env_type
USE qs_neighbor_lists, ONLY: build_qs_neighbor_lists
#include "./base/base_uses.f90"
IMPLICIT NONE
PRIVATE
PUBLIC :: run_optimize_basis
CHARACTER(len=*), PARAMETER, PRIVATE :: moduleN = 'optimize_basis'
CONTAINS
! **************************************************************************************************
!> \brief main entry point for methods aimed at optimizing basis sets
!> \param input_declaration ...
!> \param root_section ...
!> \param para_env ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE run_optimize_basis(input_declaration, root_section, para_env)
TYPE(section_type), POINTER :: input_declaration
TYPE(section_vals_type), POINTER :: root_section
TYPE(cp_para_env_type), POINTER :: para_env
CHARACTER(len=*), PARAMETER :: routineN = 'run_optimize_basis', &
routineP = moduleN//':'//routineN
INTEGER :: handle
TYPE(basis_optimization_type) :: opt_bas
CALL timeset(routineN, handle)
CALL optimize_basis_init_read_input(opt_bas, root_section, para_env)
CALL driver_para_opt_basis(opt_bas, input_declaration, para_env)
CALL deallocate_basis_optimization_type(opt_bas)
CALL timestop(handle)
END SUBROUTINE run_optimize_basis
! **************************************************************************************************
!> \brief driver routine for the parallel part of the method
!> \param opt_bas ...
!> \param input_declaration ...
!> \param para_env ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE driver_para_opt_basis(opt_bas, input_declaration, para_env)
TYPE(basis_optimization_type) :: opt_bas
TYPE(section_type), POINTER :: input_declaration
TYPE(cp_para_env_type), POINTER :: para_env
CHARACTER(len=*), PARAMETER :: routineN = 'driver_para_opt_basis', &
routineP = moduleN//':'//routineN
INTEGER :: handle, n_groups_created, opt_group
INTEGER, DIMENSION(:), POINTER :: group_distribution_p
INTEGER, DIMENSION(0:para_env%num_pe-1), TARGET :: group_distribution
CALL timeset(routineN, handle)
group_distribution_p => group_distribution
CALL mp_comm_split(para_env%group, opt_group, n_groups_created, group_distribution_p, &
n_subgroups=SIZE(opt_bas%group_partition), group_partition=opt_bas%group_partition)
opt_bas%opt_id = group_distribution(para_env%mepos)+1
CALL driver_optimization_para_low(opt_bas, input_declaration, para_env, opt_group)
CALL mp_comm_free(opt_group)
CALL timestop(handle)
END SUBROUTINE driver_para_opt_basis
! **************************************************************************************************
!> \brief low level optimization routine includes initialization of the subsytems
!> powell optimizer and deallocation of the various force envs
!> \param opt_bas ...
!> \param input_declaration ...
!> \param para_env_top ...
!> \param mpi_comm_opt ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE driver_optimization_para_low(opt_bas, input_declaration, para_env_top, mpi_comm_opt)
TYPE(basis_optimization_type) :: opt_bas
TYPE(section_type), POINTER :: input_declaration
TYPE(cp_para_env_type), POINTER :: para_env_top
INTEGER :: mpi_comm_opt
CHARACTER(len=*), PARAMETER :: routineN = 'driver_optimization_para_low', &
routineP = moduleN//':'//routineN
INTEGER :: handle, icalc, iopt, mp_id, stat
INTEGER, ALLOCATABLE, DIMENSION(:) :: f_env_id
LOGICAL :: write_basis
REAL(KIND=dp), ALLOCATABLE, DIMENSION(:) :: tot_time
TYPE(cp_fm_p_type), ALLOCATABLE, DIMENSION(:) :: matrix_S_inv
TYPE(cp_para_env_type), POINTER :: para_env
TYPE(f_env_type), POINTER :: f_env
NULLIFY (f_env)
CALL timeset(routineN, handle)
! ====== initialize the f_env and precompute some matrices =====
mp_id = opt_bas%opt_id
NULLIFY (para_env, f_env)
ALLOCATE (f_env_id(SIZE(opt_bas%comp_group(mp_id)%member_list)))
ALLOCATE (tot_time(opt_bas%ncombinations*opt_bas%ntraining_sets))
ALLOCATE (matrix_s_inv(SIZE(opt_bas%comp_group(mp_id)%member_list)))
CALL cp_para_env_create(para_env, group=mpi_comm_opt, &
owns_group=.FALSE.)
CALL init_training_force_envs(opt_bas, f_env_id, input_declaration, matrix_s_inv, para_env, mpi_comm_opt)
CALL init_free_vars(opt_bas)
tot_time = 0.0_dp
! ======= The real optimization loop =======
DO iopt = 0, opt_bas%powell_param%maxfun
CALL compute_residuum_vectors(opt_bas, f_env_id, matrix_S_inv, tot_time, &
para_env_top, para_env, iopt)
IF (para_env_top%ionode) &
CALL powell_optimize(opt_bas%powell_param%nvar, opt_bas%x_opt, opt_bas%powell_param)
IF (.NOT. para_env_top%ionode) opt_bas%x_opt = 0.0_dp
CALL mp_bcast(opt_bas%powell_param%state, para_env_top%source, para_env_top%group)
CALL mp_sum(opt_bas%x_opt, para_env_top%group)
CALL update_free_vars(opt_bas)
write_basis = MOD(iopt, opt_bas%write_frequency) == 0
CALL update_derived_basis_sets(opt_bas, write_basis, opt_bas%output_basis_file, &
para_env_top)
IF (opt_bas%powell_param%state == -1) EXIT
END DO
! ======= Update the basis set and print the final basis =======
IF (para_env_top%ionode) THEN
opt_bas%powell_param%state = 8
CALL powell_optimize(opt_bas%powell_param%nvar, opt_bas%x_opt, opt_bas%powell_param)
END IF
IF (.NOT. para_env_top%ionode) opt_bas%x_opt = 0.0_dp
CALL mp_sum(opt_bas%x_opt, para_env_top%group)
CALL update_free_vars(opt_bas)
CALL update_derived_basis_sets(opt_bas, .TRUE., opt_bas%output_basis_file, &
para_env_top)
! ====== get rid of the f_env again =====
DO icalc = SIZE(opt_bas%comp_group(mp_id)%member_list), 1, -1
CALL f_env_get_from_id(f_env_id(icalc), f_env)
CALL destroy_force_env(f_env_id(icalc), stat)
CALL cp_fm_release(matrix_s_inv(icalc)%matrix)
END DO
DEALLOCATE (f_env_id); DEALLOCATE (tot_time); DEALLOCATE (matrix_S_inv)
CALL cp_para_env_release(para_env)
CALL timestop(handle)
END SUBROUTINE driver_optimization_para_low
! **************************************************************************************************
!> \brief compute all ingredients for powell optimizer. Rho_diff,
!> condition number, energy,... for all ttraining sets in
!> the computational group
!> \param opt_bas ...
!> \param f_env_id ...
!> \param matrix_S_inv ...
!> \param tot_time ...
!> \param para_env_top ...
!> \param para_env ...
!> \param iopt ...
! **************************************************************************************************
SUBROUTINE compute_residuum_vectors(opt_bas, f_env_id, matrix_S_inv, tot_time, &
para_env_top, para_env, iopt)
TYPE(basis_optimization_type) :: opt_bas
INTEGER, ALLOCATABLE, DIMENSION(:) :: f_env_id
TYPE(cp_fm_p_type), DIMENSION(:) :: matrix_S_inv
REAL(KIND=dp), DIMENSION(:) :: tot_time
TYPE(cp_para_env_type), POINTER :: para_env_top, para_env
INTEGER :: iopt
CHARACTER(len=*), PARAMETER :: routineN = 'compute_residuum_vectors', &
routineP = moduleN//':'//routineN
INTEGER :: bas_id, handle, icalc, icomb, mp_id, &
my_id, ncalc, set_id
REAL(KIND=dp), ALLOCATABLE, DIMENSION(:) :: cond_vec, energy, f_vec, my_time, &
start_time
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_ks, matrix_s_aux_fit, &
matrix_s_aux_fit_vs_orb
TYPE(f_env_type), POINTER :: f_env
TYPE(force_env_type), POINTER :: force_env
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(qs_ks_env_type), POINTER :: ks_env
CALL timeset(routineN, handle)
NULLIFY (matrix_ks, matrix_s_aux_fit_vs_orb, matrix_s_aux_fit, ks_env)
ncalc = opt_bas%ncombinations*opt_bas%ntraining_sets
ALLOCATE (f_vec(ncalc)); ALLOCATE (my_time(ncalc)); ALLOCATE (cond_vec(ncalc)); ALLOCATE (energy(ncalc))
f_vec = 0.0_dp; cond_vec = 0.0_dp; my_time = 0.0_dp; energy = 0.0_dp
mp_id = opt_bas%opt_id
ALLOCATE (start_time(SIZE(opt_bas%comp_group(mp_id)%member_list)))
DO icalc = 1, SIZE(opt_bas%comp_group(mp_id)%member_list)
my_id = opt_bas%comp_group(mp_id)%member_list(icalc)+1
! setup timings
start_time(icalc) = m_walltime()
CALL get_set_and_basis_id(opt_bas%comp_group(mp_id)%member_list(icalc), opt_bas, set_id, bas_id)
CALL f_env_get_from_id(f_env_id(icalc), f_env)
force_env => f_env%force_env
CALL force_env_get(force_env, qs_env=qs_env)
CALL get_qs_env(qs_env, ks_env=ks_env)
CALL update_basis_set(opt_bas, bas_id, qs_env)
CALL build_qs_neighbor_lists(qs_env, para_env, molecular=.FALSE., force_env_section=qs_env%input)
CALL calculate_overlap(ks_env, "S_AB_AUX")
CALL get_qs_env(qs_env, &
matrix_ks=matrix_ks, &
matrix_s_aux_fit_vs_orb=matrix_s_aux_fit_vs_orb, &
matrix_s_aux_fit=matrix_s_aux_fit)
CALL admm_fit_mo_coeffs(qs_env%admm_env, matrix_s_aux_fit, &
matrix_s_aux_fit_vs_orb, qs_env%mos, qs_env%mos_aux_fit, &
geometry_did_change=.TRUE.)
CALL evaluate_fval(qs_env%mos, qs_env%mos_aux_fit, matrix_s_aux_fit_vs_orb(1)%matrix, &
matrix_s_aux_fit(1)%matrix, qs_env%admm_env, f_vec(my_id), cond_vec(my_id))
CALL evaluate_energy(qs_env%mos_aux_fit, matrix_ks, matrix_s_inv(icalc)%matrix, qs_env%admm_env%Q, &
qs_env%admm_env%work_aux_aux, energy(my_id))
my_time(my_id) = m_walltime()-start_time(icalc)
IF (.NOT. para_env%ionode) THEN
f_vec = 0.0_dp; cond_vec = 0.0_dp; my_time = 0.0_dp; energy = 0.0_dp
END IF
END DO
DEALLOCATE (start_time)
CALL mp_sum(f_vec, para_env_top%group); CALL mp_sum(cond_vec, para_env_top%group); CALL mp_sum(my_time, para_env_top%group)
opt_bas%powell_param%f = 0.0_dp
DO icalc = 1, SIZE(f_vec)
icomb = MOD(icalc-1, opt_bas%ncombinations)
opt_bas%powell_param%f = opt_bas%powell_param%f+ &
(f_vec(icalc)+energy(icalc))*opt_bas%fval_weight(icomb)
IF (opt_bas%use_condition_number) &
opt_bas%powell_param%f = opt_bas%powell_param%f+ &
LOG(cond_vec(icalc))*opt_bas%condition_weight(icomb)
END DO
CALL mp_sync(para_env_top%group)
! output info if required
CALL output_opt_info(f_vec, cond_vec, my_time, tot_time, opt_bas, iopt, para_env_top)
DEALLOCATE (f_vec); DEALLOCATE (my_time); DEALLOCATE (cond_vec); DEALLOCATE (energy)
CALL timestop(handle)
END SUBROUTINE compute_residuum_vectors
! **************************************************************************************************
!> \brief create the force_envs for every input in the computational group
!> \param opt_bas ...
!> \param f_env_id ...
!> \param input_declaration ...
!> \param matrix_s_inv ...
!> \param para_env ...
!> \param mpi_comm_opt ...
! **************************************************************************************************
SUBROUTINE init_training_force_envs(opt_bas, f_env_id, input_declaration, matrix_s_inv, para_env, mpi_comm_opt)
TYPE(basis_optimization_type) :: opt_bas
INTEGER, ALLOCATABLE, DIMENSION(:) :: f_env_id
TYPE(section_type), POINTER :: input_declaration
TYPE(cp_fm_p_type), DIMENSION(:) :: matrix_S_inv
TYPE(cp_para_env_type), POINTER :: para_env
INTEGER :: mpi_comm_opt
CHARACTER(len=*), PARAMETER :: routineN = 'init_training_force_envs', &
routineP = moduleN//':'//routineN
CHARACTER(len=default_path_length) :: main_dir
INTEGER :: bas_id, handle, icalc, ierr, mp_id, &
set_id, stat
TYPE(cp_blacs_env_type), POINTER :: blacs_env
TYPE(dbcsr_p_type), DIMENSION(:), POINTER :: matrix_s
TYPE(f_env_type), POINTER :: f_env
TYPE(force_env_type), POINTER :: force_env
TYPE(qs_environment_type), POINTER :: qs_env
TYPE(qs_ks_env_type), POINTER :: ks_env
TYPE(section_vals_type), POINTER :: input_file
CALL timeset(routineN, handle)
NULLIFY (matrix_s, blacs_env, ks_env)
mp_id = opt_bas%opt_id
CALL m_getcwd(main_dir)
! ======= Create f_env for all calculations in MPI group =======
DO icalc = 1, SIZE(opt_bas%comp_group(mp_id)%member_list)
NULLIFY (input_file)
! parse the input of the training sets
CALL get_set_and_basis_id(opt_bas%comp_group(mp_id)%member_list(icalc), opt_bas, set_id, bas_id)
CALL m_chdir(TRIM(opt_bas%training_dir(set_id)), ierr)
CPASSERT(ierr == 0)
input_file => read_input(input_declaration, &
opt_bas%training_input(set_id), &
initial_variables=empty_initial_variables, &
para_env=para_env)
CALL modify_input_settings(opt_bas, bas_id, input_file)
CALL create_force_env(f_env_id(icalc), &
input_declaration=input_declaration, &
input_path=opt_bas%training_input(set_id), &
input=input_file, &
output_path="scrap_information", &
mpi_comm=mpi_comm_opt, &
ierr=stat)
! some weirdness with the default stacks defaults have to be addded to get the
! correct default program name this causes trouble with the timer stack if kept
CALL f_env_add_defaults(f_env_id(icalc), f_env)
force_env => f_env%force_env
CALL force_env_get(force_env, qs_env=qs_env)
CALL allocate_mo_sets(qs_env)
CALL f_env_rm_defaults(f_env, stat)
CALL get_qs_env(qs_env, ks_env=ks_env)
CALL build_qs_neighbor_lists(qs_env, para_env, molecular=.FALSE., &
force_env_section=qs_env%input)
CALL calculate_overlap(ks_env, "S_AB")
CALL get_qs_env(qs_env, matrix_s=matrix_s, blacs_env=blacs_env)
CALL calculate_overlap_inverse(matrix_s(1)%matrix, matrix_s_inv(icalc)%matrix, &
para_env, blacs_env)
CALL calculate_ks_matrix(qs_env)
CALL create_opt_admm_env(qs_env)
CALL section_vals_release(input_file)
CALL m_chdir(TRIM(ADJUSTL(main_dir)), ierr)
END DO
CALL timestop(handle)
END SUBROUTINE init_training_force_envs
! **************************************************************************************************
!> \brief variable update from the powell vector for all sets
!> \param opt_bas ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE update_free_vars(opt_bas)
TYPE(basis_optimization_type) :: opt_bas
CHARACTER(len=*), PARAMETER :: routineN = 'update_free_vars', &
routineP = moduleN//':'//routineN
INTEGER :: handle, ikind, iset, ix
CALL timeset(routineN, handle)
ix = 0
DO ikind = 1, opt_bas%nkind
DO iset = 1, opt_bas%kind_basis(ikind)%flex_basis(0)%nsets
CALL update_subset_freevars(opt_bas%kind_basis(ikind)%flex_basis(0)%subset(iset), ix, opt_bas%x_opt)
END DO
END DO
CALL timestop(handle)
END SUBROUTINE update_free_vars
! **************************************************************************************************
!> \brief low level update for the basis sets. Exponents are transformed according to constraint
!> \param subset ...
!> \param ix ...
!> \param x ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE update_subset_freevars(subset, ix, x)
TYPE(subset_type) :: subset
INTEGER :: ix
REAL(KIND=dp), DIMENSION(:) :: x
CHARACTER(len=*), PARAMETER :: routineN = 'update_subset_freevars', &
routineP = moduleN//':'//routineN
INTEGER :: handle, icon1, icon2, icont, iexp, il, &
istart
REAL(KIND=dp) :: fermi_f, gs_scale
CALL timeset(routineN, handle)
DO iexp = 1, subset%nexp
IF (subset%opt_exps(iexp)) THEN
ix = ix+1
subset%exps(iexp) = ABS(x(ix))
IF (subset%exp_has_const(iexp)) THEN
!use a fermi function to keep expoenents in a given range around their initial value
fermi_f = 1.0_dp/(EXP((x(ix)-1.0_dp)/0.5_dp)+1.0_dp)
subset%exps(iexp) = (2.0_dp*fermi_f-1.0_dp)*subset%exp_const(iexp)%var_fac*subset%exp_const(iexp)%init+ &
subset%exp_const(iexp)%init
ELSE
END IF
END IF
DO icont = 1, subset%ncon_tot
IF (subset%opt_coeff(iexp, icont)) THEN
ix = ix+1
subset%coeff(iexp, icont) = x(ix)
END IF
END DO
END DO
! orthonormalize contraction coefficients using gram schmidt
istart = 1
DO il = 1, subset%nl
DO icon1 = istart, istart+subset%l(il)-2
DO icon2 = icon1+1, istart+subset%l(il)-1
gs_scale = DOT_PRODUCT(subset%coeff(:, icon2), subset%coeff(:, icon1))/ &
DOT_PRODUCT(subset%coeff(:, icon1), subset%coeff(:, icon1))
subset%coeff(:, icon2) = subset%coeff(:, icon2)-gs_scale*subset%coeff(:, icon1)
END DO
END DO
istart = istart+subset%l(il)
END DO
DO icon1 = 1, subset%ncon_tot
subset%coeff(:, icon1) = subset%coeff(:, icon1)/ &
SQRT(DOT_PRODUCT(subset%coeff(:, icon1), subset%coeff(:, icon1)))
END DO
CALL timestop(handle)
END SUBROUTINE update_subset_freevars
! **************************************************************************************************
!> \brief variable initialization for the powell vector for all sets
!> \param opt_bas ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE init_free_vars(opt_bas)
TYPE(basis_optimization_type) :: opt_bas
CHARACTER(len=*), PARAMETER :: routineN = 'init_free_vars', routineP = moduleN//':'//routineN
INTEGER :: handle, ikind, iset, ix
CALL timeset(routineN, handle)
ix = 0
DO ikind = 1, opt_bas%nkind
DO iset = 1, opt_bas%kind_basis(ikind)%flex_basis(0)%nsets
CALL init_subset_freevars(opt_bas%kind_basis(ikind)%flex_basis(0)%subset(iset), ix, opt_bas%x_opt)
END DO
END DO
CALL timestop(handle)
END SUBROUTINE init_free_vars
! **************************************************************************************************
!> \brief variable initialization for the powell vector from low level informations
!> constraint exponents will be mapped on a fermi function
!> \param subset ...
!> \param ix ...
!> \param x ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE init_subset_freevars(subset, ix, x)
TYPE(subset_type) :: subset
INTEGER :: ix
REAL(KIND=dp), DIMENSION(:) :: x
CHARACTER(len=*), PARAMETER :: routineN = 'init_subset_freevars', &
routineP = moduleN//':'//routineN
INTEGER :: handle, icont, iexp
REAL(KIND=dp) :: fract
CALL timeset(routineN, handle)
DO iexp = 1, subset%nexp
IF (subset%opt_exps(iexp)) THEN
ix = ix+1
x(ix) = subset%exps(iexp)
IF (subset%exp_has_const(iexp)) THEN
IF (subset%exp_const(iexp)%const_type == 0) THEN
fract = 1.0_dp+(subset%exps(iexp)-subset%exp_const(iexp)%init)/ &
(subset%exp_const(iexp)%init*subset%exp_const(iexp)%var_fac)
x(ix) = 0.5_dp*LOG((2.0_dp/fract-1.0_dp))+1.0_dp
END IF
IF (subset%exp_const(iexp)%const_type == 1) THEN
x(ix) = 1.0_dp
END IF
END IF
END IF
DO icont = 1, subset%ncon_tot
IF (subset%opt_coeff(iexp, icont)) THEN
ix = ix+1
x(ix) = subset%coeff(iexp, icont)
END IF
END DO
END DO
CALL timestop(handle)
END SUBROUTINE init_subset_freevars
! **************************************************************************************************
!> \brief commuticates all info to the master and assembles the output
!> \param f_vec ...
!> \param cond_vec ...
!> \param my_time ...
!> \param tot_time ...
!> \param opt_bas ...
!> \param iopt ...
!> \param para_env_top ...
!> \author Florian Schiffmann
! **************************************************************************************************
SUBROUTINE output_opt_info(f_vec, cond_vec, my_time, tot_time, opt_bas, iopt, para_env_top)
REAL(KIND=dp), DIMENSION(:) :: f_vec, cond_vec, my_time, tot_time
TYPE(basis_optimization_type) :: opt_bas
INTEGER :: iopt
TYPE(cp_para_env_type), POINTER :: para_env_top
CHARACTER(len=*), PARAMETER :: routineN = 'output_opt_info', &
routineP = moduleN//':'//routineN
INTEGER :: handle, ibasis, icalc, iset, unit_nr
TYPE(cp_logger_type), POINTER :: logger
CALL timeset(routineN, handle)
logger => cp_get_default_logger()
tot_time = tot_time+my_time
unit_nr = -1
IF (para_env_top%ionode .AND. (MOD(iopt, opt_bas%write_frequency) == 0 .OR. iopt == opt_bas%powell_param%maxfun)) &
unit_nr = cp_logger_get_default_unit_nr(logger)
IF (unit_nr .GT. 0) THEN
WRITE (unit_nr, '(1X,A,I8)') "BASOPT| Information at iteration number:", iopt
WRITE (unit_nr, '(1X,A)') "BASOPT| Training set | Combination | Rho difference | Condition num. | Time"
WRITE (unit_nr, '(1X,A)') "BASOPT| -----------------------------------------------------------------------"
icalc = 0
DO iset = 1, opt_bas%ntraining_sets
DO ibasis = 1, opt_bas%ncombinations
icalc = icalc+1
WRITE (unit_nr, '(1X,A,2(5X,I3,5X,A),2(1X,E14.8,1X,A),1X,F8.3)') &
'BASOPT| ', iset, "|", ibasis, "|", f_vec(icalc), "|", cond_vec(icalc), "|", tot_time(icalc)
END DO
END DO
WRITE (unit_nr, '(1X,A)') "BASOPT| -----------------------------------------------------------------------"
WRITE (unit_nr, '(1X,A,E14.8)') "BASOPT| Total residuum value: ", opt_bas%powell_param%f
WRITE (unit_nr, '(A)') ""
END IF
CALL timestop(handle)
END SUBROUTINE output_opt_info
END MODULE optimize_basis
|
